new allowTrailer[MAX_VEHICLES char];

stock ac_AttachTrailerToVehicle(trailerid, vehicleid)
{
    allowTrailer{trailerid} = 1;
    return AttachTrailerToVehicle(trailerid, vehicleid);
}
#if defined _ALS_AttachTrailerToVehicle
    #undef AttachTrailerToVehicle
#else
    #define _ALS_AttachTrailerToVehicle
#endif
#define AttachTrailerToVehicle ac_AttachTrailerToVehicle

public OnVehicleSpawn(vehicleid)
{
    if(allowTrailer{vehicleid}) allowTrailer{vehicleid} = 0;
    #if defined ac_OnVehicleSpawn
        return ac_OnVehicleSpawn(vehicleid);
    #else
        return 1;
    #endif
}
#if defined _ALS_OnVehicleSpawn
    #undef OnVehicleSpawn
#else
    #define _ALS_OnVehicleSpawn
#endif
#if defined ac_OnVehicleSpawn
    forward ac_OnVehicleSpawn(vehicleid);
#endif
#define OnVehicleSpawn ac_OnVehicleSpawn

IPacket:210(playerid, BitStream:bs)
{
    new data[PR_TrailerSync];
    BS_IgnoreBits(bs, 8);
    BS_ReadTrailerSync(bs, data);

    if(allowTrailer{data[PR_trailerId]}) return 1;
    new model = GetVehicleModel(data[PR_trailerId]);
    switch(model)
    {
        case 435, 450, 584, 591, 606..608, 610, 611: {}
        default: return false;
    }
    if(!IsPlayerInRangeOfPoint(playerid, 50.0, data[PR_position][0], data[PR_position][1], data[PR_position][2])) return 0;
    return 1;
}

1secTimer
{
    for(new vehid = GetVehiclePoolSize(); vehid > 0; vehid--) if(allowTrailer{vehid} && !IsTrailerAttachedToVehicle(vehid))
    {
        allowTrailer{vehid} = 0;
    }
}