// F3 - Folk Group Markers
// Credits: Please see the F3 online manual (http://www.ferstaberinde.com/f3/en/)

private ["_grp", "_mkr"];

call compile format ["
    if (!isNil '%1') then {
	    _grp = %1;
    };
", _this select 0];

_grpName = _this select 0;
_mkrType = _this select 1;
_mkrText = _this select 2;
_mkrColor = _this select 3;

_mkrName = format ["mkr_%1", _grpName];

if (isNil "_grp") then {
	call compile format ["
		waitUntil {
		    sleep 3;

            if (!isNil '%1') then {
			    count units %1 > 0
		    };
		};

		_grp = %1;
	", _grpName];
};

if (isNil "_grp") exitWith {};

_Create_Marker = {
    params ["_type", ["_size", 0.8]];

    _mkr = createMarkerLocal [
        _mkrName,
        [(getPos leader _grp select 0), (getPos leader _grp select 1)]
    ];

    _mkr     setMarkerShapeLocal "ICON";
    _mkrName setMarkerSizeLocal  [_size, _size];
    _mkrName setMarkerTextLocal  _mkrText;
    _mkrName setMarkerTypeLocal  _type;
    _mkrName setMarkerAlphaLocal 0.9;
    _mkrName setMarkerColorLocal _mkrColor;
};

switch (_mkrType) do {
    case 0: { ["b_hq", 1]     call _Create_Marker; };
    case 1: { ["b_inf"]       call _Create_Marker; };
    case 2: { ["b_support"]   call _Create_Marker; };
    case 3: { ["b_motor_inf"] call _Create_Marker; };
    case 4: { ["b_recon"]     call _Create_Marker; };
    case 5: { ["b_mortar"]    call _Create_Marker; };
    case 6: { ["b_maint"]     call _Create_Marker; };
    case 7: { ["b_mech_inf"]  call _Create_Marker; };
    case 8: { ["b_armor"]     call _Create_Marker; };
    case 9: { ["b_air"]       call _Create_Marker; };
    case 10: { ["b_plane"]    call _Create_Marker; };
    case 11: { ["b_art"]      call _Create_Marker; };
    case 12: { ["b_hq", 1.2]  call _Create_Marker; };
    case 13: { ["b_service"]  call _Create_Marker; };
};

while {{!isNull _x} count units _grp > 0} do {
	_mkrName setMarkerPosLocal [
        (getPos leader _grp select 0),
        (getPos leader _grp select 1)
    ];

	sleep 1;
};