Windowsinfo.bat.RENAME

@echo off

REM set variables
set system=
set osname=
set osarch=
set sp=
set cpuname=
set gpuname=
setlocal ENABLEDELAYEDEXPANSION
set totalMem=
set mvnversion=

echo Getting data. Please Wait...

REM Get Computer Name
FOR /F "tokens=2 delims='='" %%A in ('wmic OS Get csname /value') do SET system=%%A

REM Get Computer OS
FOR /F "tokens=2 delims='='" %%A in ('wmic os get Name /value') do SET osname=%%A
FOR /F "tokens=1 delims='|'" %%A in ("%osname%") do SET osname=%%A
FOR /F "tokens=2 delims='='" %%A in ('wmic os get OSArchitecture /value') do SET osarch=%%A

REM Get Computer OS SP
FOR /F "tokens=2 delims='='" %%A in ('wmic os get ServicePackMajorVersion /value') do SET sp=%%A

REM Get CPU details
FOR /F "tokens=2 delims='='" %%A in ('wmic cpu get Name /value') do SET cpuname=%%A

REM Get GPU details
FOR /F "tokens=2 delims='='" %%A in ('wmic path Win32_VideoController get Name /value') do SET gpuname=%%A

REM Get Memory
FOR /F "tokens=4" %%a in ('systeminfo ^| findstr Physical') do if defined totalMem (set availableMem=%%a) else (set totalMem=%%a)
set totalMem=%totalMem:,=%
set /a usedMem=totalMem-availableMem

echo --------------------------------------------
echo Operating System: %osname% %osarch%
echo Service Pack: %sp%
echo Processor: %cpuname%
echo GPU: %gpuname%
echo Total Memory: %totalMem%
echo --------------------------------------------
echo -- Java --
java -version
echo Java home: %JAVA_HOME%
echo --------------------------------------------
echo -- cl.exe --
where cl.exe
cl.exe
echo -- vcvars32.bat --
where vcvars32.bat
echo -- vcvars64.bat --
where vcvars64.bat
echo -- CUDA --
nvcc --version
echo -- GIT --
git --version
echo -- Maven --
FOR /f "tokens=*" %%a in ('mvn --version') do echo %%a
echo -- OpenBLAS --
echo libblas3.dll, liblapack3.dll, libopenblas.dll:
where libblas3.dll
where liblapack3.dll
where libopenblas.dll
echo --------------------------------------------
echo -- PATH --
echo %PATH%
echo --------------------------------------------

:END