Blacksmith slayers with beetle

//Note: Be sure that there are no weapons of the chosen type in your main pack before running.
if listexists 'slayerType'
  clearlist 'slayerType'
else
  createlist 'slayerType'
endif
//Set the graphic below to match that of the weapon you're crafting.
pushlist 'slayerType' 0x1401
//0xf5e broadsword
//0x13ff katana
//0xf4b double axe
//0x1403 short spear
//0xf49 axe
//0x1401 kryss
//0x1439 war hammer
//0x1407 war mace
//0xf47 battle axe
if @findtype 'slayerType[0]' 'any' 'backpack' 'any' '0'
  headmsg '*Remove weapons of the chosen type from your main pack before starting.*' 50
  stop
endif
while mounted
  useobject 'self'
  pause 200
endwhile
if not @findobject 'mount'
  promptalias 'mount'
endif
if not @findobject 'mount'
  headmsg 'Beetle not found.' 50
  stop
else
  while not mounted
    useobject 'mount'
    pause 200
  endwhile
endif
@createtimer 'failSafe'
while @findtype 0xfbb 'any' 'backpack'
  setalias 'tongs' 'found'
  pause 600
  useobject 'found'
  waitforgump 0x38920abd 3000
  pause 200
  while @findobject 'tongs' and gumpexists 0x38920abd
    if @injournal 'crafted a slayer' 'system'
      sysmsg 'Slayer crafted!' 33
      while not @findobject 'mount'
        useobject 'self'
        pause 600
      endwhile
      while @findtype slayerType[0] 0x0 'backpack'
        @setalias 'slayerWep' 'found'
        while not @inrange 'mount' 2
          msg 'all come'
          pause 200
        endwhile
        moveitem 'slayerWep' 'mount'
        pause 600
      endwhile
      while @findobject 'mount'
        if @inrange 'mount' 1
          useobject 'mount'
          pause 200
        else
          msg 'all come'
        endif
        pause 300
      endwhile
      ignoreobject 'slayerWep'
      clearjournal
      pause 600
    elseif @findtype slayerType[0] 0x0 'backpack' 'any' 0
      if @gumpexists 0x38920abd
        @replygump 0x38920abd 14
        waitfortarget 3000
        @target! 'found'
        waitforgump 0x38920abd 3000
      else
        ignoreobject 'found'
      endif
    endif
    if @gumpexists 0x38920abd
      @replygump 0x38920abd 21
      waitforgump 0x38920abd 3000
      settimer 'failSafe' 0
      if not @gumpexists 0x16bcf486
        while not @findtype slayerType[0] 0x0 'backpack' 'any' 0
          pause 50
          if timer 'failSafe' > 3000
            headmsg 'No weapon found.  Be sure you have the correct weapon type inserted on line 8.' 50
            messagebox 'Alert' 'No weapon found.  Be sure you have the correct weapon type inserted on line 8.'
            stop
          endif
        endwhile
      else
        while @gumpexists 0x16bcf486
          pause 100
          if timer 'failSafe' > 60000
            break
          endif
        endwhile
      endif
    endif
  endwhile
endwhile
headmsg '*Tongs not found*' 50
messagebox 'Error' 'Tongs not found'