#!/usr/bin/env gnuplot
set size square; set key left top
set title 'log'
set nonlinear x via log10(x) inverse 10**x
set xrange [1:1000]
set xtics (1, 10, 100, 1000)
set ytics (0, 250, 500, 750, 1000)
plot x
pause -1

reset

set size square; set key left top
set title 'rootgram'
set nonlinear x via sqrt(x) inverse x**2
set xrange [0:16]
set xtics (0, 1, 4, 9, 16)
set ytics (0, 4, 8, 12, 16)
plot x
pause -1

reset

set size square; set key right bottom
set title 'broken axis (l:c:r = 1:1:1)'
# 900 -> 200, 1000 -> 300
f(x) = (x <= 100) ? x : (x < 900) ? NaN : x - 700
g(x) = (x <= 100) ? x : x + 700
set nonlinear x via f(x) inverse g(x)
set xrange [0:1000] noextend
set xtics (0, 100, 900, 1000)
plot sample [x=0:100] x, [x=900:1000] x
pause -1

reset

set size square; set key right bottom
set title 'broken axis (l:c:r = 10:1:5)'
# 900 -> 110, 1000 -> 160
f(x) = (x <= 100) ? x : (x < 900) ? NaN : (x - 680) / 2
g(x) = (x <= 100) ? x : 2 * x + 680
set nonlinear x via f(x) inverse g(x)
set xrange [0:1000] noextend
set xtics (0, 50, 100, 900, 1000)
plot sample [x=0:100] x, [x=900:1000] x
pause -1

set nonlinear y via f(y) inverse g(y)
set ytics (0, 50, 100, 900, 1000)
plot sample [x=0:100] x, [x=900:1000] x
pause -1

reset

set size square; set key left top
set title 'nonlog + log (l:r = 1:1)'
# 10 -> 10, 100 -> 20
f(x) = (x <= 10) ? x : 10 * log10(x)
g(x) = (x <= 10) ? x : 10 ** (x / 10)
set nonlinear x via f(x) inverse g(x)
set xrange [0:100] noextend
set xtics (0, 5, 10, 10 ** 1.5, 100)
plot x
pause -1