Plus.lsf - lsFusion addon for HockeyStats

MODULE Plus;

REQUIRE Main;

CLASS Player 'Составы команд';
name 'Имя игрока' (Player) = DATA STRING[50] (Player) IN base;
team = DATA Team (Player);
teamName 'Команда' (Player player) = name(team(player));

EXTEND FORM MainForm
  OBJECTS player = Player
  PROPERTIES(player) teamName, name, NEW, DELETE
  ORDER teamName(player), name(player)
;

CLASS Goal 'Гол';
game = DATA Game (Goal);
time 'Время' = DATA TIME (Goal);
player = DATA Player (Goal);
playerName 'Игрок' (Goal goal) = name(player(goal));
teamName 'Команда' (Goal goal) = name(team(player(goal)));
CONSTRAINT team(player(Goal goal)) != hostTeam(game(goal))
  AND team(player(goal)) != guestTeam(game(goal))
  CHECKED BY game[Goal], player[Goal]
  MESSAGE 'Команда игрока должна быть участницей игры';

EXTEND FORM MainForm
  OBJECTS goal = Goal AFTER game
  PROPERTIES(goal) time, playerName, teamName READONLY, NEW, DELETE
  ORDER time(goal)
  FILTERS game(goal) == game
;

goalNumber 'Голов' = GROUP SUM 1 BY player(Goal goal);

FORM TopScorersForm 'Таблица бомбардиров'
  OBJECTS player 'Лучшие бомбардиры турнира' = Player
  PROPERTIES(player) name, teamName, goalNumber
  ORDER goalNumber(player) DESC
;

NAVIGATOR {
  NEW TopScorersForm;
}