Working MP54

//	■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
//	PURCHASE SPRITE
//	■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■

spriteset(spriteset_EMU_PRR_MP54_purchase, "gfx/EMU/EMU_PRR_MP54.png") {
	template_purchase_dualheaded(1, 192)
}

//	■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
//	VEHICLE SPRITE(S)
//	■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■

//Front
spriteset(spriteset_EMU_PRR_MP54_front, "gfx/EMU/EMU_PRR_MP54.png") {
	template_2cc_engines_general(1, 1)
}

//Back
spriteset(spriteset_EMU_PRR_MP54_back, "gfx/EMU/EMU_PRR_MP54.png") {
	template_2cc_engines_general(1, 32)
}

//Middle - PAX-L1
spriteset(spriteset_EMU_PRR_MP54_middlepass_L1, "gfx/EMU/EMU_PRR_MP54.png") {
	template_2cc_engines_general(1, 64)
}

//Middle - MAIL-L1
spriteset(spriteset_EMU_PRR_MP54_middlemail_L1, "gfx/EMU/EMU_PRR_MP54.png") {
	template_2cc_engines_general(1, 96)
}

//Middle - PAX-L2
spriteset(spriteset_EMU_PRR_MP54_middlepass_L2, "gfx/EMU/EMU_PRR_MP54.png") {
	template_2cc_engines_general(1, 128)
}

//Middle - MAIL-L2
spriteset(spriteset_EMU_PRR_MP54_middlemail_L2, "gfx/EMU/EMU_PRR_MP54.png") {
	template_2cc_engines_general(1, 160)
}

//Dualheaded engines
switch(FEAT_TRAINS, SELF, switch_EMU_PRR_MP54_reversed, var[0xC8]) {
	0xFE: 	spriteset_EMU_PRR_MP54_back;
    0xFF: 	spriteset_EMU_PRR_MP54_back;
			spriteset_EMU_PRR_MP54_front;
}

//Visual effect, for EMU this is done on the part with the pantograph
random_switch(FEAT_TRAINS, SELF, switch_EMU_PRR_MP54_visual_effect_and_powered) {
	9: 	visual_effect_and_powered(VISUAL_EFFECT_DISABLE, 0, DISABLE_WAGON_POWER);
	1:	visual_effect_and_powered(VISUAL_EFFECT_ELECTRIC, -3, DISABLE_WAGON_POWER);
}

switch(FEAT_TRAINS, SELF, switch_EMU_PRR_MP54_visual_effect_and_powered_position, [STORE_TEMP(-1, 0x10F), var[0x61, 0, 0x0000FFFF, 0xC6]]) {
	ID_RANGE_UNIT_WAGONS: switch_EMU_PRR_MP54_visual_effect_and_powered;
	visual_effect_and_powered(VISUAL_EFFECT_ELECTRIC, -3, DISABLE_WAGON_POWER);
}

random_switch(FEAT_TRAINS, SELF, switch_EMU_PRR_MP54_middlepass_livery) {
	dependent:	switch_EMU_PRR_MP54_visual_effect_and_powered;
	9: 			spriteset_EMU_PRR_MP54_middlepass_L2;
	1: 			spriteset_EMU_PRR_MP54_middlepass_L1;
}

random_switch(FEAT_TRAINS, SELF, switch_EMU_PRR_MP54_middlemail_livery) {
	dependent: 	switch_EMU_PRR_MP54_visual_effect_and_powered;
	9: 			spriteset_EMU_PRR_MP54_middlemail_L2;
	1: 			spriteset_EMU_PRR_MP54_middlemail_L1;
}

//First unit wagon always has a pantograph
switch(FEAT_TRAINS, SELF, switch_EMU_PRR_MP54_middlepass_position, [STORE_TEMP(-1, 0x10F), var[0x61, 0, 0x0000FFFF, 0xC6]]) {
	ID_RANGE_UNIT_WAGONS: 	switch_EMU_PRR_MP54_middlepass_livery;
							spriteset_EMU_PRR_MP54_middlepass_L1;
}

