gDialog 1.0

/*
    gDialog V1.0
    Created by Gamer931215 - Released on 05-09-2011

    native CreateDialog(dialogid,style,caption[],info[],button1[],button2[])
    native ShowPlayerDialogEx(playerid,dialogid,style,caption[],info[],button1[],button2[])
    native ShowPlayerDialog(playerid,dialogid)

    http://www.gamer93.net
*/
#include <a_samp>
#if defined _SD_INCLUDED
    #endinput
#endif
#define _SD_INCLUDED

#if !defined MAX_DIALOGS
    #define MAX_DIALOGS 100
#endif
#if !defined MAX_CAPTION_LENGTH
    #define MAX_CAPTION_LENGTH 64
#endif
#if !defined MAX_INFO_LENGTH
    #define MAX_INFO_LENGTH 256
#endif
#if !defined MAX_BUTTON_LENGTH
    #define MAX_BUTTON_LENGTH 24
#endif

#define DIALOG:%0(%1,%2,%3,%4)      \
    forward dlg_%0(%1,%2,%3,%4);    \
    public dlg_%0(%1,%2,%3,%4)

enum _dialog
{
    _style,
    _caption[MAX_CAPTION_LENGTH],
    _info[MAX_INFO_LENGTH],
    _button1[MAX_BUTTON_LENGTH],
    _button2[MAX_BUTTON_LENGTH],
    bool:_used
}
new DialogDetails[MAX_DIALOGS][_dialog];

stock CreateDialog(dialogid,style,caption[],info[],button1[],button2[])
{
    if(dialogid > MAX_DIALOGS)
    {
        print("gDialog: You used a invalid dialogid! Please redefine MAX_DIALOGS");
    }
    DialogDetails[dialogid][_style] = style;
    format(DialogDetails[dialogid][_caption],MAX_CAPTION_LENGTH,"%s",caption);
    format(DialogDetails[dialogid][_info],MAX_INFO_LENGTH,"%s",info);
    format(DialogDetails[dialogid][_button1],MAX_BUTTON_LENGTH,"%s",button1);
    format(DialogDetails[dialogid][_button2],MAX_BUTTON_LENGTH,"%s",button2);
    DialogDetails[dialogid][_used] = true;
}

stock ShowPlayerDialogEx(playerid,dialogid,style,caption[],info[],button1[],button2[])
{
    return ShowPlayerDialog(playerid,dialogid,style,caption,info,button1,button2);
}

stock SD_ShowPlayerDialog(playerid,dialogid)
{
    return ShowPlayerDialog(playerid,dialogid,DialogDetails[dialogid][_style],DialogDetails[dialogid][_caption],DialogDetails[dialogid][_info],DialogDetails[dialogid][_button1],DialogDetails[dialogid][_button2]);
}
#if defined _ALS_ShowPlayerDialog
    #undef ShowPlayerDialog
#else
    #define _ALS_ShowPlayerDialog
#endif
#define ShowPlayerDialog SD_ShowPlayerDialog

public OnDialogResponse(playerid, dialogid, response, listitem, inputtext[])
{
    new function[32];format(function,sizeof function,"dlg_%i",dialogid);
    CallLocalFunction(function,"iiis",playerid,response,listitem,inputtext);
    return CallLocalFunction("SD_OnDialogResponse","iiiis",playerid,dialogid,response,listitem,inputtext);
}
#if defined _ALS_OnDialogResponse
    #undef OnDialogResponse
#else
    #define _ALS_OnDialogResponse
#endif
#define OnDialogResponse SD_OnDialogResponse
forward SD_OnDialogResponse(playerid, dialogid, response, listitem, inputtext[]);