pkgname=tauon-music-box
_pkgname=tauonmb
_gitname=TauonMusicBox
pkgver=6.2.1
pkgrel=2
pkgdesc="A modern streamlined music player"
arch=('any')
url="https://tauonmusicbox.rocks"
license=('GPL3')
depends=('python-pillow'
         'python-pylast'
         'python-flask'
         'python-hsaudiotag3k'
         'python-pysdl2'
         'python-stagger'
         'python-send2trash'
         'python-pylyrics'
         'python-musicbrainzngs'
         'python-discogs-client'
         'python-isounidecode'
         'python-setproctitle'
         'python-gobject'
         'python-cairo'
         'python-beautifulsoup4'
         'python-requests'
         'python-dbus'
         'python-oauthlib'
         'python-six'
         'alsa-plugins'
         'ffmpeg'
         'flac'
         'gst-plugins-bad'
         'gst-plugins-ugly'
         'noto-fonts-extra'
         'noto-fonts-cjk'
         'sdl2_image'
         'xdg-utils')
optdepends=('p7zip: 7z archive extraction support'
            'unrar: RAR archive extraction support'
            'python-plexapi: Plex streaming'
            'python-pypresence: Discord status support'
            'python-tekore: Spotify playback control'
            'picard: Tag editing')
source=("$pkgname-$pkgver.tar.gz::https://github.com/Taiko2k/TauonMusicBox/archive/v$pkgver.tar.gz")
sha256sums=('90ac549dd86467dfeeb1bb9a5282bc08f48300294b6466a8902e2f18fd381873')

prepare() {
    cd "$_gitname-$pkgver"
    sed -i 's|tauonmb.sh %U|tauon.py "$@"|g' "extra/$_pkgname.desktop"
}

build() {
    cd "$_gitname-$pkgver"
    python compile-translations.py
}

package() {
    cd "$_gitname-$pkgver"
    install -Dm755 tauon.py -t "$pkgdir/opt/$pkgname"
    install -d "$pkgdir/usr/bin"
    ln -s "/opt/$pkgname/tauon.py" "$pkgdir/usr/bin/$_pkgname"

    install -Dm644 input.txt -t "$pkgdir/opt/$pkgname"
    cp -r  assets templates theme t_modules "$pkgdir/opt/$pkgname"

    for t in de fr_FR ja_JP nb_NO pt_BR pt_PT sv zh_CN; do
        install -Dm644 locale/${t}/LC_MESSAGES/*.mo -t "$pkgdir/usr/share/locale/${t}/LC_MESSAGES"
    done

    install -Dm644 "extra/$_pkgname.desktop" -t "$pkgdir/usr/share/applications"
    install -Dm644 "extra/$_pkgname-symbolic.svg" -t "$pkgdir/usr/share/icons/hicolor/symbolic/apps"
    install -Dm644 "extra/$_pkgname.svg" -t "$pkgdir/usr/share/icons/hicolor/scalable/apps"
}