switch(FEAT_TRAINS, SELF, switch_EMU_PRR_MP54_middlemail_position, [STORE_TEMP(-1, 0x10F), var[0x61, 0, 0x0000FFFF, 0xC6]]) {
	ID_RANGE_UNIT_WAGONS:	switch_EMU_PRR_MP54_middlemail_livery;
							spriteset_EMU_PRR_MP54_middlemail_L1;
}

//	■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
//	CARGO CAPACITY
//	■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■

switch(FEAT_TRAINS, SELF, switch_EMU_PRR_MP54_capacity, cargo_classes) {
	bitmask(CC_PASSENGERS): 72; // Passengers
	bitmask(CC_MAIL): 		52; // Mail Cargo
	bitmask(CC_ARMOURED): 	32; // Armored Cargos
							32; // All other Cargos
}

//Graphics for the unit wagon based on cargo class
switch(FEAT_TRAINS, SELF, switch_EMU_PRR_MP54_cargo_selection, cargo_classes){
	bitmask(CC_PASSENGERS): switch_EMU_PRR_MP54_middlepass_position;
							switch_EMU_PRR_MP54_middlemail_position;
}

//	■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
//	ITEM CODE
//	■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■

item(FEAT_TRAINS, item_EMU_PRR_MP54) {
    property {
        name: 							string(STR_NAME_EMU_PRR_MP54);

        introduction_date: 				date(1980,1,1);

		climates_available: 			ALL_CLIMATES;
	    running_cost_base: 				RUNNING_COST_ELECTRIC;
        engine_class: 					ENGINE_CLASS_ELECTRIC;
		track_type: 					ELRL;

		// ### LIFE ###
        model_life: 					25;
        vehicle_life: 					25;

		// ### COSTS ###
        cost_factor: 					23; //32,918
        running_cost_factor: 			19; //17,202

		weight: 						68000 kg;
        speed: 							104 km/h;
        power: 							450 hp;
        tractive_effort_coefficient: 	0.14;
		air_drag_coefficient: 			0;
		reliability_decay: 				20;

		LOADINGSPEEDDEF_COMMUTER
		CARGODEF_MU
        cargo_capacity: 				56;
		cargo_age_period: 				222;
		default_cargo_type:				PASS;



        refit_cost: 0;

		ai_special_flag: 				AI_FLAG_PASSENGER;
		misc_flags: 					bitmask(TRAIN_FLAG_MU,TRAIN_FLAG_2CC);
        visual_effect_and_powered: 		visual_effect_and_powered(VISUAL_EFFECT_DISABLE, 0, DISABLE_WAGON_POWER);

        sprite_id: 						SPRITE_ID_NEW_TRAIN;
        dual_headed: 					1;
        length: 						8;
        extra_power_per_wagon: 			0;
        bitmask_vehicle_info: 			0;
	}

//	■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■
//	GRAPHICS AND SWITCHES
//	■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■■

	graphics {
		additional_text:				string(STR_TEXT_EMU_PRR_MP54);
		purchase: 						spriteset_EMU_PRR_MP54_purchase;
		cargo_capacity: 				switch_EMU_PRR_MP54_capacity;
										switch_EMU_PRR_MP54_reversed;
	}
	livery_override (ITEM_SPECIAL_MU_CAR_UNPOWERED){
		LOADINGSPEEDDEF_COMMUTER
		running_cost_factor:			1;
		power: 							0;
		weight: 						35;
		cargo_capacity: 				switch_EMU_PRR_MP54_capacity;
		length: 						8;
		visual_effect_and_powered: 		switch_EMU_PRR_MP54_visual_effect_and_powered_position;
		default: 						switch_EMU_PRR_MP54_cargo_selection;
	}
	livery_override (ITEM_SPECIAL_MU_CAR_POWERED){
		LOADINGSPEEDDEF_COMMUTER
		running_cost_factor: 			15;
		power: 							100;
		weight: 						68;
		cargo_capacity: 				switch_EMU_PRR_MP54_capacity;
        tractive_effort_coefficient:	33;
		length: 						8;
		visual_effect_and_powered: 		switch_EMU_PRR_MP54_visual_effect_and_powered_position;
		default: 						switch_EMU_PRR_MP54_cargo_selection;
	}
}