Advertisement
Guest User

QTGMC for avs 2.60

a guest
Feb 19th, 2019
769
0
Never
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
  1. #-------------------------------------------------------------------#
  2. #                                                                   #
  3. #           QTGMC 3.362, by Vit, 2012, 2018 mod by A.SONY           #
  4. #                                                                   #
  5. #   A high quality deinterlacer using motion-compensated temporal   #
  6. #  smoothing, with a range of features for quality and convenience  #
  7. #          Originally based on TempGaussMC_beta2 by Didée           #
  8. #                                                                   #
  9. #-------------------------------------------------------------------#
  10. #
  11. # Full documentation is in the 'QTGMC' html file that may comes with this script, or even better see avisynth wiki
  12. #
  13. # --- LATEST CHANGES ---
  14. #
  15. # v3.362s
  16. # - some changes for avs+ and avs neo, need IsAvsNeo(), IsAvsPlus() and AvsPlusVersionNumber(), they are in SMDegrain v3.1.2.101s or up
  17. #
  18. # v3.361s
  19. # - update to masktools 2.2.17, use expr in avs+ (for speed up and less RAM usage)
  20. #
  21. # v3.358s
  22. # - new n16 bool (avs+ faster replacement for lsb), and tr2=6
  23. #
  24. # v3.357s
  25. # - high bit depth now basically work in avs+
  26. #
  27. # v3.354s
  28. # - added optional chikuzen PlanarTools for YUY2 using nonyuy2clipin/nonyuy2clipout in AnimeIVTC() v2.20
  29. #
  30. # v3.353s
  31. # - added ndjamena suggestion for maximum temporal radius
  32. # - added DftDither to controle dfttest dither Parameter
  33. #
  34. # v3.352s
  35. # - added useEdiExt
  36. # - added tr0=-1 to use the EdiExt clip (if there is no EdiExt clip then it will not work)
  37. # - rep0 now will be 0 if tr0 < 1
  38. #
  39. # v3.347s
  40. # - fix SourceMatch (bug after new YUY2 method, thanks to ndjamena for report it)
  41. #
  42. # v3.346s
  43. # - EEDI3+NNEDI3 bug fix by ndjamena
  44. # - Renamed DftThreads parameter to FftThreads, to set the ncpu argument of FFT3DFilter (from VS)
  45. # - FFT3DFilter will work now in YUY2, use it with Denoiser="fft3df" (or use NoisePreset)
  46. #
  47. # v3.345s
  48. # - work with SMDegrain_KNLMeansCL now to process chroma too
  49. #
  50. # v3.343s
  51. # - edit in ChromaEdi
  52. # - others
  53. #
  54. # v3.34s (mod) 2016 12 18 (ravewulf idea in another way)
  55. # - Added yadifmod2 (if you need old one use it like this EdiMode="cYadif" or EdiMode="RepcYadif")
  56. # - fast and clean up YUY2 (will work in x64 now, no need to SSETools)
  57. #
  58. # v3.33s (mod) 2016 12 06
  59. # - Add TR2=4 and TR2=5
  60. # - add TV_range bool and dither_luma_rebuild (from SMDegrain) Str and Amp
  61. # - for avsplus now QTGMC_Bob is ready for any 420, not only yv12
  62. #
  63. # v3.33s (mod) 2016 04 11
  64. # - Add KNLMeansCL as another Denoiser to NoiseProcess
  65. # - others
  66. #
  67. # v3.33s (mod) 2016 01 19
  68. # - make QTGMC_deflate/QTGMC_inflate work with YUY2 using masktool2 for avs 2.60
  69. #
  70. # v3.33s (mod) 2015 10 23
  71. # - revert to QTGMC_deflate/QTGMC_inflate quoted from Dogway
  72. #
  73. # v3.33s (mod) 2015 9 10
  74. # - fix Multiple QTGMC Calls
  75. # - others fix
  76. #
  77. # v3.33s (mod) 2015 8 6
  78. # - some changes in bob to speed up
  79. #
  80. # v3.33s (mod) 2015 8 4
  81. # - fix bug in YUY2 with SourceMatch
  82. # - add slice=false to ditherpost to avoid artefacts
  83. #
  84. # v3.33s (mod)
  85. # - fix bob chroma
  86. # - work with new masktool2 for avs 2.60 in YUY2
  87. #
  88. # v3.33d (mod)
  89. # - Added 32 bit precision option through the lsbd (for dfttest and knlmeanscl) and lsb (mdegrain) options.
  90. # - optimized some mask handling a bit as originally suggested by Vit
  91. # - others
  92. #
  93. # v3.33
  94. # - Increased maximum value for Rep0, Rep1 and Rep2 to 7 (from 5). Higher values help with flicker on static detail, potential for minor motion blur
  95. # - Bug fix for the fact that Bob always outputs a BFF clip regardless of field order of input (thanks ajp_anton)
  96. # - Improved generation of noise (NoiseDeint="Generate") for noise bypass / EZKeepGrain
  97. # - Minor change to denoising
  98. #
  99. # v3.32
  100. # - Bugfix with shutter blur and ChromaMotion (thanks Heaud)
  101. # - Tweaked vector recalculation for shutter motion blur
  102. # - Changed defaults for TR2 when using source-match
  103. # - Minor bugfix with SLMode/SLRad on pass-through settings
  104. #
  105. # --- REQUIREMENTS ---
  106. #
  107. # Input colorspaces: YV12, YUY2, others as plugins supports
  108. #
  109. # Core plugins:
  110. #   MVTools2 (2.7.26 or above)
  111. #   MaskTools2 (v2.2.17 or above)
  112. #   NNEDI3 (0.9.4.6 or above)
  113. #   RgTools
  114. #
  115. # Core scripts:
  116. #   SMDegrain (3.1.2.100s or above) unless you set tv_range=false
  117. #   AnimeIVTC (2.20 or above) if you work with YUY2 source
  118. #
  119. # Additional plugins:
  120. #   NNEDI2, NNEDI, EEDI3, EEDI2, TDeInt - if selected directly or via a source-match preset
  121. #   yadifmod2 - for Preset="Ultra Fast" or if selected directly
  122. #   FFT3DFilter - if selected for noise processing
  123. #   dfttest (1.9.4 or above) - if selected for noise processing
  124. #       For FFT3DFilter & ddftest you also need the FFTW3 library (FFTW.org). On Windows the file needed for both is libfftw3f-3.dll. However, for FFT3DFilter
  125. #       the file needs to be called FFTW3.dll, so you will need two copies and rename one. On Windows put the files in your System32 or SysWow64 folder
  126. #   KNLMeansCL - if selected for noise processing
  127. #   AddGrainC - if NoiseDeint="Generate" selected for noise bypass
  128. #   chikuzen PlanarTools - if you work with YUY2 source (not necessarily required but may improve speed)
  129.  
  130.  
  131. # --- GETTING STARTED ---
  132. #
  133. # Install AviSynth and ensure you have at least the core plugins listed in the requirements section above. Put them in the plugins autoload folder.
  134. # To use QTGMC write a script like this:
  135. #   YourSource("yourfile")   # DGDecode_mpeg2source, FFVideoSource, AviSource, whatever your source requires
  136. #   QTGMC( Preset="Slow" )
  137. #   SelectEven()             # Add this line to keep original frame rate, leave it out for smoother doubled frame rate
  138. #
  139. # Save this script with an ".avs" extension. You can now use it as an AVI source for encoding.
  140. #
  141. # The "Preset" used selects sensible settings for a given encoding speed. Choose a preset from:
  142. #   "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast" & "Draft"
  143. # The default preset is "Slower"
  144. # Don't be obsessed with using slower settings as the differences can be small. HD material benefits little from extreme settings (and will be very slow)
  145. # For much faster speeds read the full documentation, the section on 'Multi-threading'
  146. #
  147. # There are many settings for tweaking the script, full details in the main documentation. You can display settings currently being used with "ShowSettings":
  148. #   QTGMC( Preset="Slow", ShowSettings=true )
  149.  
  150.  
  151. function QTGMC( clip Input, string "Preset", int "TR0", int "TR1", int "TR2", int "Rep0", int "Rep1", int "Rep2", string "EdiMode", bool "RepChroma", \
  152.                     int "NNSize", int "NNeurons", int "EdiQual", int "EdiMaxD", string "ChromaEdi", int "EdiThreads", clip "EdiExt", float "Sharpness", \
  153.                     int "SMode", int "SLMode", int "SLRad", int "SOvs", float "SVThin", int "Sbb", int "SrchClipPP", int "SubPel", int "SubPelInterp", \
  154.                     int "BlockSize", int "Overlap", int "Search", int "SearchParam", int "PelSearch", bool "ChromaMotion", bool "TrueMotion", int "Lambda", \
  155.                     int "LSAD", int "PNew", int "PLevel", bool "GlobalMotion", int "DCT", int "ThSAD1", int "ThSAD2", int "ThSCD1", int "ThSCD2", \
  156.                     int "SourceMatch", string "MatchPreset", string "MatchEdi", string "MatchPreset2", string "MatchEdi2", int "MatchTR2", \
  157.                     float "MatchEnhance", int "Lossless", int "NoiseProcess", float "EZDenoise", float "EZKeepGrain", string "NoisePreset", string "Denoiser", \
  158.                     int "FftThreads", bool "DenoiseMC", int "NoiseTR", float "Sigma", bool "ChromaNoise", val "ShowNoise", float "GrainRestore", \
  159.                     float "NoiseRestore", string "NoiseDeint", bool "StabilizeNoise", int "InputType", float "ProgSADMask", int "FPSDivisor", \
  160.                     int "ShutterBlur", float "ShutterAngleSrc", float "ShutterAngleOut", int "SBlurLimit", bool "Border", bool "Precise", string "Tuning", \
  161.                     bool "ShowSettings", string "GlobalNames", string "PrevGlobals", int "ForceTR", \
  162.                     val "BT", val "DetailRestore", val "MotionBlur", val "MBlurLimit", val "NoiseBypass", float "Str", float "Amp", bool "TV_range", bool "useEdiExt", int "DftDither", bool "lsbd", bool "lsb", bool "n16" )
  163. {
  164.     # EdiMode="RepcYadif"/"cYadif" require the Yadif plugin, which doesn't autoload. Typically the calling script would load it.
  165.  
  166.     # Temporary Warnings
  167.     Assert( !defined(BT),            "QTGMC: Setting BT has been replaced by setting NoiseTR" )
  168.     Assert( !defined(DetailRestore), "QTGMC: Setting DetailRestore has been renamed to GrainRestore" )
  169.     Assert( !defined(MotionBlur),    "QTGMC: Setting MotionBlur has been renamed to ShutterBlur" )
  170.     Assert( !defined(MBlurLimit),    "QTGMC: Setting MBlurLimit has been renamed to SBlurLimit" )
  171.     Assert( !defined(NoiseBypass),   "QTGMC: Setting NoiseBypass has been renamed to NoiseProcess" )
  172.  
  173.     #---------------------------------------
  174.     # Presets
  175.     lsbd         = default( lsbd,      false)
  176.     lsb          = default( lsb,       false)
  177.     n16          = default( n16,       false)
  178.     useEdiExt    = default( useEdiExt, false)
  179.     Str          = default( Str,        1.0 )
  180.     Amp          = default( Amp,     0.0625 )
  181.     TV_range     = default( TV_range,   !(Isrgb(input)))
  182.  
  183.         sisphbd = AvsPlusVersionNumber > 2294
  184.     sisphbd  ? Assert( !(Input.BitsPerComponent() > 8 && (lsb || lsbd)), "QTGMC: lsb hack is not Compatible with native high bit depth" ) : nop()
  185.  
  186.     # Select presets / tuning
  187.     Preset = default( Preset, "Slower" )
  188.     pNum = (Preset == "Placebo"   ) ? 0 : \
  189.            (Preset == "Very Slow" ) ? 1 : \
  190.            (Preset == "Slower"    ) ? 2 : \
  191.            (Preset == "Slow"      ) ? 3 : \
  192.            (Preset == "Medium"    ) ? 4 : \
  193.            (Preset == "Fast"      ) ? 5 : \
  194.            (Preset == "Faster"    ) ? 6 : \
  195.            (Preset == "Very Fast" ) ? 7 : \
  196.            (Preset == "Super Fast") ? 8 : \
  197.            (Preset == "Ultra Fast") ? 9 : \
  198.            (Preset == "Draft"     ) ? 10 : 11
  199.     Assert( pNum  < 11, "'Preset' choice is invalid" )
  200.  
  201.     mpNum1 = (!defined(MatchPreset))       ? ((pNum + 3 <= 9) ? (pNum + 3) : 9) : \
  202.              (MatchPreset == "Placebo"   ) ? 0 : \
  203.              (MatchPreset == "Very Slow" ) ? 1 : \
  204.              (MatchPreset == "Slower"    ) ? 2 : \
  205.              (MatchPreset == "Slow"      ) ? 3 : \
  206.              (MatchPreset == "Medium"    ) ? 4 : \
  207.              (MatchPreset == "Fast"      ) ? 5 : \
  208.              (MatchPreset == "Faster"    ) ? 6 : \
  209.              (MatchPreset == "Very Fast" ) ? 7 : \
  210.              (MatchPreset == "Super Fast") ? 8 : \
  211.              (MatchPreset == "Ultra Fast") ? 9 : \
  212.              (MatchPreset == "Draft"     ) ? 10 : 11
  213.     Assert( mpNum1 < 10, "'MatchPreset' choice is invalid/unsupported" )
  214.     MatchPreset = Select( mpNum1, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  215.  
  216.     mpNum2 = (!defined(MatchPreset2))       ? ((mpNum1 + 2 <= 9) ? (mpNum1 + 2) : 9) : \
  217.              (MatchPreset2 == "Placebo"   ) ? 0 : \
  218.              (MatchPreset2 == "Very Slow" ) ? 1 : \
  219.              (MatchPreset2 == "Slower"    ) ? 2 : \
  220.              (MatchPreset2 == "Slow"      ) ? 3 : \
  221.              (MatchPreset2 == "Medium"    ) ? 4 : \
  222.              (MatchPreset2 == "Fast"      ) ? 5 : \
  223.              (MatchPreset2 == "Faster"    ) ? 6 : \
  224.              (MatchPreset2 == "Very Fast" ) ? 7 : \
  225.              (MatchPreset2 == "Super Fast") ? 8 : \
  226.              (MatchPreset2 == "Ultra Fast") ? 9 : \
  227.              (MatchPreset2 == "Draft"     ) ? 10 : 11
  228.     Assert( mpNum2 < 10, "'MatchPreset2' choice is invalid/unsupported" )
  229.     MatchPreset2 = Select( mpNum2, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  230.  
  231.     NoisePreset = default( NoisePreset, "Fast" )
  232.     npNum = (NoisePreset == "Slower" ) ? 0 : \
  233.             (NoisePreset == "Slow"   ) ? 1 : \
  234.             (NoisePreset == "Medium" ) ? 2 : \
  235.             (NoisePreset == "Fast"   ) ? 3 : \
  236.             (NoisePreset == "Faster" ) ? 4 : 5
  237.     Assert( npNum < 5, "'NoisePreset' choice is invalid" )
  238.  
  239.     Tuning = default( Tuning, "None" )
  240.     tNum = (Tuning == "None"  ) ? 0 : \
  241.            (Tuning == "DV-SD" ) ? 1 : \
  242.            (Tuning == "DV-HD" ) ? 2 : 3
  243.     Assert( tNum < 3, "'Tuning' choice is invalid" )
  244.  
  245.     # Tunings only affect blocksize in this version
  246.     bs = Select( tNum,  16, 16, 32 )
  247.     bs2 = (bs >= 16) ? 32 : bs * 2
  248.  
  249.     #                                                               Very                                                        Very      Super      Ultra
  250.     # Preset groups:                                     Placebo    Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast       Fast       Draft
  251.     TR0          = default( TR0,          Select( pNum,  2,         2,        2,        2,        2,        2,        1,        1,        1,         1,         0      ) )
  252.     TR1          = default( TR1,          Select( pNum,  2,         2,        2,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  253.     TR2X         = default( TR2,          Select( pNum,  3,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  254.     Rep0         = defined(Rep0) ? Rep0 : TR0 < 1 ? 0 : undefined()
  255.     Rep0         = default( Rep0,         Select( pNum,  4,         4,        4,        4,        3,        3,        0,        0,        0,         0,         0      ) )
  256.     Rep1         = default( Rep1,         Select( pNum,  0,         0,        0,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  257.     Rep2         = default( Rep2,         Select( pNum,  4,         4,        4,        4,        4,        4,        4,        4,        3,         3,         0      ) )
  258.     EdiMode      = default( EdiMode,      Select( pNum, "NNEDI3",  "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3",  "RepYadif","Bob"   ) )
  259.     NNSize       = default( NNSize,       Select( pNum,  1,         1,        1,        1,        5,        5,        4,        4,        4,         4,         4      ) )
  260.     NNeurons     = default( NNeurons,     Select( pNum,  2,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  261.     EdiQual      = default( EdiQual,      Select( pNum,  1,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  262.     EdiMaxD      = default( EdiMaxD,      Select( pNum,  12,        10,       8,        7,        7,        6,        6,        5,        4,         4,         4      ) )
  263.     SMode        = default( SMode,        Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        2,         2,         0      ) )
  264.     SLModeX      = default( SLMode,       Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        0,         0,         0      ) )
  265.     SLRad        = default( SLRad,        Select( pNum,  3,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  266.     Sbb          = default( Sbb,          Select( pNum,  3,         1,        1,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  267.     SrchClipPP   = default( SrchClipPP,   Select( pNum,  3,         3,        3,        3,        3,        2,        2,        2,        1,         1,         0      ) )
  268.     SubPel       = default( SubPel,       Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  269.     Blocksize    = default( Blocksize,    Select( pNum,  bs,        bs,       bs,       bs,       bs,       bs,       bs2,      bs2,      bs2,       bs2,       bs2    ) )
  270.     bs = Blocksize
  271.     Overlap      = default( Overlap,      Select( pNum,  bs/2,      bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/4,     bs/4,      bs/4,      bs/4   ) )
  272.     Search       = default( Search,       Select( pNum,  5,         4,        4,        4,        4,        4,        4,        4,        0,         0,         0      ) )
  273.     SearchParam  = default( SearchParam,  Select( pNum,  2,         2,        2,        2,        2,        2,        2,        1,        1,         1,         1      ) )
  274.     PelSearch    = default( PelSearch,    Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  275.     ChromaMotion = default( ChromaMotion, Select( pNum,  true,      true,     true,     false,    false,    false,    false,    false,    false,     false,     false  ) )
  276.     Precise      = default( Precise,      Select( pNum,  true,      true,     false,    false,    false,    false,    false,    false,    false,     false,     false  ) )
  277.     ProgSADMask  = default( ProgSADMask,  Select( pNum,  10.0,      10.0,     10.0,     10.0,     10.0,     0.0,      0.0,      0.0,      0.0,       0.0,       0.0    ) )
  278.  
  279.     # Noise presets                                           Slower     Slow       Medium     Fast       Faster
  280.     Denoiser       = default( Denoiser,       Select( npNum, "dfttest", "dfttest", "dfttest", "fft3df",  "fft3df" ) )
  281.     DenoiseMC      = default( DenoiseMC,      Select( npNum,  true,      true,      false,     false,     false   ) )
  282.     NoiseTR        = default( NoiseTR,        Select( npNum,  2,         1,         1,         1,         0       ) )
  283.     NoiseDeint     = default( NoiseDeint,     Select( npNum, "Generate","Bob",      "",        "",        ""      ) )
  284.     StabilizeNoise = default( StabilizeNoise, Select( npNum,  true,      true,      true,      false,     false   ) )
  285.  
  286.     # The basic source-match step corrects and re-runs the interpolation of the input clip. So it initialy uses same interpolation settings as the main preset
  287.     SourceMatch   = default( SourceMatch, 0 )
  288.     MatchNNSize   = NNSize
  289.     MatchNNeurons = NNeurons
  290.     MatchEdiMaxD  = EdiMaxD
  291.     MatchEdiQual  = EdiQual
  292.  
  293.     # However, can use a faster initial interpolation when using source-match allowing the basic source-match step to "correct" it with higher quality settings
  294.     Assert( SourceMatch == 0 || mpNum1 >= pNum, "'MatchPreset' cannot use a slower setting than 'Preset'" )
  295.     #                                                                    Very                                                        Very      Super     Ultra
  296.     # Basic source-match presets                                Placebo  Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  297.     NNSize   = (SourceMatch == 0) ? NNSize   : Select( mpNum1,  1,       1,        1,        1,        5,        5,        4,        4,        4,        4     )
  298.     NNeurons = (SourceMatch == 0) ? NNeurons : Select( mpNum1,  2,       2,        1,        1,        1,        0,        0,        0,        0,        0     )
  299.     EdiMaxD  = (SourceMatch == 0) ? EdiMaxD  : Select( mpNum1,  12,      10,       8,        7,        7,        6,        6,        5,        4,        4     )
  300.     EdiQual  = (SourceMatch == 0) ? EdiQual  : Select( mpNum1,  1,       1,        1,        1,        1,        1,        1,        1,        1,        1     )
  301.     TempEdi  = EdiMode # Main interpolation is actually done by basic-source match step when enabled, so a little swap and wriggle is needed
  302.     EdiMode  = (SourceMatch == 0) ? EdiMode  : default( MatchEdi, ((mpNum1 < 9) ?  EdiMode : "Yadif") ) # Force Yadif for "Ultra Fast" basic source match
  303.     MatchEdi = TempEdi
  304.  
  305.     #                                                          Very                                                        Very      Super     Ultra
  306.     # Refined source-match presets                   Placebo   Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  307.     MatchEdi2 = default( MatchEdi2, Select( mpNum2, "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "TDeint",  ""    ) )
  308.     MatchNNSize2                  = Select( mpNum2,  1,        1,        1,        1,        5,        5,        4,        4,        4,        4     )
  309.     MatchNNeurons2                = Select( mpNum2,  2,        2,        1,        1,        1,        0,        0,        0,        0,        0     )
  310.     MatchEdiMaxD2                 = Select( mpNum2,  12,       10,       8,        7,        7,        6,        6,        5,        4,        4     )
  311.     MatchEdiQual2                 = Select( mpNum2,  1,        1,        1,        1,        1,        1,        1,        1,        1,        1     )
  312.  
  313.  
  314.     #---------------------------------------
  315.     # Settings
  316.  
  317.     # Core and Interpolation defaults
  318.     TR2        = (SourceMatch > 0) ? default(TR2, ((TR2X == 0) ? 1 : TR2X)) : TR2X  # ***TR2 defaults always at least 1 when using source-match***
  319.     RepChroma  = default( RepChroma,  true )
  320.     EdiThreads = default( EdiThreads, 0    )
  321.     ChromaEdi  = default( ChromaEdi,  ""   )
  322.     NNeurons   = (EdiMode == "NNEDI2" && NNeurons > 2) ? 2 : NNeurons # Smaller range for NNeurons in NNEDI2 (which calls it nsize)
  323.     EdiQual    = (EdiMode == "EEDI3+NNEDI3" || EdiMode == "NNEDI3") && EdiQual > 2 ? 2 : EdiQual  # Smaller range for EdiQual in NNEDI3
  324.  
  325.     # Source-match / lossless defaults
  326.     MatchTR1     = TR1
  327.     MatchTR2     = default( MatchTR2,     1   )
  328.     MatchEnhance = default( MatchEnhance, 0.5 )
  329.     Lossless     = default( Lossless,     0   )
  330.     Assert( Lossless <= 2, "Lossless setting only supports mode 1 ('true lossless') and mode 2 ('fake lossless') - see documentation in script and consider source-match settings" )
  331.  
  332.     # Sharpness defaults. Sharpness default is always 1.0 (0.2 with source-match), but adjusted to give roughly same sharpness for all settings
  333.     SMode      = (defined(Sharpness) && Sharpness == 0.0) ? 0 : SMode
  334.     SLMode     = (SourceMatch > 0) ? default(SLMode, 0) : SLModeX  # ***Sharpness limiting disabled by default for source-match***
  335.     SLMode     = (SLRad <= 0)      ? 0 : SLMode
  336.     spatialSL  = (SLMode == 1 || SLMode == 3)
  337.     temporalSL = (SLMode == 2 || SLMode == 4)
  338.     Sharpness  = default( Sharpness, (SMode == 0) ? 0.0 : ((SourceMatch > 0) ? 0.2 : 1.0) )      # Default sharpness is 1.0, or 0.2 if using source-match
  339.     sharpMul   = (temporalSL) ? 2 : (spatialSL) ? 1.5 : 1                                        # Adjust sharpness based on other settings
  340.     sharpAdj   = Sharpness * (sharpMul * (0.2 + TR1*0.15 + TR2*0.25) + ((SMode == 1) ? 0.1 : 0)) # [This needs a bit more refinement]
  341.     Sbb        = (SMode == 0) ? 0 : Sbb
  342.     SOvs       = default( SOvs,   0   )
  343.     SVThin     = default( SVThin, 0.0 )
  344.  
  345.     # Noise processing settings
  346.     Assert( !defined(EZDenoise) || EZDenoise <= 0.0 || !defined(EZKeepGrain) || EZKeepGrain <= 0.0, "QTGMC: EZDenoise and EZKeepGrain cannot be used together" )
  347.     NoiseProcess = defined(NoiseProcess) ? NoiseProcess : \
  348.                    (defined(EZDenoise)   && EZDenoise   > 0.0)    ? 1 : \
  349.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0)    ? 2 : \
  350.                    (Preset == "Placebo" || Preset == "Very Slow") ? 2 : 0
  351.     GrainRestore = defined(GrainRestore) ? GrainRestore : \
  352.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  353.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.3 * sqrt(EZKeepGrain) : \
  354.                                                                 Select( NoiseProcess, 0.0, 0.7, 0.3 )
  355.     NoiseRestore = defined(NoiseRestore) ? NoiseRestore : \
  356.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  357.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.1 * sqrt(EZKeepGrain) : \
  358.                                                                 Select( NoiseProcess, 0.0, 0.3, 0.1 )
  359.     Sigma        = defined(Sigma)       ? Sigma : \
  360.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? EZDenoise : \
  361.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 4.0 * EZKeepGrain : 2.0
  362.     FftThreads   = default( FftThreads, EdiThreads )
  363.     ChromaNoise  = default( ChromaNoise, false )
  364.     ShowNoise    = default( ShowNoise, 0.0 )
  365.     ShowNoise    = IsBool( ShowNoise ) ? (ShowNoise ? 10.0 : 0.0) : ShowNoise
  366.     NoiseProcess = (ShowNoise > 0.0)   ? 2   : NoiseProcess
  367.     NoiseRestore = (ShowNoise > 0.0)   ? 1.0 : NoiseRestore
  368.     NoiseTR      = (NoiseProcess == 0) ? 0   : NoiseTR
  369.     GrainRestore = (NoiseProcess == 0) ? 0.0 : GrainRestore
  370.     NoiseRestore = (NoiseProcess == 0) ? 0.0 : NoiseRestore
  371.     totalRestore = GrainRestore + NoiseRestore
  372.     StabilizeNoise = (totalRestore <= 0) ? false : StabilizeNoise
  373.     noiseTD  = Select( NoiseTR, 1, 3, 5 )
  374.     noiseCentre = (Denoiser == "dfttest") ? "128" : "128.5"
  375.  
  376.     # MVTools settings
  377.     SubPelInterp = default( SubPelInterp, 2     )
  378.     TrueMotion   = default( TrueMotion,   false )
  379.     GlobalMotion = default( GlobalMotion, true  )
  380.     Lambda       = default( Lambda, ((TrueMotion) ? 1000 : 100 ) * (BlockSize*BlockSize)/(8*8) )
  381.     LSAD         = default( LSAD,    (TrueMotion) ? 1200 : 400 )
  382.     PNew         = default( PNew,    (TrueMotion) ? 50   : 25  )
  383.     PLevel       = default( PLevel,  (TrueMotion) ? 1    : 0   )
  384.     DCT          = default( DCT,     0          )
  385.     ThSAD1       = default( ThSAD1,  10 * 8*8   )
  386.     ThSAD2       = default( ThSAD2,   4 * 8*8   )
  387.     ThSCD1       = default( ThSCD1,  180        )
  388.     ThSCD2       = default( ThSCD2,  98         )
  389.  
  390.     # Motion blur settings
  391.     FPSDivisor  = default( FPSDivisor, 1 )
  392.     ShutterBlur = default( ShutterBlur, 0 )
  393.     ShutterAngleSrc = default( ShutterAngleSrc, 180 )
  394.     ShutterAngleOut = default( ShutterAngleOut, 180 )
  395.     SBlurLimit  = default( SBlurLimit, 4 )
  396.     ShutterBlur = (ShutterAngleOut * FPSDivisor == ShutterAngleSrc) ? 0 : ShutterBlur  # If motion blur output is same as input
  397.  
  398.     # Miscellaneous
  399.     InputType      = default( InputType,     0        )
  400.     Border         = default( Border,        false    )
  401.     ShowSettings   = default( ShowSettings,  false    )
  402.     GlobalNames    = default( GlobalNames,  "QTGMC"   )
  403.     PrevGlobals    = default( PrevGlobals,  "Replace" )
  404.     ForceTR        = default( ForceTR,       0        )
  405.     ReplaceGlobals = (PrevGlobals == "Replace" || PrevGlobals == "Reuse") # If reusing existing globals put them back afterwards - simplifies logic later
  406.     ReuseGlobals   = (PrevGlobals == "Reuse")
  407.     ProgSADMask    = (InputType != 2 && InputType != 3) ? 0.0 : ProgSADMask
  408.     rgBlur         = (Precise) ? 11 : 12
  409.  
  410.     # Get maximum temporal radius needed
  411.     maxTR = (temporalSL)       ? SLRad : 0
  412.     maxTR = max(MatchTR2, TR1, TR2, NoiseTR, maxTR)
  413.     maxTR = (ProgSADMask > 0.0 || StabilizeNoise || ShutterBlur > 0) ? (maxTR > 1 ? maxTR : 1) : maxTR
  414.     maxTR = max(ForceTR, MaxTR)
  415.  
  416.  
  417.     #---------------------------------------
  418.     # Pre-Processing
  419.  
  420.     w = Input.Width()
  421.     h = Input.Height()
  422.     yuy2 = Input.IsYUY2()
  423.     epsilon = 0.0001
  424.  
  425.     # Reverse "field" dominance for progressive repair mode 3 (only difference from mode 2)
  426.     compl = (InputType == 3) ? Input.ComplementParity() : Input
  427.  
  428.     # Pad vertically during processing (to prevent artefacts at top & bottom edges)
  429.     clip = (Border) ? compl.PointResize( w,h+8, 0,-4,0,h+8+epsilon ) : compl
  430.     h = (Border) ? h+8 : h
  431.  
  432.     # Calculate padding needed for MVTools super clips to avoid crashes [fixed in latest MVTools, but keeping this code for a while]
  433.     hpad = w - (Int((w - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  434.     vpad = h - (Int((h - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  435.     hpad = (hpad > 8) ? hpad : 8 # But match default padding if possible
  436.     vpad = (vpad > 8) ? vpad : 8
  437.  
  438.  
  439.     #---------------------------------------
  440.     # Motion Analysis
  441.  
  442.     # >>> Planar YUY2 for motion analysis, interleaved whilst blurring search clip
  443.     planarClip = yuy2 ? clip.nonyuy2clipin(true) : clip
  444.  
  445.     # Bob the input as a starting point for motion search clip
  446.     bobbed = (InputType == 0) ? useEdiExt ? isyuy2(EdiExt) ? EdiExt.nonyuy2clipin(true) : EdiExt : planarClip.QTGMC_Bob( 0,0.5 ) : \
  447.              (InputType == 1) ? planarClip : \
  448.                                 planarClip.Blur( 0,1 )
  449.  
  450.     # If required, get any existing global clips with a matching "GlobalNames" setting. Unmatched values get NOP (= 0)
  451.     srchClip  = QTGMC_GetUserGlobal( GlobalNames, "srchClip",  ReuseGlobals )
  452.     srchSuper = QTGMC_GetUserGlobal( GlobalNames, "srchSuper", ReuseGlobals )
  453.     bVec1     = QTGMC_GetUserGlobal( GlobalNames, "bVec1",     ReuseGlobals )
  454.     fVec1     = QTGMC_GetUserGlobal( GlobalNames, "fVec1",     ReuseGlobals )
  455.     bVec2     = QTGMC_GetUserGlobal( GlobalNames, "bVec2",     ReuseGlobals )
  456.     fVec2     = QTGMC_GetUserGlobal( GlobalNames, "fVec2",     ReuseGlobals )
  457.     bVec3     = QTGMC_GetUserGlobal( GlobalNames, "bVec3",     ReuseGlobals )
  458.     fVec3     = QTGMC_GetUserGlobal( GlobalNames, "fVec3",     ReuseGlobals )
  459.     bVec4     = QTGMC_GetUserGlobal( GlobalNames, "bVec4",     ReuseGlobals )
  460.     fVec4     = QTGMC_GetUserGlobal( GlobalNames, "fVec4",     ReuseGlobals )
  461.     bVec5     = QTGMC_GetUserGlobal( GlobalNames, "bVec5",     ReuseGlobals )
  462.     fVec5     = QTGMC_GetUserGlobal( GlobalNames, "fVec5",     ReuseGlobals )
  463.     bVec6     = QTGMC_GetUserGlobal( GlobalNames, "bVec6",     ReuseGlobals )
  464.     fVec6     = QTGMC_GetUserGlobal( GlobalNames, "fVec6",     ReuseGlobals )
  465.  
  466.     CMmt = ChromaMotion ? 3   :  1
  467.     CMts = ChromaMotion ? 255 :  0
  468.     CMrg = ChromaMotion ? 12  : -1
  469.  
  470.     # The bobbed clip will shimmer due to being derived from alternating fields. Temporally smooth over the neighboring frames using a binomial kernel. Binomial
  471.     # kernels give equal weight to even and odd frames and hence average away the shimmer. The two kernels used are [1 2 1] and [1 4 6 4 1] for radius 1 and 2.
  472.     # These kernels are approximately Gaussian kernels, which work well as a prefilter before motion analysis (hence the original name for this script)
  473.     # Create linear weightings of neighbors first                                                 -2    -1     0    1     2
  474.     ts1 = (!IsClip(srchClip) && TR0 > 0) ? bobbed.TemporalSoften( 1, 255,CMts, 28, 2 ) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  475.     ts2 = (!IsClip(srchClip) && TR0 > 1) ? bobbed.TemporalSoften( 2, 255,CMts, 28, 2 ) : NOP()  # 0.20  0.20  0.20  0.20  0.20
  476.  
  477.     # Combine linear weightings to give binomial weightings - TR0=0: (1), TR0=1: (1:2:1), TR0=2: (1:4:6:4:1)
  478.     binomial0 = IsClip(srchClip) ? NOP() : \
  479.     TR0 == -1 && defined(EdiExt) ? isyuy2(EdiExt) ? EdiExt.nonyuy2clipin(true) : EdiExt : \
  480.                 (TR0 == 0)       ? bobbed : \
  481.                 (TR0 == 1)       ? (ChromaMotion ? ts1.Merge( bobbed, 0.25 ) : ts1.MergeLuma( bobbed, 0.25 )) : \
  482.                                    (ChromaMotion ? ts1.Merge( ts2, 0.357 ).Merge( bobbed, 0.125 ) : ts1.MergeLuma( ts2, 0.357 ).MergeLuma( bobbed, 0.125 ))
  483.  
  484.     # Remove areas of difference between temporal blurred motion search clip and bob that are not due to bob-shimmer - removes general motion blur
  485.     repair0 = (IsClip(srchClip) || Rep0 == 0) ? binomial0 : binomial0.QTGMC_KeepOnlyBobShimmerFixes( bobbed, Rep0, (RepChroma && ChromaMotion) )
  486.  
  487.     # Blur image and soften edges to assist in motion matching of edge blocks. Blocks are matched by SAD (sum of absolute differences between blocks), but even
  488.     # a slight change in an edge from frame to frame will give a high SAD due to the higher contrast of edges
  489.     spatialBlur = (IsClip(srchClip) || SrchClipPP == 0) ? NOP() : \
  490.                   (SrchClipPP == 1) ? repair0.BilinearResize( w/2, h/2 ).RemoveGrain( 12,CMrg).BilinearResize( w, h ) : \
  491.                                       repair0.RemoveGrain( 12,CMrg).GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=2 )
  492.  
  493.     spatialBlur = (IsClip(spatialBlur) && SrchClipPP > 1) ? (ChromaMotion ? spatialBlur.Merge( repair0, 0.1 ) : spatialBlur.MergeLuma( repair0, 0.1 )) : spatialBlur
  494.     tweaked     = (!IsClip(srchClip) && SrchClipPP > 1) ? mt_lutxy( repair0, bobbed, "x 3 scalef + y < x 3 scalef + x 3 scalef - y > x 3 scalef - y ? ?", use_expr=2, U=CMmt,V=CMmt ) : NOP()
  495.     srchcheck   = IsClip(srchClip)
  496.     srchClip    = srchcheck         ? srchClip : \
  497.                   (SrchClipPP == 0) ? repair0 : \
  498.                   (SrchClipPP < 3)  ? spatialBlur : \
  499.                                       spatialBlur.mt_lutxy( tweaked, "x 7 scalef + y < x 2 scalef + x 7 scalef - y > x 2 scalef - x 51 * y 49 * + 100 / ? ?", use_expr=2, U=CMmt,V=CMmt )
  500.     srchClip    = tv_range && !srchcheck ? srchClip.Dither_Luma_Rebuild(S0=Str,c=Amp,slice=false,lsb=lsb,uv=CMmt) : srchClip
  501.     # Calculate forward and backward motion vectors from motion search clip
  502.     srchSuper = IsClip(srchSuper) ? srchSuper : \
  503.                 (maxTR > 0)       ? srchClip.MSuper( pel=SubPel, sharp=SubPelInterp, hpad=hpad, vpad=vpad, chroma=ChromaMotion ) : NOP()
  504.     bVec6 = IsClip(bVec6) ? bVec6 : \
  505.             (maxTR > 5)   ? srchSuper.MAnalyse( isb=true,  delta=6, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  506.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  507.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  508.     bVec5 = IsClip(bVec5) ? bVec5 : \
  509.             (maxTR > 4)   ? srchSuper.MAnalyse( isb=true,  delta=5, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  510.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  511.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  512.     bVec4 = IsClip(bVec4) ? bVec4 : \
  513.             (maxTR > 3)   ? srchSuper.MAnalyse( isb=true,  delta=4, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  514.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  515.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  516.     bVec3 = IsClip(bVec3) ? bVec3 : \
  517.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=true,  delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  518.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  519.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  520.     bVec2 = IsClip(bVec2) ? bVec2 : \
  521.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=true,  delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  522.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  523.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  524.     bVec1 = IsClip(bVec1) ? bVec1 : \
  525.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=true,  delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  526.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  527.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  528.     fVec1 = IsClip(fVec1) ? fVec1 : \
  529.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=false, delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  530.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  531.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  532.     fVec2 = IsClip(fVec2) ? fVec2 : \
  533.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=false, delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  534.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  535.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  536.     fVec3 = IsClip(fVec3) ? fVec3 : \
  537.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=false, delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  538.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  539.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  540.     fVec4 = IsClip(fVec4) ? fVec4 : \
  541.             (maxTR > 3)   ? srchSuper.MAnalyse( isb=false, delta=4, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  542.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  543.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  544.     fVec5 = IsClip(fVec5) ? fVec5 : \
  545.             (maxTR > 4)   ? srchSuper.MAnalyse( isb=false, delta=5, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  546.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  547.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  548.     fVec6 = IsClip(fVec6) ? fVec6 : \
  549.             (maxTR > 5)   ? srchSuper.MAnalyse( isb=false, delta=6, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  550.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  551.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  552.  
  553.     # Expose search clip, motion search super clip and motion vectors to calling script through globals
  554.     QTGMC_SetUserGlobal( GlobalNames, "srchClip",  srchClip,  ReplaceGlobals )
  555.     QTGMC_SetUserGlobal( GlobalNames, "srchSuper", srchSuper, ReplaceGlobals )
  556.     QTGMC_SetUserGlobal( GlobalNames, "bVec1",     bVec1,     ReplaceGlobals )
  557.     QTGMC_SetUserGlobal( GlobalNames, "fVec1",     fVec1,     ReplaceGlobals )
  558.     QTGMC_SetUserGlobal( GlobalNames, "bVec2",     bVec2,     ReplaceGlobals )
  559.     QTGMC_SetUserGlobal( GlobalNames, "fVec2",     fVec2,     ReplaceGlobals )
  560.     QTGMC_SetUserGlobal( GlobalNames, "bVec3",     bVec3,     ReplaceGlobals )
  561.     QTGMC_SetUserGlobal( GlobalNames, "fVec3",     fVec3,     ReplaceGlobals )
  562.     QTGMC_SetUserGlobal( GlobalNames, "bVec4",     bVec4,     ReplaceGlobals )
  563.     QTGMC_SetUserGlobal( GlobalNames, "fVec4",     fVec4,     ReplaceGlobals )
  564.     QTGMC_SetUserGlobal( GlobalNames, "bVec5",     bVec5,     ReplaceGlobals )
  565.     QTGMC_SetUserGlobal( GlobalNames, "fVec5",     fVec5,     ReplaceGlobals )
  566.     QTGMC_SetUserGlobal( GlobalNames, "bVec6",     bVec6,     ReplaceGlobals )
  567.     QTGMC_SetUserGlobal( GlobalNames, "fVec6",     fVec6,     ReplaceGlobals )
  568.  
  569.  
  570.     #---------------------------------------
  571.     # Noise Processing
  572.  
  573.     # >>>> Interleaved YUY2 for denoising, planar whilst pre-motion compensating
  574.  
  575.     # Expand fields to full frame size before extracting noise (allows use of motion vectors which are frame-sized)
  576.     fullClip  = (NoiseProcess == 0) ? NOP() : \
  577.                 (InputType > 0)     ? clip : \
  578.                                       clip.QTGMC_Bob( 0,1.0 )
  579.     fullClip  = (yuy2 && NoiseTR > 0) ? fullClip.nonyuy2clipin(true) : fullClip
  580.     fullSuper = (NoiseTR > 0)         ? fullClip.MSuper( pel=SubPel, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise ) : NOP() #TEST chroma OK?
  581.  
  582.     # Create a motion compensated temporal window around current frame and use to guide denoisers
  583.     noiseWindow = (NoiseProcess == 0) ? NOP() : \
  584.                   (!DenoiseMC)        ? fullClip : \
  585.                   (NoiseTR == 0)      ? fullClip : \
  586.                   (NoiseTR == 1)      ? Interleave( fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  587.                                                     fullClip, \
  588.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) ) : \
  589.                                         Interleave( fullClip.MCompensate( fullSuper, fVec2, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  590.                                                     fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  591.                                                     fullClip, \
  592.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  593.                                                     fullClip.MCompensate( fullSuper, bVec2, thSCD1=ThSCD1,thSCD2=ThSCD2 ) )
  594.     noiseWindow = yuy2 && (Denoiser == "fft3df") && NoiseTR > 0 ? noiseWindow.nonyuy2clipout(true) : noiseWindow
  595.     dnWindow = (NoiseProcess == 0)      ? NOP() : \
  596.                (Denoiser == "dfttest")  ? noiseWindow.dfttest( Y=true, U=ChromaNoise, V=ChromaNoise, sigma=Sigma*4, tbsize=noiseTD, threads=FftThreads, Dither=DftDither, lsb=lsbd ) : \
  597.             (Denoiser == "KNLMeansCL")  ? noiseWindow.SMDegrain_KNLMeansCL(Chroma=ChromaNoise, lsb=lsbd, a=2, d=NoiseTR, h=Sigma, device_type="GPU" ) : \
  598.                                           noiseWindow.FFT3DFilter( plane=(ChromaNoise ? 4 : 0), sigma=Sigma, bt=noiseTD, ncpu=FftThreads )
  599.     dnwindow = (Denoiser == "KNLMeansCL" || Denoiser == "dfttest") && (NoiseProcess != 0) && lsbd ? dnWindow.ditherpost(mode=6, U=ChromaNoise?3:2, V=ChromaNoise?3:2, slice=false) : dnWindow
  600.     dnwindow = (Denoiser == "KNLMeansCL" || Denoiser == "dfttest") && (NoiseProcess != 0) && yuy2 ? dnWindow.nonyuy2clipout(true) : dnWindow
  601.  
  602.     # Rework denoised clip to match source format - various code paths here: discard the motion compensation window, discard doubled lines (from point resize)
  603.     # Also reweave to get interlaced noise if source was interlaced (could keep the full frame of noise, but it will be poor quality from the point resize)
  604.     denoised = (NoiseProcess == 0) ? NOP() : \
  605.                (!DenoiseMC)        ? ((InputType > 0) ? dnWindow : dnWindow.SeparateFields().SelectEvery( 4, 0,3 ).Weave()) : \
  606.                (InputType > 0)     ? ((NoiseTR == 0)  ? dnWindow : dnWindow.SelectEvery( noiseTD, NoiseTR )) : \
  607.                                      dnWindow.SeparateFields().SelectEvery( noiseTD*4, NoiseTR*2,NoiseTR*6+3 ).Weave()
  608.  
  609.     # >>>> Switch to planar YUY2 for noise bypass
  610.  
  611.     CNmt1   = ChromaNoise ? 3 : 1
  612.     CNmt2   = ChromaNoise ? 3 : 2
  613.     CNmt128 = ChromaNoise ? 3 : -128
  614.  
  615.     # Get actual noise from difference. Then 'deinterlace' where we have weaved noise - create the missing lines of noise in various ways
  616.     planarDenoised = (NoiseProcess == 0) ? NOP() : yuy2 ? denoised.nonyuy2clipin(true) : denoised
  617.     noise = (totalRestore > 0.0)  ? mt_makediff( planarClip, planarDenoised, U=CNmt1,V=CNmt1 ) : NOP()
  618.     deintNoise = (NoiseProcess == 0 || totalRestore == 0.0) ? NOP() : \
  619.                  (InputType != 0)                           ? noise : \
  620.                  (NoiseDeint == "Bob")                      ? noise.QTGMC_Bob( 0,0.5 ) : \
  621.                  (NoiseDeint == "Generate")                 ? noise.QTGMC_Generate2ndFieldNoise( denoised, ChromaNoise ) : \
  622.                                                               noise.DoubleWeave()
  623.     # Motion-compensated stabilization of generated noise
  624.     noiseSuper = (StabilizeNoise) ? deintNoise.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise ) : NOP()
  625.     mcNoise    = (StabilizeNoise) ? deintNoise.MCompensate( noiseSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  626.     finalNoise = (StabilizeNoise) ? mt_lutxy( deintNoise, mcNoise, "x range_half - abs y range_half - abs > x y ? 0.6 * x y + 0.2 * +", use_expr=2, U=CNmt1,V=CNmt1 ) : deintNoise
  627.  
  628.     # If NoiseProcess=1 denoise input clip. If NoiseProcess=2 leave noise in the clip and let the temporal blurs "denoise" it for a stronger effect
  629.     innerClip = (NoiseProcess == 1) ? denoised : clip
  630.  
  631.  
  632.     #---------------------------------------
  633.     # Interpolation
  634.  
  635.     # >>>> Interleaved YUY2 for interpolation
  636.  
  637.     # Support badly deinterlaced progressive content - drop half the fields and reweave to get 1/2fps interlaced stream appropriate for QTGMC processing
  638.     ediInput = (InputType == 2 || InputType == 3) ? innerClip.SeparateFields().SelectEvery(4,0,3).Weave() : innerClip
  639.  
  640.     # Create interpolated image as starting point for output
  641.     edi1 = defined(EdiExt) ? EdiExt.PointResize( w,h, 0,(EdiExt.Height()-h)/2, -0,h+epsilon ) : \
  642.                              QTGMC_Interpolate( ediInput, InputType, EdiMode, NNSize, NNeurons, EdiQual, EdiMaxD, EdiThreads, bobbed, ChromaEdi )
  643.  
  644.     # >>>> Switch to planar YUY2 during next step - remains planar until very end of script except blurring for back blending & SVThin
  645.  
  646.     # InputType=2,3: use motion mask to blend luma between original clip & reweaved clip based on ProgSADMask setting. Use chroma from original clip in any case
  647.     inputTypeBlend = (ProgSADMask > 0.0) ? MMask( srchClip, bVec1, kind=1, ml=ProgSADMask ) : NOP()
  648.     edi = (InputType != 2 && InputType != 3) ? (!yuy2 ? edi1 : edi1.nonyuy2clipin(true)) :\
  649.           (ProgSADMask <= 0.0)               ? (!yuy2 ? edi1.MergeChroma( innerClip ) : edi1.MergeChroma( innerClip ).nonyuy2clipin(true)) : \
  650.                                                (!yuy2 ? mt_merge( innerClip, edi1, inputTypeBlend, U=2,V=2 ) : \
  651.                                                         mt_merge( innerClip.nonyuy2clipin(true), edi1.nonyuy2clipin(true), inputTypeBlend, U=2,V=2 ))
  652.  
  653.     # Get the max/min value for each pixel over neighboring motion-compensated frames - used for temporal sharpness limiting
  654.     ediSuper = (TR1 > 0 || temporalSL)   ? edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  655.     bComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  656.     fComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  657.     tMax     = (temporalSL)              ? edi.mt_logic( fComp1, "max", U=3,V=3 ).mt_logic( bComp1, "max", U=3,V=3 )    : NOP()
  658.     tMin     = (temporalSL)              ? edi.mt_logic( fComp1, "min", U=3,V=3 ).mt_logic( bComp1, "min", U=3,V=3 )    : NOP()
  659.     bComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, bVec3, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  660.     fComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, fVec3, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  661.     tMax     = (SLRad > 1 && temporalSL) ? tMax.mt_logic( fComp3, "max", U=3,V=3 ).mt_logic( bComp3, "max", U=3,V=3 )   : tMax
  662.     tMin     = (SLRad > 1 && temporalSL) ? tMin.mt_logic( fComp3, "min", U=3,V=3 ).mt_logic( bComp3, "min", U=3,V=3 )   : tMin
  663.  
  664.  
  665.     #---------------------------------------
  666.     # Create basic output
  667.  
  668.     # Use motion vectors to blur interpolated image (edi) with motion-compensated previous and next frames. As above, this is done to remove shimmer from
  669.     # alternate frames so the same binomial kernels are used. However, by using motion-compensated smoothing this time we avoid motion blur. The use of
  670.     # MDegrain1 (motion compensated) rather than TemporalSmooth makes the weightings *look* different, but they evaluate to the same values
  671.     # Create linear weightings of neighbors first                                                                                -2    -1     0    1     2
  672.     degrain1 = (TR1 > 0) ? edi.MDegrain1( ediSuper, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  673.     degrain2 = (TR1 > 1) ? edi.MDegrain1( ediSuper, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16) : NOP()  # 0.33  0.00  0.33  0.00  0.33
  674.     degrain1 = (TR1 > 0) ? lsb ? degrain1.ditherpost(mode=6, slice=false) : n16 ? degrain1.ConvertTo8bit(dither=1) : degrain1 : degrain1
  675.     degrain2 = (TR1 > 1) ? lsb ? degrain2.ditherpost(mode=6, slice=false) : n16 ? degrain2.ConvertTo8bit(dither=1) : degrain2 : degrain2
  676.  
  677.     # Combine linear weightings to give binomial weightings - TR1=0: (1), TR1=1: (1:2:1), TR1=2: (1:4:6:4:1)
  678.     binomial1 = (TR1 == 0) ? edi : \
  679.                 (TR1 == 1) ? degrain1.Merge( edi, 0.25 ) : \
  680.                              degrain1.Merge( degrain2, 0.2 ).Merge( edi, 0.0625 )
  681.  
  682.     # Remove areas of difference between smoothed image and interpolated image that are not bob-shimmer fixes: repairs residual motion blur from temporal smooth
  683.     repair1 = (Rep1 == 0) ? binomial1 : binomial1.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep1, RepChroma )
  684.  
  685.     # Apply source match - use difference between output and source to succesively refine output [extracted to function to clarify main code path]
  686.     match = (SourceMatch == 0) ? repair1 : \
  687.                                  repair1.QTGMC_ApplySourceMatch( InputType, ediInput, bVec1,fVec1, bVec2,fVec2, SubPel, SubPelInterp, hpad, vpad, \
  688.                                                                  ThSAD1, ThSCD1, ThSCD2, SourceMatch, MatchTR1, MatchEdi, MatchNNSize, MatchNNeurons, \
  689.                                                                  MatchEdiQual, MatchEdiMaxD, MatchTR2, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, \
  690.                                                                  MatchEdiMaxD2, MatchEnhance, EdiThreads, lsb, n16 )
  691.  
  692.     # Lossless=2 - after preparing an interpolated, de-shimmered clip, restore the original source fields into it and clean up any artefacts.
  693.     # This mode will not give a true lossless result because the resharpening and final temporal smooth are still to come, but it will add further detail.
  694.     # However, it can introduce minor combing. This setting is best used together with source-match (it's effectively the final source-match stage).
  695.     lossed1 = (Lossless == 2) ? QTGMC_MakeLossless( match, innerClip, InputType ) : match
  696.  
  697.  
  698.     #---------------------------------------
  699.     # Resharpen / retouch output
  700.  
  701.     # Resharpen to counteract temporal blurs. Little sharpening needed for source-match mode since it has already recovered sharpness from source
  702.     vresharp1 = (SMode == 2) ? Merge( lossed1.mt_expand( mode="vertical", U=3,V=3 ), lossed1.mt_inpand( mode="vertical", U=3,V=3 ) ) : NOP()
  703.     vresharp  = (Precise && SMode == 2) ? vresharp1.mt_lutxy( lossed1, "x y < x 1 scalef + x y > x 1 scalef - x ? ?", use_expr=2, U=3,V=3 ) : vresharp1 # Precise mode: reduce tiny overshoot
  704.     resharp   = (SMode == 0) ? lossed1 : \
  705.                 (SMode == 1) ? lossed1.mt_lutxy( lossed1.RemoveGrain( rgBlur ),  "x x y - "+ string(sharpAdj) + " * +", clamp_float=true, use_expr=1, U=3,V=3 ) : \
  706.                                lossed1.mt_lutxy( vresharp.RemoveGrain( rgBlur ), "x x y - "+ string(sharpAdj) + " * +", clamp_float=true, use_expr=1, U=3,V=3 )
  707.  
  708.     # Slightly thin down 1-pixel high horizontal edges that have been widened into neigboring field lines by the interpolator
  709.     SVThinSc = SVThin * 6.0
  710.     vertMedD = (SVthin > 0.0) ? mt_lutxy( lossed1, lossed1.VerticalCleaner( mode=1, modeU=-1, modeV=-1 ), "y x - " + string(SVThinSc) + " * range_half +", use_expr=3, U=1,V=1 ) : NOP()
  711.     vertMedD = (SVthin > 0.0) ? (vertMedD.Blur( 1,0 )) : NOP()
  712.     neighborD = (SVthin > 0.0) ? mt_lutxy( vertMedD, vertMedD.RemoveGrain( rgBlur,-1 ), "y range_half - abs x range_half - abs > y range_half ?", use_expr=3 ) : NOP()
  713.     thin      = (SVthin > 0.0) ? resharp.mt_adddiff( neighborD, U=2,V=2 ) : resharp
  714.  
  715.     # Back blend the blurred difference between sharpened & unsharpened clip, before (1st) sharpness limiting (Sbb == 1,3). A small fidelity improvement
  716.     backBlend1 = (Sbb != 1 && Sbb != 3) ? thin : \
  717.                          thin.mt_makediff( mt_makediff( thin, lossed1, U=1,V=1 ).RemoveGrain( 12, -1 ) \
  718.                              .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 )
  719.  
  720.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  721.     # Occurs here (before final temporal smooth) if SLMode == 1,2. This location will restrict sharpness more, but any artefacts introduced will be smoothed
  722.     sharpLimit1 = (SLMode == 1) ? backBlend1.Repair( ((SLrad <= 1) ? edi : backBlend1.Repair( edi, 12 )), 1 ) : \
  723.                   (SLMode == 2) ? backBlend1.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  724.                                   backBlend1
  725.  
  726.     # Back blend the blurred difference between sharpened & unsharpened clip, after (1st) sharpness limiting (Sbb == 2,3). A small fidelity improvement
  727.     backBlend2 = (Sbb < 2) ? sharpLimit1 : \
  728.                          sharpLimit1.mt_makediff( mt_makediff( sharpLimit1, lossed1, U=1,V=1 ).RemoveGrain( 12, -1 ) \
  729.                                         .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 )
  730.  
  731.     # Add back any extracted noise, prior to final temporal smooth - this will restore detail that was removed as "noise" without restoring the noise itself
  732.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  733.     addNoise1 = (GrainRestore <= 0.0) ? backBlend2 : \
  734.                                         backBlend2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " scalef - " + string(GrainRestore) + " * range_half +", use_expr=2, U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  735.  
  736.     # Final light linear temporal smooth for denoising
  737.     stableSuper = (TR2 > 0) ? addNoise1.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  738.     stable  = (TR2 == 0) ? addNoise1 : \
  739.               (TR2 == 1) ? addNoise1.MDegrain1( stableSuper, bVec1,fVec1,                                                                  thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : \
  740.               (TR2 == 2) ? addNoise1.MDegrain2( stableSuper, bVec1,fVec1, bVec2,fVec2,                                                     thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : \
  741.               (TR2 == 3) ? addNoise1.MDegrain3( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3,                                        thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : \
  742.               (TR2 == 4) ? addNoise1.MDegrain4( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4,                           thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : \
  743.               (TR2 == 5) ? addNoise1.MDegrain5( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4, bVec5,fVec5,              thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : \
  744.                            addNoise1.MDegrain6( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4, bVec5,fVec5, bVec6,fVec6, thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 )
  745.     stable  = (TR2 > 0) ? lsb ? stable.ditherpost(mode=6, slice=false) : n16 ? stable.ConvertTo8bit(dither=1) : stable : stable
  746.  
  747.     # Remove areas of difference between final output & basic interpolated image that are not bob-shimmer fixes: repairs motion blur caused by temporal smooth
  748.     repair2 = (Rep2 == 0) ? stable : stable.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep2, RepChroma )
  749.  
  750.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  751.     # Occurs here (after final temporal smooth) if SLMode == 3,4. Allows more sharpening here, but more prone to introducing minor artefacts
  752.     sharpLimit2 = (SLMode == 3) ? repair2.Repair( ((SLrad <= 1) ? edi : repair2.Repair( edi, 12 )), 1 ) : \
  753.                   (SLMode == 4) ? repair2.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  754.                                   repair2
  755.  
  756.     # Lossless=1 - inject source fields into result and clean up inevitable artefacts. Provided NoiseRestore=0.0 or 1.0, this mode will make the script result
  757.     # properly lossless, but this will retain source artefacts and cause some combing (where the smoothed deinterlace doesn't quite match the source)
  758.     lossed2 = (Lossless == 1) ? QTGMC_MakeLossless( sharpLimit2, innerClip, InputType ) : sharpLimit2
  759.  
  760.     # Add back any extracted noise, after final temporal smooth. This will appear as noise/grain in the output
  761.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  762.     addNoise2 = (NoiseRestore <= 0.0) ? lossed2 : \
  763.                                         lossed2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " scalef - " + string(NoiseRestore) + " * range_half +", clamp_float=true, use_expr=3, U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  764.  
  765.  
  766.     #---------------------------------------
  767.     # Post-Processing
  768.  
  769.     # Shutter motion blur - get level of blur depending on output framerate and blur already in source
  770.     blurLevel = (ShutterAngleOut * FPSDivisor - ShutterAngleSrc) * 100.0 / 360.0
  771.     Assert( blurLevel >= 0, "Cannot reduce motion blur already in source: increase ShutterAngleOut or FPSDivisor" )
  772.     Assert( blurLevel <= 200, "Exceeded maximum motion blur level: decrease ShutterAngleOut or FPSDivisor" )
  773.  
  774.     # ShutterBlur mode 2,3 - get finer resolution motion vectors to reduce blur "bleeding" into static areas
  775.     rBlockDivide = Select( ShutterBlur, 1, 1, 2, 4 )
  776.     rBlockSize = BlockSize / rBlockDivide
  777.     rOverlap   = Overlap   / rBlockDivide
  778.     rBlockSize = (rBlockSize < 4) ? 4 : rBlockSize
  779.     rOverlap   = (rOverlap   < 2) ? 2 : rOverlap
  780.     rBlockDivide = BlockSize / rBlockSize
  781.     rLambda = Lambda / (rBlockDivide * rBlockDivide)
  782.     sbBVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( bVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  783.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : bVec1
  784.     sbFVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( fVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  785.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : fVec1
  786.  
  787.     # Shutter motion blur - use MFlowBlur to blur along motion vectors
  788.     sblurSuper = (ShutterBlur > 0) ? addNoise2.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  789.     sblur =      (ShutterBlur > 0) ? addNoise2.MFlowBlur( sblurSuper, sbBVec1, sbFVec1, blur=blurLevel, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  790.  
  791.     # Shutter motion blur - use motion mask to reduce blurring in areas of low motion - also helps reduce blur "bleeding" into static areas, then select blur type
  792.     sbMotionMask = (ShutterBlur > 0 && SBlurLimit > 0) ? MMask( srchClip, bVec1, kind=0, ml=SBlurLimit ) : NOP()
  793.     sblurred     = (ShutterBlur == 0) ? addNoise2 : \
  794.                    (SBlurLimit == 0)  ? sblur : \
  795.                                         mt_merge( addNoise2, sblur, sbMotionMask, U=3,V=3 )
  796.     # Reduce frame rate
  797.     decimated = (FPSDivisor != 1) ? sblurred.SelectEvery( FPSDivisor, 0 ) : sblurred
  798.  
  799.     # Crop off temporary vertical padding
  800.     cropped = Border ? decimated.Crop( 0, 4, -0, -4 ) : decimated
  801.     h = Border ? h-8 : h
  802.  
  803.     # Show output of choice + settings
  804.     # >>>> Restore YUY2 to interleaved
  805.     output = (ShowNoise == 0.0) ? cropped : finalNoise.mt_lut( "x range_half - " + string(ShowNoise) + " * range_half +", clamp_float=true, use_expr=2, U=CNmt128,V=CNmt128 )
  806.     output = yuy2 ? output.nonyuy2clipout(true) : output
  807.     return (ShowSettings == false) ? output : \
  808.         output.Subtitle( "TR0=" + string(TR0) + " | TR1=" + string(TR1) + " | TR2=" + string(TR2) + " | Rep0=" + string(Rep0) + " | Rep1=" + string(Rep1) + \
  809.         " | Rep2=" + string(Rep2) + " | RepChroma=" + string(RepChroma) + "\nEdiMode='" + EdiMode + "' | NNSize=" + string(NNSize) + " | NNeurons=" + \
  810.         string(NNeurons) + " | EdiQual=" + string(EdiQual) + " | EdiMaxD=" + string(EdiMaxD) + " | ChromaEdi='" + ChromaEdi + "' | EdiThreads=" + \
  811.         string(EdiThreads) + "\nSharpness=" + string(Sharpness, "%.2f") + " | SMode=" + string(SMode) + " | SLMode=" + string(SLMode) + " | SLRad=" + \
  812.         string(SLRad) + " | SOvs=" + string(SOvs) + " | SVThin=" + string(SVThin, "%.2f") + " | Sbb=" + string(Sbb) + "\nSrchClipPP=" + string(SrchClipPP) + \
  813.         " | SubPel=" + string(SubPel) + " | SubPelInterp=" + string(SubPelInterp) + " | BlockSize=" + string(BlockSize) + " | Overlap=" + string(Overlap) + \
  814.         "\nSearch=" + string(Search) + " | SearchParam=" + string(SearchParam) + " | PelSearch=" + string(PelSearch) + " | ChromaMotion=" + \
  815.         string(ChromaMotion) + " | TrueMotion=" + string(TrueMotion) + "\nLambda=" + string(Lambda) + " | LSAD=" + string(LSAD) + " | PNew=" + string(PNew) + \
  816.         " | PLevel=" + string(PLevel) + " | GlobalMotion=" + string(GlobalMotion) + " | DCT=" + string(DCT) + "\nThSAD1=" + string(ThSAD1) + " | ThSAD2=" + \
  817.         string(ThSAD2) + " | ThSCD1=" + string(ThSCD1) + " | ThSCD2=" + string(ThSCD2) + "\nSourceMatch=" + string(SourceMatch) + " | MatchPreset='" + \
  818.         MatchPreset + "' | MatchEdi='" + MatchEdi + "'\nMatchPreset2='" + MatchPreset2 + "' | MatchEdi2='" + MatchEdi2 + "' | MatchTR2=" + string(MatchTR2) + \
  819.         " | MatchEnhance=" + string(MatchEnhance, "%.2f") + " | Lossless=" + string(Lossless) + "\nNoiseProcess=" + string(NoiseProcess) + " | Denoiser='" + \
  820.         Denoiser + "' | FftThreads=" + string(FftThreads) + " | DenoiseMC=" + string(DenoiseMC) + " | NoiseTR=" + string(NoiseTR) + " | Sigma=" + \
  821.         string(Sigma, "%.2f") + "\nChromaNoise=" + string(ChromaNoise) + " | ShowNoise=" + string(ShowNoise, "%.2f") + " | GrainRestore=" + \
  822.         string(GrainRestore, "%.2f") + " | NoiseRestore=" + string(NoiseRestore, "%.2f") + "\nNoiseDeint='" + NoiseDeint + "' | StabilizeNoise=" + \
  823.         string(StabilizeNoise) + " | InputType=" + string(InputType) + " | ProgSADMask=" + string(ProgSADMask, "%.2f") + "\nFPSDivisor=" + \
  824.         string(FPSDivisor) + " | ShutterBlur=" + string(ShutterBlur) + " | ShutterAngleSrc=" + string(ShutterAngleSrc, "%.2f") + " | ShutterAngleOut=" + \
  825.         string(ShutterAngleOut, "%.2f") + " | SBlurLimit=" + string(SBlurLimit) + "\nBorder=" + string(Border) + " | Precise=" + string(Precise) + \
  826.         "\nPreset='" + Preset + "' | Tuning='" + Tuning + "' | GlobalNames='" + GlobalNames + "' | PrevGlobals='" + PrevGlobals + "' | ForceTR=" + \
  827.         string(ForceTR), font="Lucida Console", size=11, lsp=12 )
  828. }
  829.  
  830.  
  831. #---------------------------------------
  832. # Helpers
  833.  
  834. # Same as Bob, but keeps the field order the same.
  835. function QTGMC_Bob(clip cp, float "b", float "c", int "height" )
  836. {
  837.   sisphbd = AvsPlusVersionNumber > 2294
  838.   h = Default(height, cp.Height)
  839.   w = cp.Width
  840.   shift = GetParity(cp) ? 0.25 : -0.25
  841.  
  842.   c420 = sisphbd  ? Is420(cp) : IsYV12(cp)
  843.  
  844.   c420 ? cp.SeparateFields() : nop()
  845.  
  846.   oeven=c420 ? SelectEven() : nop()
  847.   oodd=c420 ? SelectOdd() : nop()
  848.  
  849.   even=c420 ? sisphbd  ? oeven.ConvertToY().BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : oeven.ConvertToY8().BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : nop()
  850.   odd=c420 ? sisphbd  ? oodd.ConvertToY().BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : oodd.ConvertToY8().BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : nop()
  851.  
  852.   evenChr=c420 ? Interleave(sisphbd  ? oeven.ExtractU() : oeven.UToY8(), sisphbd  ? oeven.ExtractV() : oeven.VToY8()).BicubicResize(w/2, h/2, b, c, 0, shift, w/2, Height()/2).AssumeFrameBased() : nop()
  853.   oddChr=c420 ? Interleave(sisphbd  ? oodd.ExtractU() : oodd.UToY8(), sisphbd  ? oodd.ExtractV() :oodd.VToY8()).BicubicResize(w/2, h/2, b, c, 0, -shift, w/2, Height()/2).AssumeFrameBased() : nop()
  854.  
  855.   c420 ? YToUV(Interleave(evenChr.SelectEven(), oddChr.SelectEven()),Interleave(evenChr.SelectOdd(), oddChr.SelectOdd()),Interleave(even, odd)) : cp.Bob( b,c, h )
  856.   GetParity(cp) ? AssumeTFF() : AssumeBFF()
  857. }
  858.  
  859.  
  860. # Interpolate input clip using method given in EdiMode. Use Fallback or Bob as result if mode not in list. If ChromaEdi string if set then interpolate chroma
  861. # separately with that method (only really useful for EEDIx). The function is used as main algorithm starting point and for first two source-match stages
  862. function QTGMC_Interpolate( clip Input, int InputType, string EdiMode, int NNSize, int NNeurons, int EdiQual, int EdiMaxD, int EdiThreads, clip "Fallback", \
  863.                             string "ChromaEdi" )
  864. {
  865.     # >>>> YUY2 is interleaved here
  866.  
  867.     ChromaEdi = default( ChromaEdi, "" )
  868.     CEed = (ChromaEdi == "")
  869.  
  870.     interp = (InputType == 1)            ? Input : \
  871.              (EdiMode == "NNEDI3")       ? Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  872.              (EdiMode == "NNEDI2")       ? Input.NNEDI2( field=-2, nsize=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  873.              (EdiMode == "NNEDI")        ? Input.NNEDI( field=-2, U=CEed,V=CEed ) : \
  874.              (EdiMode == "EEDI3+NNEDI3") ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed, \
  875.                                                         sclip=Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) ) : \
  876.              (EdiMode == "EEDI3")        ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed ) : \
  877.              (EdiMode == "EEDI2")        ? Input.SeparateFields().EEDI2( field=-2, maxd=EdiMaxD ) : \
  878.              (EdiMode == "Yadif")        ? isyuy2(Input) ? Input.nonyuy2clipin(true).Yadifmod2( mode=3 ).nonyuy2clipout(true) : Input.Yadifmod2( mode=3 ) : \
  879.              (EdiMode == "cYadif")       ? Input.Yadif( mode=3 ) : \
  880.              (EdiMode == "TDeint")       ? Input.TDeInt( mode=1 ) : \
  881.              (EdiMode == "RepYadif")     ? isyuy2(Input) ? Repair( Input.nonyuy2clipin(true).Yadifmod2( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ).nonyuy2clipin(true), 2, 0 ).nonyuy2clipout(true) : \
  882.                                                            Input.Yadifmod2( mode=3 ) : \   
  883.              (EdiMode == "RepcYadif")    ? isyuy2(Input) ? Repair( Input.Yadif( mode=3 ).nonyuy2clipin(true), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ).nonyuy2clipin(true), 2, 0 ).nonyuy2clipout(true) : \
  884.                                                    Repair( Input.Yadif( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ), 2, 0 ) : \
  885.                                            default( Fallback, Input.QTGMC_Bob( 0,0.5 ) )
  886.  
  887.     interpuv = (InputType == 1)        ? NOP() : \
  888.                (ChromaEdi == "NNEDI3") ? Input.NNEDI3( field=-2, nsize=4, nns=0, qual=1, threads=EdiThreads, Y=false ) : \
  889.                (ChromaEdi == "Yadif")  ? isyuy2(Input) ? Input.nonyuy2clipin(true).Yadifmod2( mode=3 ).nonyuy2clipout(true) : Input.Yadifmod2( mode=3 ) : \
  890.                (ChromaEdi == "cYadif") ? Input.Yadif( mode=3 ) : \
  891.                (ChromaEdi == "Bob")    ? Input.QTGMC_Bob( 0,0.5 ) : \
  892.                                          NOP()
  893.  
  894.     return (!IsClip(interpuv)) ? interp : interp.MergeChroma( interpuv )
  895. }
  896.  
  897.  
  898. # Functions (from original TGMC) used instead of mt_xxflate with similar operation but a somewhat stronger result. Originally added for speed, they are
  899. # no longer faster due to improvements in masktools. Difference (visual and speed) is small so may be reverted in a later version.
  900. function QTGMC_inflate( clip c, int "Y", int "U", int "V" )
  901. {
  902.     # >>>> YUY2 is planar here
  903.     mtY =default( Y, 3 )
  904.     mtU =default( U, 1 )
  905.     mtV =default( V, 1 )
  906.     rgY = (mtY == 3) ? 20 : -1
  907.     rgU = (mtU == 3) ? 20 : -1
  908.     rgV = (mtV == 3) ? 20 : -1
  909.     mt_logic( c, c.RemoveGrain( rgY, rgU, rgV ), "max", Y=mtY,U=mtU,V=mtV )
  910. }
  911.  
  912. function QTGMC_deflate( clip c, int "Y", int "U", int "V" )
  913. {
  914.     # >>>> YUY2 is planar here
  915.     mtY =default( Y, 3 )
  916.     mtU =default( U, 1 )
  917.     mtV =default( V, 1 )
  918.     rgY = (mtY == 3) ? 20 : -1
  919.     rgU = (mtU == 3) ? 20 : -1
  920.     rgV = (mtV == 3) ? 20 : -1
  921.     mt_logic( c, c.RemoveGrain( rgY, rgU, rgV ), "min", Y=mtY,U=mtU,V=mtV )
  922. }
  923.  
  924. # Helper function: Compare processed clip with reference clip: only allow thin, horizontal areas of difference, i.e. bob shimmer fixes
  925. # Rough algorithm: Get difference, deflate vertically by a couple of pixels or so, then inflate again. Thin regions will be removed
  926. #                  by this process. Restore remaining areas of difference back to as they were in reference clip.
  927. function QTGMC_KeepOnlyBobShimmerFixes( clip Input, clip Ref, int Rep, bool Chroma )
  928. {
  929.     # >>>> YUY2 is planar here
  930.  
  931.     # ed is the erosion distance - how much to deflate then reflate to remove thin areas of interest: 0 = minimum to 6 = maximum
  932.     # od is over-dilation level  - extra inflation to ensure areas to restore back are fully caught:  0 = none to 3 = one full pixel
  933.     # If Rep < 10, then ed = Rep and od = 0, otherwise ed = 10s digit and od = 1s digit (nasty method, but kept for compatibility with original TGMC)
  934.     Rep    = default( Rep,    1    )
  935.     Chroma = default( Chroma, true )
  936.     ed = (Rep < 10) ? Rep : Rep / 10
  937.     od = (Rep < 10) ? 0   : Rep % 10
  938.     RCrg  = Chroma ? 3 : 1
  939.     RCrgo = Chroma ? 3 : 2
  940.  
  941.     diff = mt_makediff(Ref, Input, U=3,V=3 )
  942.  
  943.     # Areas of positive difference                                                                # ed = 0 1 2 3 4 5 6 7
  944.     choke1 =                        diff.  mt_inpand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel   \
  945.     choke1 = (ed > 2)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . x x x x x    1 pixel    |  Deflate to remove thin areas
  946.     choke1 = (ed > 5)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . . x x    1 pixel   /
  947.     choke1 = (ed % 3 != 0)        ? choke1.QTGMC_deflate( U=RCrg,V=RCrg )              : choke1   #      . x x . x x . x    A bit more deflate & some horizonal effect
  948.     choke1 = (ed == 2 || ed == 5) ? choke1.RemoveGrain( 4              )               : choke1   #      . . x . . x . .    Local median
  949.                                                                                                                      
  950.     choke1 =                        choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel  \
  951.     choke1 = (ed > 1)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . x x x x x x    1 pixel   | Reflate again
  952.     choke1 = (ed > 4)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . x x x    1 pixel  /
  953.  
  954.     # Over-dilation - extra reflation up to about 1 pixel
  955.     choke1 = (od == 0)            ? choke1 : \
  956.              (od == 1)            ? choke1.QTGMC_inflate( U=RCrg,V=RCrg ) : \
  957.              (od == 2)            ? choke1.QTGMC_inflate( U=RCrg,V=RCrg ).QTGMC_inflate( U=RCrg,V=RCrg ) : \
  958.                                     choke1.mt_expand ( U=RCrg,V=RCrg )
  959.  
  960.     # Areas of negative difference (similar to above)
  961.     choke2 =                        diff.  mt_expand( mode="vertical", U=RCrg,V=RCrg )        
  962.     choke2 = (ed > 2)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  963.     choke2 = (ed > 5)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  964.     choke2 = (ed % 3 != 0)        ? choke2.QTGMC_inflate( U=RCrg,V=RCrg )              : choke2
  965.     choke2 = (ed == 2 || ed == 5) ? choke2.RemoveGrain( 4              )               : choke2
  966.     choke2 =                        choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg )
  967.     choke2 = (ed > 1)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  968.     choke2 = (ed > 4)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  969.     choke2 = (od == 0)            ? choke2 : \
  970.              (od == 1)            ? choke2.QTGMC_deflate( U=RCrg,V=RCrg )  : \
  971.              (od == 2)            ? choke2.QTGMC_deflate( U=RCrg,V=RCrg ).QTGMC_deflate( U=RCrg,V=RCrg ) : \
  972.                                     choke2.mt_inpand ( U=RCrg,V=RCrg )
  973.  
  974.     # Combine above areas to find those areas of difference to restore
  975.     restore = diff.mt_lutxy( choke1, "x 129 scalef < x y range_half < range_half y ? ?", use_expr=2, U=RCrg,V=RCrg ).mt_lutxy( choke2, "x 127 scalef > x y range_half > range_half y ? ?", use_expr=1, U=RCrg,V=RCrg )
  976.  
  977.     return Input.mt_adddiff( restore, U=RCrgo,V=RCrgo )
  978. }
  979.  
  980.  
  981. # Given noise extracted from an interlaced source (i.e. the noise is interlaced), generate "progressive" noise with a new "field" of noise injected. The new
  982. # noise is centered on a weighted local average and uses the difference between local min & max as an estimate of local variance
  983. # YUY2 clip input is planar, but must pass interleaved version of clip to setup noise
  984. function QTGMC_Generate2ndFieldNoise( clip Input, clip InterleavedClip, bool "ChromaNoise" )
  985. {
  986.     # >>>> YUY2 is planar here. Noise is generated (AddGrainC) interleaved, but immediately made planar
  987.     ChromaNoise = default( ChromaNoise, false )
  988.     CNmt1 = ChromaNoise ? 3 : 1
  989.     origNoise = Input.SeparateFields()
  990.     noiseMax  = origNoise.mt_expand( mode="square", U=CNmt1,V=CNmt1 ).mt_expand( mode="horizontal", U=CNmt1,V=CNmt1 )
  991.     noiseMin  = origNoise.mt_inpand( mode="square", U=CNmt1,V=CNmt1 ).mt_inpand( mode="horizontal", U=CNmt1,V=CNmt1 )
  992.     random    = BlankClip( InterleavedClip.SeparateFields(), color_yuv=$808080 ).AddGrainC( var=1800, uvar=ChromaNoise ? 1800 : 0 )
  993.     random    = InterleavedClip.IsYUY2() ? random.nonyuy2clipin(true) : random
  994.     varRandom = mt_makediff( noiseMax, noiseMin, U=CNmt1,V=CNmt1 ).mt_lutxy( random, "x range_half - y * range_size / range_half +", scale_inputs="floatf", use_expr=3, U=CNmt1,V=CNmt1)
  995.     newNoise  = noiseMin.mt_adddiff( varRandom, U=CNmt1,V=CNmt1 )
  996.     return Interleave( origNoise, newNoise ).Weave()
  997. }
  998.  
  999.  
  1000. # Insert the source lines into the result to create a true lossless output. However, the other lines in the result have had considerable processing and won't
  1001. # exactly match source lines. There will be some slight residual combing. Use vertical medians to clean a little of this away
  1002. function QTGMC_MakeLossless( clip Input, clip Source, int InputType )
  1003. {
  1004.     Assert( InputType != 1, "Lossless modes are incompatible with InputType=1" )
  1005.  
  1006.     # >>>> YUY2: 'Input' is planar, 'Source' is interleaved (changed to planar here for processing) - returns planar result
  1007.  
  1008.     # Weave the source fields and the "new" fields that have generated in the input
  1009.     srcFields1 = (InputType == 0) ? Source.SeparateFields() : Source.SeparateFields().SelectEvery( 4, 0,3 )
  1010.     srcFields  = Source.IsYUY2() ? srcFields1.nonyuy2clipin(true) : srcFields1
  1011.     newFields  = Input.SeparateFields().SelectEvery( 4, 1,2 )
  1012.     processed  = Interleave( srcFields, newFields ).SelectEvery(4, 0,1,3,2 ).Weave()
  1013.  
  1014.     # Clean some of the artefacts caused by the above - creating a second version of the "new" fields
  1015.     vertMedian  = processed.VerticalCleaner( mode=1 )
  1016.     vertMedDiff = mt_makediff( processed, vertMedian, U=3,V=3 )
  1017.     vmNewDiff1  = vertMedDiff.SeparateFields().SelectEvery( 4, 1,2 )
  1018.     vmNewDiff2  = vmNewDiff1.VerticalCleaner( mode=1 ).mt_lutxy( vmNewDiff1, "x range_half - y range_half - * 0 < range_half x range_half - abs y range_half - abs < x y ? ?", use_expr=2, U=3,V=3 )
  1019.     vmNewDiff3  = vmNewDiff2.Repair( vmNewDiff2.RemoveGrain( 2 ), 1 )
  1020.  
  1021.     # Reweave final result
  1022.     return Interleave( srcFields, newFields.mt_makediff( vmNewDiff3, U=3,V=3 )).SelectEvery( 4, 0,1,3,2 ).Weave()
  1023. }
  1024.  
  1025.  
  1026. # Source-match, a three stage process that takes the difference between deinterlaced input and the original interlaced source, to shift the input more towards
  1027. # the source without introducing shimmer. All other arguments defined in main script
  1028. function QTGMC_ApplySourceMatch( clip Deinterlace, int InputType, val Source, val bVec1, val fVec1, val bVec2, val fVec2, \
  1029.                                  int SubPel, int SubPelInterp, int hpad, int vpad, int ThSAD1, int ThSCD1, int ThSCD2, int SourceMatch, \
  1030.                                  int MatchTR1, string MatchEdi, int MatchNNSize, int MatchNNeurons, int MatchEdiQual, int MatchEdiMaxD,\
  1031.                                  int MatchTR2, string MatchEdi2, int MatchNNSize2, int MatchNNeurons2, int MatchEdiQual2, int MatchEdiMaxD2, \
  1032.                                  float MatchEnhance, int EdiThreads, bool lsb, bool n16 )
  1033. {
  1034.     # >>>> YUY2: 'Deinterlace' is planar, 'Source' is interleaved (changed to planar here for all processing except interpolation) - returns planar result
  1035.     yuy2 = Source.IsYUY2()
  1036.     Source = yuy2 ? Source.nonyuy2clipin(true) : Source
  1037.  
  1038.     # Basic source-match. Find difference between source clip & equivalent fields in interpolated/smoothed clip (called the "error" in formula below). Ideally
  1039.     # there should be no difference, we want the fields in the output to be as close as possible to the source whilst remaining shimmer-free. So adjust the
  1040.     # *source* in such a way that smoothing it will give a result closer to the unadjusted source. Then rerun the interpolation (edi) and binomial smooth with
  1041.     # this new source. Result will still be shimmer-free and closer to the original source.
  1042.     # Formula used for correction is P0' = P0 + (P0-P1)/(k+S(1-k)), where P0 is original image, P1 is the 1st attempt at interpolation/smoothing , P0' is the
  1043.     # revised image to use as new source for interpolation/smoothing, k is the weighting given to the current frame in the smooth, and S is a factor indicating
  1044.     # "temporal similarity" of the error from frame to frame, i.e. S = average over all pixels of [neighbor frame error / current frame error] . Decreasing
  1045.     # S will make the result sharper, sensible range is about -0.25 to 1.0. Empirically, S=0.5 is effective [will do deeper analysis later]
  1046.     errorTemporalSimilarity = 0.5  # S in formula described above
  1047.     errorAdjust1   = Select( MatchTR1, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  1048.     match1Clip     = (SourceMatch < 1 || InputType == 1) ? Deinterlace : Deinterlace.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  1049.     match1Update   = (SourceMatch < 1 || MatchTR1 == 0) \
  1050.                         ? Source : mt_lutxy( Source, match1Clip, "x " + string(errorAdjust1 + 1) + " * y " + string(errorAdjust1) + " * -", clamp_float=true, use_expr=2, U=3,V=3 )
  1051.     noyv16ma1Edi   = MatchEdi =="NNEDI2" || MatchEdi =="NNEDI" || MatchEdi =="EEDI3+NNEDI3" || MatchEdi =="EEDI3" || MatchEdi =="EEDI2" || MatchEdi =="TDeint" || MatchEdi =="cYadif" || MatchEdi =="RepcYadif"
  1052.     noyv16ma2Edi   = MatchEdi2=="NNEDI2" || MatchEdi2=="NNEDI" || MatchEdi2=="EEDI3+NNEDI3" || MatchEdi2=="EEDI3" || MatchEdi2=="EEDI2" || MatchEdi2=="TDeint" || MatchEdi2=="cYadif" || MatchEdi2=="RepcYadif"
  1053.     match1Edi      = (SourceMatch == 0) ? NOP() : \
  1054.     !noyv16ma1Edi || !yuy2 ? match1Update.QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) : \
  1055.                              match1Update.nonyuy2clipout(true) \
  1056.                                          .QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) \
  1057.                                          .nonyuy2clipin(true)
  1058.     match1Super    = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1059.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MDegrain1( match1Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : NOP()
  1060.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) ? match1Edi.MDegrain1( match1Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : NOP()
  1061.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) ? lsb ? match1Degrain1.ditherpost(mode=6, slice=false) : n16 ? match1Degrain1.ConvertTo8bit(dither=1) : match1Degrain1 : match1Degrain1
  1062.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) ? lsb ? match1Degrain2.ditherpost(mode=6, slice=false) : n16 ? match1Degrain2.ConvertTo8bit(dither=1) : match1Degrain2 : match1Degrain2
  1063.     match1         = (SourceMatch < 1) ? Deinterlace : \
  1064.                      (MatchTR1 == 0)   ? match1Edi : \
  1065.                      (MatchTR1 == 1)   ? match1Degrain1.Merge( match1Edi, 0.25 ) : \
  1066.                                          match1Degrain1.Merge( match1Degrain2, 0.2 ).Merge( match1Edi, 0.0625 )
  1067.  
  1068.     # Enhance effect of source-match stages 2 & 3 by sharpening clip prior to refinement (source-match tends to underestimate so this will leave result sharper)
  1069.     match1Shp = (SourceMatch > 1 && MatchEnhance > 0.0) ? match1.mt_lutxy( match1.RemoveGrain( 12 ), "x x y - "+ string(MatchEnhance) + " * +", clamp_float=true, use_expr=2, U=3,V=3 ) : match1
  1070.  
  1071.     # Source-match refinement. Find difference between source clip & equivalent fields in (updated) interpolated/smoothed clip. Interpolate & binomially smooth
  1072.     # this difference then add it back to output. Helps restore differences that the basic match missed. However, as this pass works on a difference rather than
  1073.     # the source image it can be prone to occasional artefacts (difference images are not ideal for interpolation). In fact a lower quality interpolation such
  1074.     # as a simple bob often performs nearly as well as advanced, slower methods (e.g. NNEDI3)
  1075.     match2Clip     = (SourceMatch < 2 || InputType == 1) ? match1Shp : match1Shp.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  1076.     match2Diff     = (SourceMatch > 1) ? mt_makediff( Source, match2Clip, U=3,V=3 ) : NOP()
  1077.     match2Edi      = (SourceMatch <= 1) ? NOP() : \
  1078.     !noyv16ma2Edi || !yuy2 ? match2Diff.QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) : \
  1079.                              match2Diff.nonyuy2clipout(true) \
  1080.                                        .QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) \
  1081.                                        .nonyuy2clipin(true)
  1082.     match2Super    = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1083.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MDegrain1( match2Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : NOP()
  1084.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) ? match2Edi.MDegrain1( match2Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : NOP()
  1085.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) ? lsb ? match2Degrain1.ditherpost(mode=6, slice=false) : n16 ? match2Degrain1.ConvertTo8bit(dither=1) : match2Degrain1 : match2Degrain1
  1086.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) ? lsb ? match2Degrain2.ditherpost(mode=6, slice=false) : n16 ? match2Degrain2.ConvertTo8bit(dither=1) : match2Degrain2 : match2Degrain2
  1087.     match2         = (SourceMatch < 2) ? match1 : \
  1088.                      (MatchTR2 == 0)   ? match2Edi : \
  1089.                      (MatchTR2 == 1)   ? match2Degrain1.Merge( match2Edi, 0.25 ) : \
  1090.                                          match2Degrain1.Merge( match2Degrain2, 0.2 ).Merge( match2Edi, 0.0625 )
  1091.  
  1092.     # Source-match second refinement - correct error introduced in the refined difference by temporal smoothing. Similar to error correction from basic step
  1093.     errorAdjust2   = Select( MatchTR2, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  1094.     match3Update   = (SourceMatch < 3 || MatchTR2 == 0) \
  1095.                          ? match2Edi : mt_lutxy( match2Edi, match2, "x " + string(errorAdjust2 + 1) + " * y " + string(errorAdjust2) + " * -", clamp_float=true, use_expr=2, U=3,V=3 )
  1096.     match3Super    = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1097.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MDegrain1( match3Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : NOP()
  1098.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) ? match3Update.MDegrain1( match3Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb, out16=n16 ) : NOP()
  1099.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) ? lsb ? match3Degrain1.ditherpost(mode=6, slice=false) : n16 ? match3Degrain1.ConvertTo8bit(dither=1) : match3Degrain1 : match3Degrain1
  1100.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) ? lsb ? match3Degrain2.ditherpost(mode=6, slice=false) : n16 ? match3Degrain2.ConvertTo8bit(dither=1) : match3Degrain2 : match3Degrain2
  1101.     match3         = (SourceMatch < 3) ? match2 : \
  1102.                      (MatchTR2 == 0)   ? match3Update : \
  1103.                      (MatchTR2 == 1)   ? match3Degrain1.Merge( match3Update, 0.25 ) : \
  1104.                                          match3Degrain1.Merge( match3Degrain2, 0.2 ).Merge( match3Update, 0.0625 )
  1105.  
  1106.     # Apply difference calculated in source-match refinement
  1107.     return (SourceMatch < 2) ? match1 : match1Shp.mt_adddiff( match3, U=3,V=3 )
  1108. }
  1109.  
  1110.  
  1111. # Set global variable called "Prefix_Name" to "Value". Throws exception if global already exists unless Replace=true, in which case the global is overwritten
  1112. function QTGMC_SetUserGlobal( string Prefix, string Name, val Value, bool "Replace" )
  1113. {
  1114.     Replace = default( Replace, false )
  1115.     globalName = Prefix + "_" + Name
  1116.  
  1117.     # Tricky logic to check global: enter catch block if Replace=true *or* globalName doesn't exist (i.e. need to set the global), the exception is not rethrown
  1118.     # Not entering catch block means that Replace=false and global exists - so it throws an exception back to AviSynth
  1119.     try { Assert( !Replace && defined(Eval(globalName)) ) }
  1120.     catch (e)
  1121.     {
  1122.         Eval( "global " + globalName + " = Value" )
  1123.         Replace = true
  1124.     }
  1125.     Assert( Replace, """Multiple calls to QTGMC, set PrevGlobals="Replace" or read documentation on 'Multiple QTGMC Calls'""" )
  1126. }
  1127.  
  1128. # Return value of global variable called "Prefix_Name". Returns NOP() if it doesn't exist or Reuse is false
  1129. function QTGMC_GetUserGlobal( string Prefix, string Name, bool "Reuse" )
  1130. {
  1131.     Reuse = default( Reuse, false )
  1132.     globalName = Prefix + "_" + Name
  1133.  
  1134.     try       { ret = Reuse ? Eval( globalName ) : NOP() }
  1135.     catch (e) { ret = NOP() }
  1136.     return ret
  1137. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement