PowerText.shader

Shader "Custom/PowerText"
{
	Properties
	{
		_MainTex ("Texture", 2D) = "white" {}
		_Noise ("Noise", 2D) = "white" {}
		_Color ("Color", Color) = (1,1,1,1)
		_Frequency ("Shake Frequency", float) = 1
		_Amplitude ("Shake Intensity", float) = 10
	}
	SubShader
	{
		Tags { "RenderType"="Transparent" "Queue"="Transparent"}
		Blend SrcAlpha OneMinusSrcAlpha
		LOD 100
		ZWrite Off
		ZTest Off


		Pass
		{
			CGPROGRAM
			#pragma vertex vert
			#pragma fragment frag
			#pragma geometry geom

			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
				float4 vertColor : COLOR;
			};

			struct v2g
			{
				float2 uv : TEXCOORD0;
				float4 vertex : SV_POSITION;
				float4 vertColor : COLOR;
			};

			struct g2f
			{
				float2 uv : TEXCOORD0;
				float4 vertex : SV_POSITION;
				float4 vertColor : COLOR;
				float2 charPos : TEXCOORD1;
			};

			sampler2D _MainTex;
			sampler2D _Noise;
			float4 _MainTex_ST;
			float4 _Color;

			float _Frequency;
			float _Amplitude;

			float3 HUEtoRGB(in float H)
			{
				float R = abs(H * 6 - 3) - 1;
				float G = 2 - abs(H * 6 - 2);
				float B = 2 - abs(H * 6 - 4);
				return saturate(float3(R,G,B));
			}

			v2g vert (appdata v)
			{
				v2g o;
				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = TRANSFORM_TEX(v.uv, _MainTex);
				o.vertColor = v.vertColor;
				return o;
			}

			[maxvertexcount(3)]
            void geom(triangle v2g IN[3], inout TriangleStream<g2f> triStream) {
				float4 offset = float4(0,0,0,0);

				float3 EdgeA = IN[0].vertex - IN[1].vertex;
				float3 EdgeB = IN[1].vertex - IN[2].vertex;
				float3 EdgeC = IN[2].vertex - IN[0].vertex;

				float3 center;

				if(length(EdgeA) > length(EdgeB) && length(EdgeA) > length(EdgeC))
					center = IN[1].vertex + EdgeA * 0.5;
				else if (length(EdgeB) > length(EdgeC) && length(EdgeB) > length(EdgeA))
					center = IN[2].vertex + EdgeB * 0.5;
				else
					center = IN[0].vertex + EdgeC * 0.5;

				if(IN[0].vertColor.r > 0){
					float2 offsetUV = float2(0, _Time.y * _Frequency) + center.xy * 1000;
					offset = tex2Dlod(_Noise, float4(offsetUV, 0,0))*2-1;
					offset *= _Amplitude;
				}

                g2f o;
				[unroll]
				for(int i=0;i<3;i++){
					o.vertex = IN[i].vertex + offset;
					o.uv = IN[i].uv;
					o.vertColor = IN[i].vertColor;
					o.charPos = center;
					triStream.Append(o);
				}
            }

			fixed4 frag (g2f i) : SV_Target
			{
				// sample the texture
				fixed4 col = 1;
				if(i.vertColor.g <= 0) {
					col = _Color;
				} else {
					col.rgb = HUEtoRGB(fmod(_Time.y + i.charPos.x, 1));
				}
				col.a = tex2D(_MainTex, i.uv).a;

				return col;
			}
			ENDCG
		}
	}
}