PKGBUILD for f2c

# Maintainer: Jesin <jesin00@gmail.com>
# Contributor: Alexander Rødseth <rodseth@gmail.com>
# Contributor: Gabriele Lanaro <gabriele.lanaro@gmail.com>
# Contributor: Antony Lee <anntzer dot lee at gmail dot com>

DLAGENTS=('rsync::/usr/bin/rsync --no-motd -az %u %o' ${DLAGENTS[@]})

pkgname=f2c
pkgver=1.0
pkgrel=6
pkgdesc='Fortran to C code translator'
url='http://www.netlib.org/f2c/index.html'
license=('custom')
arch=('x86_64' 'i686')
options=('staticlibs')
source=('http://www.netlib.org/f2c/libf2c.zip'
        'f2c::rsync://netlib.org/netlib/f2c/src')
sha256sums=('5dff29c58b428fa00cd36b1220e2d71b9882a658fdec1aa094fb7e6e482d6765'
            'SKIP')

prepare() {
  rm f2c/src/xsum # Rebuild it.
}

build() {
  make -C f2c/src -f makefile.u CFLAGS="-O ${CFLAGS} -fPIC"
  make -f makefile.u CFLAGS="-O ${CFLAGS} -fPIC -DNON_UNIX_STDIO"
  gcc ${CPPFLAGS} ${CFLAGS} ${LDFLAGS} \
    -shared -Wl,-soname,libf2c.so.2 -o libf2c.so.2 *.o -lc
}

package() {
  install -Dm644 f2c.h "${pkgdir}/usr/include/f2c.h"
  install -Dm755 libf2c.so.2 "${pkgdir}/usr/lib/libf2c.so.2"
  ln -sr "${pkgdir}/usr/lib/libf2c.so"{.2,}
  make -f makefile.u LIBDIR="${pkgdir}/usr/lib" install
  install -Dm755 f2c/src/f2c "${pkgdir}/usr/bin/f2c"
  install -Dm644 f2c/src/f2c.1t "${pkgdir}/usr/share/man/man1/f2c.1"
  install -Dm644 f2c/src/Notice "${pkgdir}/usr/share/licenses/f2c/LICENSE"
}

# vim:set ts=2 sw=2 et: