;
;            ******************************
;            *  Leczenie        ver 1,04  *
;            *<<>><<>><<>><<>><<>><<>><<>>*
;            *           Romek_z_Jawora   *
;            ******************************
;
;
;
;
;
;leczenie przez .um uzdrawianie
;gdy okno statusu jest zamkniete, to je otwiera
;gdy jestesmy ukryci, to nie wlacza leczenia
;gdy zalozymy witala, to sprawdza co 9 sekund, czy mozna leczyc
;po 21 sekundach skrypt mysli, ze przestalismy sie leczyc.
;skrypt liczy czas do wyleczenia - co sekunde nas o tym informuje
;gdy zmieni nam sie hp to informuje o tym nad nasza glowa
;-------------------
set %leczenietrwa 8     ; Jak dlugo sie leczysz - to nalezy dostosowac do swoich potrzeb
;-------------------

set #lpc 20
set #sysmsgcol 88
event sysmessage [RJ]: Leczenie
set #sysmsgcol 253 ; kolor komunikatow - mierzenie czasu leczenia
set %kiedypokazywacczas 5 ;od jakiego czasu do wyleczenia ma pokazywac
set %ji #jindex
set %lecze #false
set %ostatnio 0
;------------------
repeat
{
        if #hits = N/A
            event macro 8 2
        if #hits <> %hp                    ;jezeli nie chcesz informacji o hp nad glowa - usun ta i nastepna linijke
            gosub roznicahp
        if %lecze
        {
            gosub mierzczas                ;jezeli nie chcesz mierzyc czasu, usun ta linijke
            gosub sprawdzczywyleczony
            continue
        }
        if #hits < #maxhits
            gosub leczenie
}
until #false
;------------------
sub leczenie
        set %nielecze #false
        set %ji #jindex
        set %jindex #jindex
        set %czas #scnt2 + 9
        if H in #charstatus || #charghost = yes
           return
        event macro 1 0 .um uzdrawianie
        repeat
        {
          if #targcurs = 1
                   event macro 23 0
                if %ji < #jindex
                   set %ji %ji + 1
                scanjournal %ji
                if Nie_mozesz_te in #journal && %jindex <> #jindex
                {
                   set %leczy #scnt + 8
                   set %lecze #true ;chociaz nie leczy
                   set %nielecze #true
                   return
                }
                if %czas < #scnt2
                   return
        }
        until Zaczynasz_sie in #journal
        set %lecze #true
        set *RJskill #true
        set %leczy #scnt + 20
        set %rozpoczetoleczenie #scnt
return

sub sprawdzczywyleczony
        repeat
        {
           if %ji < #jindex
              set %ji %ji + 1
           scanjournal %ji
           if : notin #journal && ( Wyleczyl in #journal || Nie_udalo_Ci_sie_wyleczyc_ in #journal || Przestal in #journal || Ta_osoba_jest_w_pelni_zdrowa in #journal || Your_skill_in_Uzdrawianie in #journal || Przerwa in #journal )
           {
              set %lecze #false
        set *RJskill #false
              return
           }
           if Zapisywanie in #journal
               gosub Zapisywanie
        }
        until %ji = #jindex
        if %leczy < #scnt
     {
           set %lecze #false
        set *RJskill #false
     }
return

sub mierzczas
        if %nielecze
             return
        if %ostatnio = #scnt
             return
        set %ostatnio #scnt
        set %czasleczenia %leczenietrwa + %rozpoczetoleczenie - #scnt
        if %czasleczenia <= %kiedypokazywacczas
        event sysmessage Lecze:  %czasleczenia , s
return


sub roznicahp
        set %roznica #hits - %hp
        set %hp #hits
        if %roznica >= 0 && %roznica < 3
            return
        if %roznica < 0
            set %col 230
        else
            set %col 88
        set %roznica abs %roznica
        event exmsg #charid 3 %col %roznica [ , #hits , ]

return

sub zapisywanie
        set %zapis #scnt
        repeat
        {
            if %ji < #jindex
                set %ji %ji + 1
            scanjournal %ji
        }
        until Koniec in #journal
        set %leczy %leczy + #scnt - %zapis
        set %rozpoczetoleczenie %rozpoczetoleczenie + #scnt - %zapis
return