// Run this Query into your database.
/*
CREATE TABLE IF NOT EXISTS `reward_list` (
	`reward_id` bigint(20) unsigned NOT NULL auto_increment,

	`sender_name` varchar(30) NOT NULL default '',
	`winner_name` varchar(30) NOT NULL default '',

	`nameid` int(11) unsigned NOT NULL default '0',
	`amount` int(11) unsigned NOT NULL default '0',
	`refine` tinyint(3) unsigned NOT NULL default '0',

	`status` tinyint(2) NOT NULL default '0',
	`time` datetime NOT NULL default '0000-00-00 00:00:00',

	`sender_ip` varchar(100) NOT NULL default '',
	`winner_ip` varchar(100) NOT NULL default '',

	PRIMARY KEY  (`reward_id`)
) ENGINE=MyISAM;
*/


prontera,143,179,5	script	Reward Npc	757,{
.@gmlevel = getgmlevel();

mes "How can i help you ?";
next;
switch( select( "Claim Rewards",
				( .@gmlevel < .gm_level )?"":"^0055FF[ GM ]^000000 Give Reward",
				( .@gmlevel < .gm_level )?"":"^0055FF[ GM ]^000000 Delete Reward",
				( .@gmlevel < 99 )?"":"^0055FF[ GM ]^000000 Approve Reward",
				( .@gmlevel < 99 )?"":"^FF0000[ GM ] View Logs^000000" )){
	Case 1:
		query_sql( "SELECT `reward_id`,`sender_name`,`nameid`,`amount`,`refine`,`time` FROM `reward_list` WHERE `winner_name` LIKE '"+escape_sql( strcharinfo(0) )+"' AND `status` = '1' LIMIT "+.max_record_view,.@id,.@sender_name$,.@item,.@amount,.@refine,.@time$ );
		.@item_size = getarraysize( .@item );
		if( !.@item_size ){
			mes "You dont have any rewards.";
		}else{
			mes "Pick an Items.";
			for( .@i = 0; .@i < .@item_size; .@i++ )
				.@menu$ = .@menu$ + "^0055FF"+( ( .@refine[.@i] )?"+"+.@refine[.@i]:.@amount[.@i]+" x" )+" "+ getitemname( .@item[.@i] )+"^000000 by ^FF0000"+.@sender_name$[.@i]+"^000000" +":";
			.@i = select( .@menu$ ) - 1;
			if( checkweight( .@item[.@i],.@amount[.@i] ) ){
				query_sql( "UPDATE `reward_list` SET `status`='2',`winner_ip`='"+getcharip( strcharinfo(0) )+"' WHERE `reward_id` = '"+.@id[.@i]+"'" );
				getitem2 .@item[.@i],.@amount[.@i],1,.@refine,0,0,0,0,0;
				mes "Done, claimed ^0055FF"+( ( .@refine[.@i] )?"+"+.@refine[.@i]:.@amount[.@i]+" x" )+" "+ getitemname( .@item[.@i] )+"^000000";
			}else{
				mes "Item too heavy, you cant take it now.";
			}
		}
		break;
	Case 2:
		mes "Enter ^0055FFItem ID^000000";
		do{
			input .@item_id,0,32767;
			if( !.@item_id ) close;
		}while( getitemname( .@item_id ) == "null" );
		.@item_type = getiteminfo( .@item_id,2 );
		if( .@item_type == 4 || .@item_type == 5 ){
			mes "Enter ^0055FFRefine Rate^000000 for "+getitemname( .@item_id );
			input .@refine,0,10;
			.@amount = 1;
		}else{
			mes "Enter ^0055FFAmount^000000";
			input .@amount,1,30000;
			.@refine = 0;
		}
		mes "Enter ^0055FFWinner Name^000000";
		input .@winner_name$;
		next;
		mes "Winner : ^FF0000"+.@winner_name$+"^000000";
		mes "Item : ^0055FF"+( ( .@refine )?"+"+.@refine:.@amount+" x" ) +" "+ getitemname( .@item_id )+"^000000";
		if( select( "Confirm","Cancel" ) == 1 ){
			query_sql( "INSERT INTO `reward_list` ( `sender_name`,`winner_name`,`nameid`,`amount`,`refine`,`time`,`sender_ip` ) VALUES ( '"+escape_sql( strcharinfo(0) )+"','"+escape_sql( .@winner_name$ )+"','"+.@item_id+"','"+.@amount+"','"+.@refine+"','"+gettimestr( "%Y-%m-%d %H:%M:%S",21 )+"','"+getcharip()+"' )" );
			mes "Done.";
		}
		break;
	Case 3:
		query_sql( "SELECT `reward_id`,`sender_name`,`winner_name`,`nameid`,`amount`,`refine`,`time`,`sender_ip` FROM `reward_list` WHERE `status` = '0' ORDER BY `time` DESC LIMIT "+.max_record_view,.@id,.@sender_name$,.@winner_name$,.@item,.@amount,.@refine,.@time$,.@ip$ );
		.@item_size = getarraysize( .@item );
		if( !.@item_size ){
			mes "Dont have any un-claimed rewards.";
		}else{
			mes "Delete un-claimed Rewards.";
			mes "^777777Lastest "+.max_record_view+" Rewards^000000";
			for( .@i = 0; .@i < .@item_size; .@i++ )
				.@menu$ = .@menu$ + "[ "+( .@i + 1 )+". ]^FF0000"+.@winner_name$[.@i]+"^000000 sent ^0055FF"+( ( .@refine[.@i] )?"+"+.@refine[.@i]:.@amount[.@i]+" x" )+" "+ getitemname( .@item[.@i] )+"^000000" +":";
			next;
			.@i = select( .@menu$ ) - 1;
			mes "Winner : ^FF0000"+.@winner_name$[.@i]+"^000000";
			mes "Item : ^0055FF"+( ( .@refine[.@i] )?"+"+.@refine[.@i]:.@amount[.@i]+" x" )+" "+ getitemname( .@item[.@i] )+"^000000";
			mes "Sender : ^FF0000"+.@sender_name$[.@i]+"^000000";
			mes "Sender IP : ^777777"+.@ip$[.@i]+"^000000";
			mes "Time : ^777777"+.@time$[.@i]+"^000000";
			if( select( "Delete Reward","Cancel" ) == 1 ){
				query_sql( "DELETE FROM `reward_list` WHERE `reward_id` = '"+.@id[.@i]+"' LIMIT 1" );
				mes "Done, removed rewards.";
			}
		}
		break;
	Case 4:
		query_sql( "SELECT `reward_id`,`sender_name`,`winner_name`,`nameid`,`amount`,`refine`,`time`,`sender_ip` FROM `reward_list` WHERE `status` = '0' ORDER BY `time` DESC LIMIT "+.max_record_view,.@id,.@sender_name$,.@winner_name$,.@item,.@amount,.@refine,.@time$,.@ip$ );
		.@item_size = getarraysize( .@item );
		if( !.@item_size ){
			mes "Dont have any pending rewards.";
		}else{
			mes "Approve Rewards.";
			mes "^777777Lastest "+.max_record_view+" Rewards^000000";
			for( .@i = 0; .@i < .@item_size; .@i++ )
				.@menu$ = .@menu$ + "[ "+( .@i + 1 )+". ]^FF0000"+.@winner_name$[.@i]+"^000000 sent ^0055FF"+( ( .@refine[.@i] )?"+"+.@refine[.@i]:.@amount[.@i]+" x" )+" "+ getitemname( .@item[.@i] )+"^000000" +":";
			next;
			.@i = select( .@menu$ ) - 1;
			mes "Winner : ^FF0000"+.@winner_name$[.@i]+"^000000";
			mes "Item : ^0055FF"+( ( .@refine[.@i] )?"+"+.@refine[.@i]:.@amount[.@i]+" x" )+" "+ getitemname( .@item[.@i] )+"^000000";
			mes "Sender : ^FF0000"+.@sender_name$[.@i]+"^000000";
			mes "Sender IP : ^777777"+.@ip$[.@i]+"^000000";
			mes "Time : ^777777"+.@time$[.@i]+"^000000";
			if( select( "Approve Reward","Cancel" ) == 1 ){
				query_sql( "UPDATE `reward_list` SET `status`='1' WHERE `reward_id` = '"+.@id[.@i]+"' LIMIT 1" );
				mes "Done, approved rewards.";
			}
		}
		break;
	Case 5:
		.@status = select( "Pending Approval","Un-claimed Records","Claimed Records" );
		query_sql( "SELECT `reward_id`,`sender_name`,`winner_name`,`nameid`,`amount`,`refine`,`time`,`sender_ip`,`winner_ip` FROM `reward_list` WHERE `status`='"+.@status+"' ORDER BY `time` DESC LIMIT "+.max_record_view,.@id,.@sender_name$,.@winner_name$,.@item,.@amount,.@refine,.@time$,.@sender_ip$,.@winner_ip$ );
		.@item_size = getarraysize( .@item );
		if( !.@item_size ){
			mes "Dont have any records.";
		}else{
			mes "^777777Lastest "+.max_record_view+" Records^000000";
			for( .@i = 0; .@i < .@item_size; .@i++ )
				.@menu$ = .@menu$ + "[ "+( .@i + 1 + .@offset )+". ]^FF0000"+.@winner_name$[.@i]+"^000000 gained ^0055FF"+( ( .@refine[.@i] )?"+"+.@refine[.@i]:.@amount[.@i]+" x" )+" "+ getitemname( .@item[.@i] )+"^000000" +":";
			do{
				.@i = select( .@menu$+":Close" ) - 1;
				if( .@i >= .@item_size ) break;
				// next;
				mes "Winner : ^FF0000"+.@winner_name$[.@i]+"^000000";
				mes "Winner IP : "+( ( .@winner_ip$[.@i] == "" )?"^777777none^000000":"^FF0000"+.@winner_ip$[.@i] )+"^000000";
				mes "Item : ^0055FF"+( ( .@refine[.@i] )?"+"+.@refine[.@i]:.@amount[.@i]+" x" )+" "+ getitemname( .@item[.@i] )+"^000000";
				mes "Sender : ^FF0000"+.@sender_name$[.@i]+"^000000";
				mes "Sender IP : ^777777"+.@sender_ip$[.@i]+"^000000";
				mes "Time : ^777777"+.@time$[.@i]+"^000000";
				mes "Status : "+( ( .@status )?"^0055FFClaimed":"^FF0000Un-Claimed" )+"^000000";
				next;
			}while( 1 );
		}
		break;
	default: break;
}
close;

OnInit:
.gm_level = 60;
.max_record_view = 10;
end;
}