//=================================================================================
// Type "/list" while in vanish with an item in your hand to teleport around.
// You can pause the teleportation sequence by putting the item aside.

// If you want to exclude players from your tour list them as shown in the example.
// Example: &tabu="Player1 Player2 Player3 Player4"
&tabu="LexyDev stefm90 malaboo Kademlia"

// Enter the time you want to wait between teleports in seconds.
// Example: #rest=5
#rest=5

// This Macro was written by 22855.
// Modify at own risk.
//=================================================================================

ifmatches(%CHAT%,"^§3You have joined vanished. To appear: /vanish§r$")
    set(vanish)
endif
ifmatches(%CHAT%,"^§3You have vanished. Poof.§r$")
    set(vanish)
endif
ifmatches(%CHAT%,"^§3You have become visible.§r$")
    unset(vanish)
endif
if(vanish)
    ifmatches(%CHAT%,"^§6Players§r: §r(.+)§r$")
        getslotitem(%INVSLOT%,&item)
        if(&item!="air")
            match(%CHAT%,"^§6Players§r: §r(.+)§r$",{&list})
            split("§r§f, ",%&list%,&list[])
            &check=" %&tabu% "
            #i=0
            do
                if(%&list[%#i%]%!=%PLAYER%)
                    ifcontains("%&check%"," %&list[%#i%]% ")
                    else
                        do
                            getslotitem(%INVSLOT%,&item)
                            if(!vanish)
                                unset(&list[])
                                log("§cYou became visible! The tour ended.")
                                stop
                            endif
                        until(&item!="air")
                        log("/tp %&list[%#i%]%")
                        wait("%#rest%")
                    endif
                endif
                inc(#i)
            while("%&list[%#i%]%")
            log("§3Your secret journey has come to an end!")
        endif
    endif
endif