Discord Text Manipulation Tool

@echo off
:: ---------------------------------------
:: Discord Text Manipulation Tool
:: By @Inwayn#1590
::
:: Last updated: 11.01.2018, 13:25
:: ---------------------------------------
setlocal enabledelayedexpansion
title Discord Text Manipulation Tool
set f=a,b,c,d,e,f,g,h,j,i,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z
set h=:zero:-0,:one:-1,:two:-2,:three:-3,:four:-4,:five:-5,:six:-6,:seven:-7,:eight:-8,:nine:-9,:hash:-#
set i=:white_check_mark:
set a=BIG
:a
cls
if not "!a!"=="BIG" (
    if not "!a!"=="SMALL" (
        echo Error.
        pause > nul
        exit
    ) else (
        set "b=\"
    )
) else (
    set "b= "
)
set /p t="(!a!) Text: "
if /i "!t!"=="\B" (
    set a=BIG
    goto a
)
if /i "!t!"=="\S" (
    set a=SMALL
    goto a
)
setlocal
set e=!t!
:c
if not defined e goto e
set "g=!e:~0,1!"
for %%A in (!f!) do (
    if /i "%%A"=="!g!" (
        set g=%%A
        goto d
    )
)
if "!g!"==" " goto d
for %%A in (!h!) do (
    for /f "tokens=1,2 delims=-" %%B in ("%%A") do (
        if "%%C"=="!g!" (
            set "o=!o!!b!%%B"
            set "e=!e:~1!"
            goto c
        )
    )
)
if !a!==BIG (
    set "o=!o! **!g!**"
) else (
    set "o=!o!!g!"
)
set "e=!e:~1!"
goto c
:d
if "!g!"==" " (
    if !a!==BIG (
        set "o=!o!      "
    ) else (
        set "o=!o! "
    )
) else (
    set "o=!o!!b!:regional_indicator_!g!:"
)
set "e=!e:~1!"
goto c
:e
if /i "!t!"=="rekt" set "o=!o!!b!!i!"
if /i "!t!"=="not rekt" set "o=!o!!b!:x:"
if /i "!t!"=="prankt" set "o=!o!!b!!i!"
if /i "!t!"=="pranked" set "o=!o!!b!!i!"
if /i "!t!"=="nice meme" set "o=!o!!b!!i!"
if /i "!t!"=="bad meme" set "o=!o!!b!:x:"
if /i "!t!"=="not allowed" set "o=!o!!b!:no_entry_sign:"
if /i "!t!"=="stop" set "o=!o!!b!:no_entry:"
echo !o!
<nul set /p ="!o!"|clip
timeout /t 2 >nul
endlocal
goto a