Smplayer 14.3.0 QT4 version PKGBUILD and smplayer.install

PKGBUILD

# AndrzejL
pkgname=smplayer
pkgver=14.3.0
pkgrel=2
pkgdesc="A complete front-end for MPlayer"
arch=('i686' 'x86_64')
url="http://smplayer.sourceforge.net/"
license=('GPL')
depends=('qt4' 'mplayer')
optdepends=('smplayer-themes: icon themes collection'
'smplayer-skins: skin themes collection'
'smtube: browse and play youtube videos')
install=smplayer.install
provides=('smplayer-qt4')
source=(http://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-$pkgver.tar.bz2)
md5sums=('c6ef86f7fe0022b35c0f06430f4cd9bd')
build() {
  cd "smplayer-$pkgver"
  make PREFIX=/usr QMAKE=qmake-qt4 LRELEASE=lrelease-qt4 \
    DOC_PATH="\\\"/usr/share/doc/smplayer\\\"" \
    QMAKE_OPTS=DEFINES+=NO_DEBUG_ON_CONSOLE
}

package() {
  cd "smplayer-$pkgver"
  make DOC_PATH=/usr/share/doc/smplayer \
    DESTDIR="$pkgdir" PREFIX="/usr" install
}

smplayer.install

post_install() {
     xdg-icon-resource forceupdate --theme hicolor &> /dev/null
     update-desktop-database -q
}

post_upgrade() {
    post_install
}

post_remove() {
    post_install
}