TxtEditor - Edit Find & Find Next Options.

'------------------------------------------------------------------------------------------
'           Notice of My Copyright and Intellectual Property Rights
'
' Any intellectual property contained within the program by Joseph L. Bolen remains the
' intellectual property of the Joseph L. Bolen. This means that no person may distribute,
' publish or provide such intellectual property to any other person or entity for any
' reason, commercial or otherwise, without the express written permission of Joseph L. Bolen.
'
'                 Copyright © 2015. All rights reserved.
'        All trademarks remain the property of their respective owners.
'-------------------------------------------------------------------------------------------
' Class Name:     FindTextForm
'
' Author:         Joseph L. Bolen
' Date Created:   Mar 2015
'
' Description:    Using a Singleton design pattern for a modeless form,
'                 the class uses the String.IndexOf and String.LastIndexOf methods
'                 to search forward and backward through MainForm's MyTextBox to
'                 find matching text.
'
'                 Documentation is at:
'                   Form's screen image is at http://i.imgur.com/4xVTebj.png
'                   App's Visual Basic .NET code is at http://pastebin.com/u/jaybeeoh
'                   Video tutorial at YouTube: http://www.youtube.com/user/bolenpresents
'-------------------------------------------------------------------------------------------

Public Class FindTextForm

#Region " Class Level Variables Declared"

    Private Shared myInstance As FindTextForm = Nothing
    Private Shared ReadOnly aLock As New Object

#End Region

#Region " Private Methods and Functions"

    ' Change constructor to a private method.
    Private Sub New()

        InitializeComponent()
    End Sub

    ' Retrieve last findString value.
    Private Sub FindForm_Activated(sender As Object, e As EventArgs) _
        Handles Me.Activated

        If MainForm.findString <> String.Empty Then
            FindTextBox.Text = MainForm.findString
        End If
    End Sub

    ' On the FormClosing event hide the form, instead of closing it.
    Private Sub FindForm_FormClosing(sender As Object, e As FormClosingEventArgs) _
        Handles Me.FormClosing

        ' Cancel the Closing event from closing the form.
        e.Cancel = True
        Me.Hide()
    End Sub

    ' On the CancelButton Click event hide the form, instead of closing it.
    Private Sub CancelButton_Click(sender As Object, e As EventArgs) _
        Handles CancelButton.Click

        Me.Hide()
    End Sub

    ' Find text.
    Private Sub FindNextButton_Click(sender As Object, e As EventArgs) _
        Handles FindNextButton.Click

        FindText()
    End Sub

    ' When Find Text changes, update MainForm's findStrng variable.
    Private Sub FindTextBox_TextChanged(sender As Object, e As EventArgs) _
        Handles FindTextBox.TextChanged

        If (FindTextBox.Text.Length > 0) Then
            MainForm.findString = FindTextBox.Text
            'Unselect last find, but keep cursor at current location.
            MainForm.MyTextBox.Select(MainForm.MyTextBox.SelectionStart, 0)
            FindNextButton.Enabled = True
        Else
            MainForm.findString = String.Empty
            FindNextButton.Enabled = False
        End If
    End Sub

#End Region

#Region " Public Methods and Functions"

    ' Use factory method to instantiate class.
    Public Shared Function GetInstance() As FindTextForm
        ' Thread safe.
        SyncLock aLock
            ' If constructor has not been evoked, call constructor and return instance.
            ' Otherwise, return the previously created instance.
            If myInstance Is Nothing Then
                myInstance = New FindTextForm
            End If
            Return myInstance
        End SyncLock
    End Function

    ' Find text in MainForm's MyTextBox
    Public Sub FindText()

        Dim startPosition As Integer
        Dim foundPosition As Integer

        With MainForm.MyTextBox
            If startPosition <> .SelectionStart Then
                If DownRadioButton.Checked Then
                    startPosition = .SelectionStart + 1
                    If startPosition > .Text.Length Then
                        startPosition = .Text.Length
                    End If
                Else
                    startPosition = .SelectionStart - 1
                    If startPosition < 0 Then
                        startPosition = 0
                    End If
                End If
            End If

            If DownRadioButton.Checked Then
                If MatchCaseCheckBox.Checked Then
                    foundPosition = .Text.IndexOf(MainForm.findString, startPosition, StringComparison.Ordinal)
                Else
                    foundPosition = .Text.IndexOf(MainForm.findString, startPosition, StringComparison.OrdinalIgnoreCase)
                End If
            Else
                If MatchCaseCheckBox.Checked Then
                    foundPosition = .Text.LastIndexOf(MainForm.findString, startPosition, StringComparison.Ordinal)
                Else
                    foundPosition = .Text.LastIndexOf(MainForm.findString, startPosition, StringComparison.OrdinalIgnoreCase)
                End If
            End If

            If foundPosition = -1 Then
                If DialogResult.Yes = MessageBox.Show("Cannot find """ & MainForm.findString & """. Reverse search direction?",
                                MainForm.applicationTitle,
                                MessageBoxButtons.YesNo,
                                MessageBoxIcon.Question) Then
                    DownRadioButton.Checked = Not DownRadioButton.Checked
                    UpRadioButton.Checked = Not DownRadioButton.Checked
                End If
                .ScrollToCaret()
                .Focus()
                Exit Sub
            End If

            .Select(foundPosition, MainForm.findString.Length)
            .ScrollToCaret()
            .Focus()
        End With
    End Sub

#End Region

End Class

'=======================================================================================================================
Changes to MainForm's code --

Public Class MainForm

#Region "  Declare Class Level Variables"

    Public findString As String = String.Empty

#End Region

#Region " Find / Find Next / Replace"

    ' Edit Find option - Show FindTextForm.
    Private Sub FindToolStripMenuItem_Click(sender As Object, e As EventArgs) _
        Handles FindToolStripMenuItem.Click

        ' Instanciate and display FindTextForm form.
        Dim aFindTextForm As FindTextForm = FindTextForm.GetInstance()
        aFindTextForm.Show()
    End Sub

    ' Edit Find Next option - Using FindTextForm's FindText method.
    Private Sub FindNextToolStripMenuItem_Click(sender As Object, e As EventArgs) _
        Handles FindNextToolStripMenuItem.Click

        ' Instanciate and display FindTextForm form, then call FindText subroutine.
        Dim aFindTextForm As FindTextForm = FindTextForm.GetInstance()
        aFindTextForm.FindText()
    End Sub

#End Region

End Class