mate-calc aur

# Maintainer: Perberos <perberos@gmail.com>
pkgname=mate-calc
pkgver=20120308
pkgrel=1
pkgdesc="Calculator for the Mate desktop environment"
arch=('i686' 'x86_64')
license=('LGPL' 'GPL')
depends=('gtk2' 'libxml2' 'libpng' 'freetype2' 'pixman' 'glib' 'pango' 'gdk-pixbuf2' 'cairo' 'atk')
makedepends=('pkgconfig' 'mate-doc-utils')
groups=('mate-extra')
url="http://matsusoft.com.ar/projects/mate/"
source=()
sha256sums=()

_gitroot=git://github.com/mate-desktop/mate-calc.git
_gitname=mate-calc

build() {
    cd "$srcdir"
    msg "Connecting to GIT server...."

    if [[ -d "$_gitname" ]]; then
        cd "$_gitname" && git pull origin
        msg "The local files are updated."
    else
        git clone "$_gitroot" "$_gitname"
    fi

    msg "GIT checkout done or server timeout"
    msg "Starting build..."

    rm -rf "$srcdir/$_gitname-build"
    git clone "$srcdir/$_gitname" "$srcdir/$_gitname-build"
    cd "$srcdir/$_gitname-build"

    ./autogen.sh --prefix=/usr || return 1
    make || return 1
}

package() {
    cd "$srcdir/$_gitname-build"

    make DESTDIR="${pkgdir}" install || return 1
}