Not a member of Pastebin yet?
Sign Up,
it unlocks many cool features!
- \ Create a fixed-point notation output function using REPRESENT.
- \ It should correctly handle the following cases:
- \
- \ 0.9e 0 f.n \ 1.
- \ 0.4e 0 f.n \ 0.
- \
- \ 1 set-precision
- \ 1e 0e f/ 0 f.n \ +INF
- \
- \ The following requires REPRESENT as used in DX-Forth, 4tH and
- \ VFX. A sample implementation is provided at:
- \
- \ https://dxforth.mirrors.minimaltype.com/represent2.html#REPRESENT
- DECIMAL
- [UNDEFINED] MAX-PRECISION [IF]
- CR .( Requires REPRESENT from DX-Forth, 4tH or VFX.) ABORT
- [THEN]\
- [DEFINED] DXFORTH [IF] AKA SHOLD HOLDS [THEN]
- MAX-PRECISION CONSTANT mc#
- CREATE fbuf mc# CHARS ALLOT
- 0 VALUE ex# \ exponent
- 0 VALUE sn# \ sign
- 0 VALUE pl# \ decimal places
- \ get exponent uses FLOG if exists
- : (f1) ( F: r -- r ) ( -- exp )
- [DEFINED] FLOG [IF] FDUP F0= IF 1 EXIT THEN
- FDUP FABS FLOG FLOOR F>S DUP -5000 5000 WITHIN AND 1+
- [ELSE] FDUP fbuf mc# REPRESENT NIP AND [THEN] ;
- \ float to character string
- : (f3) ( F: r -- ) ( places -- c-addr u flag )
- TO pl# (f1) pl# + MAX-PRECISION MIN
- fbuf SWAP REPRESENT >R TO sn# TO ex#
- fbuf mc# -TRAILING R> <# ;
- \ insert string
- : (f6) ( c-addr n -- ) 0 MAX HOLDS ;
- \ insert '0's
- : (f7) ( n -- ) 0 MAX 0 ?DO [CHAR] 0 HOLD LOOP ;
- \ insert fraction string n places right of dec. point
- : (fb) ( c-addr u n -- )
- DUP >R +
- pl# OVER - (f7) \ trailing 0's
- pl# MIN R@ - (f6) \ fraction
- R> pl# MIN (f7) \ leading 0's
- [CHAR] . HOLD ;
- \ split string into integer/fraction parts at n and insert
- : (fc) ( c-addr u n -- )
- >R 2DUP R@ MIN 2SWAP R> /STRING 0 (fb) (f6) ;
- \ Convert real number r to a string c-addr u in fixed-point
- \ notation with +n decimal places.
- : (F.) ( F: r -- ) ( +n -- c-addr u )
- (f3) IF
- ex# DUP mc# > IF
- fbuf 0 ( dummy ) 0 (fb)
- mc# - (f7) (f6)
- ELSE
- DUP 0> IF
- (fc)
- ELSE
- ABS (fb) 1 (f7)
- THEN
- THEN sn# SIGN 0 0 #> EXIT
- THEN HOLDS 0 0 #> ;
- \ Display real number r in fixed-point notation with +n
- \ decimal places right-justified in a field width u .
- : F.R ( F: r -- ) ( +n u -- )
- >R (F.) R> OVER - SPACES TYPE ;
- \ end
- \ tests
- : f.n 0 f.r space ;
- :noname cr begin refill while source 2dup type space
- evaluate cr repeat ; execute
- 0.9e 0 f.n
- 0.3e 0 f.n
- -0.9e 0 f.n
- -0.3e 0 f.n
- 0.123e 0 f.n
- 0.123e-1 1 f.n
- 0.123e-2 2 f.n
- 0.123e-3 3 f.n
- 0.823e 0 f.n
- 0.823e-1 1 f.n
- 0.823e-2 2 f.n
- 0.823e-3 3 f.n
- 0.1368e 3 f.n
- 0.1368e-1 3 f.n
- 0.1368e-2 3 f.n
- 0.1368e-3 3 f.n
- 0.1368e-4 3 f.n
- -0.8368e 3 f.n
- -0.8368e-1 3 f.n
- -0.8368e-2 3 f.n
- -0.8368e-3 3 f.n
- -0.8368e-4 3 f.n
- 123.4567e 3 f.n
- 123.4567e 2 f.n
- 123.4567e 1 f.n
- 123.4567e 0 f.n
- \ 123.4567e -1 f.n
- \ 123.4567e -2 f.n
- \ 123.4567e -3 f.n
- 99.995e 3 f.n
- 99.995e 2 f.n
- 99.995e 1 f.n
- 5.2345678e-1 10 f.n
- 5.2345678e-2 10 f.n
- 5.2345678e-3 10 f.n
- 5.2345678e-4 10 f.n
- 5.2345678e-5 10 f.n
- 5.2345678e-6 10 f.n
- 5.2345678e-7 10 f.n
- 5.2345678e-8 10 f.n
- 5.2345678e-9 10 f.n
- 5.2345678e-10 10 f.n
- 5.2345678e-11 10 f.n
- 5.2345678e-12 10 f.n
- 123e30 10 f.n
- 123e-30 35 f.n
- precision 1 set-precision
- 1e 0e f/ 0 f.n
- 0e 0e f/ 0 f.n
- set-precision
- abort
- \ results
- 0.9e 0 f.n 1.
- 0.3e 0 f.n 0.
- -0.9e 0 f.n -1.
- -0.3e 0 f.n 0.
- 0.123e 0 f.n 0.
- 0.123e-1 1 f.n 0.0
- 0.123e-2 2 f.n 0.00
- 0.123e-3 3 f.n 0.000
- 0.823e 0 f.n 1.
- 0.823e-1 1 f.n 0.1
- 0.823e-2 2 f.n 0.01
- 0.823e-3 3 f.n 0.001
- 0.1368e 3 f.n 0.137
- 0.1368e-1 3 f.n 0.014
- 0.1368e-2 3 f.n 0.001
- 0.1368e-3 3 f.n 0.000
- 0.1368e-4 3 f.n 0.000
- -0.8368e 3 f.n -0.837
- -0.8368e-1 3 f.n -0.084
- -0.8368e-2 3 f.n -0.008
- -0.8368e-3 3 f.n -0.001
- -0.8368e-4 3 f.n 0.000
- 123.4567e 3 f.n 123.457
- 123.4567e 2 f.n 123.46
- 123.4567e 1 f.n 123.5
- 123.4567e 0 f.n 123.
- \ 123.4567e -1 f.n
- \ 123.4567e -2 f.n
- \ 123.4567e -3 f.n
- 99.995e 3 f.n 99.995
- 99.995e 2 f.n 100.00
- 99.995e 1 f.n 100.0
- 5.2345678e-1 10 f.n 0.5234567800
- 5.2345678e-2 10 f.n 0.0523456780
- 5.2345678e-3 10 f.n 0.0052345678
- 5.2345678e-4 10 f.n 0.0005234568
- 5.2345678e-5 10 f.n 0.0000523457
- 5.2345678e-6 10 f.n 0.0000052346
- 5.2345678e-7 10 f.n 0.0000005235
- 5.2345678e-8 10 f.n 0.0000000523
- 5.2345678e-9 10 f.n 0.0000000052
- 5.2345678e-10 10 f.n 0.0000000005
- 5.2345678e-11 10 f.n 0.0000000001
- 5.2345678e-12 10 f.n 0.0000000000
- 123e30 10 f.n 123000000000000000000000000000000.0000000000
- 123e-30 35 f.n 0.00000000000000000000000000012300000
- precision 1 set-precision
- 1e 0e f/ 0 f.n +INF
- 0e 0e f/ 0 f.n -NAN
- set-precision
Advertisement
Add Comment
Please, Sign In to add comment