@AbapCatalog.sqlViewName: 'IPPMFGORDEROPC'
@AccessControl.authorizationCheck: #CHECK
@Analytics: {dataCategory: #CUBE, dataExtraction.enabled: true}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Manufacturing Order Operation Cube'

define view I_MfgOrderOperationCube
  as select from I_MfgOrderOperation as oper
    left outer join P_MfgOrderOpDurnInWorkdays (im_clnt : $session.client)
                                                 as durn on  durn.sapclient                      = mandt
                                                         and durn.ManufacturingOrder             = oper.ManufacturingOrder
                                                         and durn.ManufacturingOrderSequence     = oper.ManufacturingOrderSequence
                                                         and durn.ManufacturingOrderOperation    = oper.ManufacturingOrderOperation
                                                         and durn.ManufacturingOrderSubOperation = oper.ManufacturingOrderSubOperation
                                                         and durn.OpErlstSchedldExecStrtDte      = oper.OpErlstSchedldExecStrtDte
                                                         and durn.OpErlstSchedldExecEndDte       = oper.OpErlstSchedldExecEndDte
                                                         and durn.OpLtstSchedldExecStrtDte       = oper.OpLtstSchedldExecStrtDte
                                                         and durn.OpLtstSchedldExecEndDte        = oper.OpLtstSchedldExecEndDte
                                                         and durn.OpActualExecutionStartDate     = oper.OpActualExecutionStartDate
                                                         and durn.OpActualExecutionEndDate       = oper.OpActualExecutionEndDate
    left outer join P_MfgOrderOpDayDurnInSeconds (im_clnt : $session.client)
                                                         as ddis on  ddis.sapclient              = mandt
                                                         and ddis.ManufacturingOrder             = oper.ManufacturingOrder
                                                         and ddis.ManufacturingOrderSequence     = oper.ManufacturingOrderSequence
                                                         and ddis.ManufacturingOrderOperation    = oper.ManufacturingOrderOperation
                                                         and ddis.ManufacturingOrderSubOperation = oper.ManufacturingOrderSubOperation
                                                         and ddis.OpLtstSchedldExecStrtDte       = oper.OpLtstSchedldExecStrtDte
                                                         and ddis.OpLtstSchedldExecStrtTme       = oper.OpLtstSchedldExecStrtTme
                                                         and ddis.OpLtstSchedldExecEndDte        = oper.OpLtstSchedldExecEndDte
                                                         and ddis.OpLtstSchedldExecEndTme        = oper.OpLtstSchedldExecEndTme
                                                         and ddis.OpActualExecutionStartDate     = oper.OpActualExecutionStartDate
                                                         and ddis.OpActualExecutionStartTime     = oper.OpActualExecutionStartTime
                                                         and ddis.OpActualExecutionEndDate       = oper.OpActualExecutionEndDate
                                                         and ddis.OpActualExecutionEndTime       = oper.OpActualExecutionEndTime

    inner join I_OrderOperationStatus as stat on  stat.OrderInternalID          = oper.OrderInternalBillOfOperations // Status
                                              and stat.OrderOperationInternalID = oper.OrderIntBillOfOperationsItem

  association [1..1] to I_CalendarDate            as _StartDate               on  $projection.OpErlstSchedldExecStrtDte = _StartDate.CalendarDate
  association [0..1] to I_WorkCenterBySemanticKey as _WorkCenterBySemanticKey on  $projection.WorkCenter      = _WorkCenterBySemanticKey.WorkCenter
                                                                              and $projection.ProductionPlant = _WorkCenterBySemanticKey.Plant
{
      // Technical Key
      @ObjectModel.foreignKey.association: '_OrdInternalBillOfOperations'
  key oper.OrderInternalBillOfOperations,
  key oper.OrderIntBillOfOperationsItem,

      // Semantical Key
      @ObjectModel.foreignKey.association: '_MfgOrder'
      oper.ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_MfgOrderSequence'
      oper.ManufacturingOrderSequence,
      @ObjectModel.text.element: 'MfgOrderOperationText'
      oper.ManufacturingOrderOperation,
      @ObjectModel.text.element: 'MfgOrderOperationText'
      oper.ManufacturingOrderSubOperation,

      // Order header data
      @ObjectModel.foreignKey.association: '_MfgOrderCategory'
      ManufacturingOrderCategory,
      @ObjectModel.foreignKey.association: '_MfgOrderType'
      ManufacturingOrderType,
      @ObjectModel.foreignKey.association: '_ProductionSupervisor'
      ProductionSupervisor,
      @ObjectModel.foreignKey.association: '_MRPController'
      MRPController,
      @ObjectModel.foreignKey.association: '_ResponsiblePlannerGroup'
      ResponsiblePlannerGroup,

      // Text
      @Semantics.text: true
      MfgOrderOperationText,
      @ObjectModel.foreignKey.association: '_Language'
      Language,
      @ObjectModel.foreignKey.association: '_OperationStandardTextCode'
      OperationStandardTextCode,

      // Attributes
      MfgOrderOperationIsPhase,
      MfgOrderPhaseSuperiorOperation,
      NumberOfCapacities,
      NumberOfConfirmationSlips,
      OperationConfirmationCount as NumberOfOperationConfirmations,
      OperationImportance,

      // Status
      stat.OperationIsCreated,
      stat.OperationIsReleased,
      stat.OperationIsPrinted,
      stat.OperationIsConfirmed,
      stat.OperationIsPartiallyConfirmed,
      stat.OperationIsDeleted,
      stat.OperationIsTechlyCompleted,
      stat.OperationIsClosed,
      stat.OperationIsScheduled,
      stat.OperationIsPartiallyDelivered,
      stat.OperationIsDelivered,

      // Assignments
      @ObjectModel.foreignKey.association: '_ProductionPlant'
      ProductionPlant,
      @ObjectModel.foreignKey.association: '_WorkCenter'
      WorkCenterInternalID,
      @ObjectModel.foreignKey.association: '_WorkCenterType'
      WorkCenterTypeCode,
      @ObjectModel.foreignKey.association: '_WorkCenterBySemanticKey'
      cast(_WorkCenter.WorkCenter as pph_arbpl preserving type) as WorkCenter,
      @ObjectModel.foreignKey.association: '_OperationControlProfile'
      OperationControlProfile,
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
      BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_OperationConfirmation'
      OperationConfirmation,
      @ObjectModel.foreignKey.association: '_CapacityRequirement'
      CapacityRequirement,
      @ObjectModel.foreignKey.association: '_CapacityRequirementItem'
      CapacityRequirementItem,

      // Assignments Purchasing
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      PurchasingOrganization,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      PurchasingGroup,
--    @ObjectModel.foreignKey.association: '_PurchaseRequisition'
      PurchaseRequisition,
--    @ObjectModel.foreignKey.association: '_PurchaseRequisitionItem'
      PurchaseRequisitionItem,
--    @ObjectModel.foreignKey.association: '_PurchaseOrder'
      PurchaseOrder,
--    @ObjectModel.foreignKey.association: '_PurchaseOrderItem'
      PurchaseOrderItem,
--    @ObjectModel.foreignKey.association: '_PurchasingInfoRecord'
      PurchasingInfoRecord,
      PurgInfoRecdDataIsFixed,
      PurchasingInfoRecordCategory,
      @ObjectModel.foreignKey.association: '_Supplier'
      Supplier,
      @Semantics.text: true
      GoodsRecipientName,
      @Semantics.text: true
      UnloadingPointName,

      // Amount and Currency
      @Semantics.currencyCode: true
      OpExternalProcessingCurrency,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'OpExternalProcessingCurrency'
      OpExternalProcessingPrice,
      NumberOfOperationPriceUnits,

      // Assignments FI/CO
      @ObjectModel.foreignKey.association: '_CompanyCode'
      CompanyCode,
      @ObjectModel.foreignKey.association: '_BusinessArea'
      BusinessArea,
      @ObjectModel.foreignKey.association: '_ControllingArea'
      ControllingArea,
      @ObjectModel.foreignKey.association: '_ProfitCenter'
      ProfitCenter,
      RequestingCostCenter,
      CostElement,
      CostingVariant,
      CostingSheet,
      CostEstimate,
      ControllingObjectCurrency,
      @ObjectModel.foreignKey.association: '_ControllingObjectClass'
      ControllingObjectClass,
      @ObjectModel.foreignKey.association: '_FunctionalArea'
      FunctionalArea,
      TaxJurisdiction,

      // Assignments HR
      EmployeeWageType,
      @ObjectModel.foreignKey.association: '_EmployeeWageGroup'
      EmployeeWageGroup,
      @ObjectModel.foreignKey.association: '_EmployeeSuitability'
      EmployeeSuitability,
      NumberOfTimeTickets,
--    @ObjectModel.foreignKey.association: '_Employee'
      Personnel,
      NumberOfEmployees,

      // Setup and Overlapping
      @ObjectModel.foreignKey.association: '_OperationSetupGroupCategory'
      OperationSetupGroupCategory,
      @ObjectModel.foreignKey.association: '_OperationSetupGroup'
      OperationSetupGroup,
      @ObjectModel.foreignKey.association: '_OperationSetupType'
      OperationSetupType,
      OperationOverlappingIsRequired,
      OperationOverlappingIsPossible,
      OperationsIsAlwaysOverlapping,
      OperationSplitIsRequired,
      MaximumNumberOfSplits,
      @ObjectModel.foreignKey.association: '_LeadTimeReductionStrategy'
      LeadTimeReductionStrategy,
      OpSchedldReductionLevel,

      // Dates and Times
      @Semantics.calendarItem.dtStart: true
      oper.OpErlstSchedldExecStrtDte,
      OpErlstSchedldExecStrtTme,
      @Semantics.calendarItem.dtStart: true
      OpErlstSchedldProcgStrtDte,
      OpErlstSchedldProcgStrtTme,
      @Semantics.calendarItem.dtStart: true
      OpErlstSchedldTrdwnStrtDte,
      OpErlstSchedldTrdwnStrtTme,
      @Semantics.calendarItem.dtEnd: true
      oper.OpErlstSchedldExecEndDte,
      OpErlstSchedldExecEndTme,
      @Semantics.calendarItem.dtStart: true
      oper.OpLtstSchedldExecStrtDte,
      oper.OpLtstSchedldExecStrtTme,
      @Semantics.calendarItem.dtStart: true
      OpLtstSchedldProcgStrtDte,
      OpLtstSchedldProcgStrtTme,
      @Semantics.calendarItem.dtStart: true
      OpLtstSchedldTrdwnStrtDte,
      OpLtstSchedldTrdwnStrtTme,
      @Semantics.calendarItem.dtEnd: true
      oper.OpLtstSchedldExecEndDte,
      oper.OpLtstSchedldExecEndTme,
      @Semantics.calendarItem.dtStart: true
      OperationConfirmedStartDate,
      OperationConfirmedEndDate,
      @Semantics.calendarItem.dtStart: true
      oper.OpActualExecutionStartDate,
      oper.OpActualExecutionStartTime,
      @Semantics.calendarItem.dtEnd: true
      OpActualSetupEndDate,
      OpActualSetupEndTime,
      @Semantics.calendarItem.dtStart: true
      OpActualProcessingStartDate,
      OpActualProcessingStartTime,
      @Semantics.calendarItem.dtEnd: true
      OpActualProcessingEndDate,
      OpActualProcessingEndTime,
      @Semantics.calendarItem.dtStart: true
      OpActualTeardownStartDate,
      OpActualTeardownStartTme,
      @Semantics.calendarItem.dtEnd: true
      oper.OpActualExecutionEndDate,
      oper.OpActualExecutionEndTime,
      // Forecast Dates and Times
      @Semantics.calendarItem.dtEnd: true
      ActualForecastEndDate,
      ActualForecastEndTime,
      @Semantics.calendarItem.dtStart: true
      SchedldFcstdEarliestStartDate,
      SchedldFcstdEarliestStartTime,
      @Semantics.calendarItem.dtEnd: true
      SchedldFcstdEarliestEndDate,
      SchedldFcstdEarliestEndTime,
      @Semantics.calendarItem.dtStart: true
      LatestSchedldFcstdStartDate,
      SchedldFcstdLatestStartTime,
      @Semantics.calendarItem.dtEnd: true
      LatestSchedldFcstdEndDate,
      SchedldFcstdLatestEndTime,

      // Durations
      @Semantics.calendarItem.duration: true
      durn.ErlstSchedldExecDurnInWorkdays as ErlstSchedldExecDurnInWorkdays,
      @Semantics.calendarItem.duration: true
      durn.LtstSchedldExecDurnInWorkdays  as LtstSchedldExecDurnInWorkdays,
      @Semantics.calendarItem.duration: true
      durn.actualexecutiondurninworkdays  as OpActualExecutionDays,

      @Semantics.calendarItem.duration: true
      ddis.ActualWorkdayDurnInSeconds     as ActualWorkdayDurnInSeconds,
      @Semantics.calendarItem.duration: true
      ddis.PlannedWorkdayDurnInSeconds    as PlannedWorkdayDurnInSeconds,
      @Semantics.calendarItem.duration: true
      ddis.DeviationDurationInSeconds     as DeviationWorkdayDurnInSeconds,

      // former TF content is replaced by SQL function in I_MfgOrderOperation view
      @Semantics.calendarItem.duration: true
      oper.PlannedActualStartDateDvtnDurn,
      @Semantics.calendarItem.duration: true
      oper.PlannedActualEndDateDvtnDurn,
      @Semantics.calendarItem.duration: true
      oper.PlannedCurrentStrtDateDvtnDurn,
      @Semantics.calendarItem.duration: true
      oper.PlannedCurrentEndDateDvtnDurn,

      // Start and End is Late by Deviation in Seconds
      cast( case
        when stat.OperationIsPartiallyConfirmed = 'X' then
          case
            when oper.PlannedActualStartDateDvtnDurn > 0
            then 'X'
            else ''
          end
        else
          case
            when (stat.OperationIsReleased = 'X' and stat.OperationIsConfirmed = '') then
              case
                when oper.PlannedCurrentStrtDateDvtnDurn > 0
                then 'X'
                else''
              end
            else ''
          end
      end as executionstartislate preserving type) as OperationExecutionStartIsLate,
      cast( case
        when stat.OperationIsConfirmed = 'X' then
          case
            when oper.PlannedActualEndDateDvtnDurn > 0
            then 'X'
            else ''
          end
        else
          case
            when (stat.OperationIsPartiallyConfirmed = 'X' and stat.OperationIsConfirmed = '') then
              case
                when oper.PlannedCurrentEndDateDvtnDurn > 0
                then 'X'
                else''
              end
            else ''
          end
      end as executionendislate preserving type)   as OperationExecutionEndIsLate,

      // Deviation
      case
        when durn.actualexecutiondurninworkdays >= 0
          then case
            when durn.ErlstSchedldExecDurnInWorkdays >= 0
              then (durn.actualexecutiondurninworkdays - durn.ErlstSchedldExecDurnInWorkdays)
            else 0
          end
        else 0
      end                                 as OpExecutionDurnDeviationDays,

      // Duration Unit calculation
      @Semantics.unitOfMeasure: true
      case
        when ActualWorkdayDurnInSeconds < 60        then cast('S'   as abap.unit( 3 ))
        when ActualWorkdayDurnInSeconds < 3600      then cast('MIN' as abap.unit( 3 ))
        when ActualWorkdayDurnInSeconds < 86400     then cast('STD' as abap.unit( 3 ))
        when ActualWorkdayDurnInSeconds < 604800    then cast('TAG' as abap.unit( 3 ))
        when ActualWorkdayDurnInSeconds < 2592000   then cast('WCH' as abap.unit( 3 ))
        when ActualWorkdayDurnInSeconds < 31536000  then cast('MON' as abap.unit( 3 ))
        else cast('JHR' as abap.unit( 3 ))
      end as ActualDurationUnit,

      @Semantics.unitOfMeasure: true
      case
        when PlannedWorkdayDurnInSeconds < 60        then cast('S'   as abap.unit( 3 ))
        when PlannedWorkdayDurnInSeconds < 3600      then cast('MIN' as abap.unit( 3 ))
        when PlannedWorkdayDurnInSeconds < 86400     then cast('STD' as abap.unit( 3 ))
        when PlannedWorkdayDurnInSeconds < 604800    then cast('TAG' as abap.unit( 3 ))
        when PlannedWorkdayDurnInSeconds < 2592000   then cast('WCH' as abap.unit( 3 ))
        when PlannedWorkdayDurnInSeconds < 31536000  then cast('MON' as abap.unit( 3 ))
        else cast('JHR' as abap.unit( 3 ))
      end as PlannedDurationUnit,

      @Semantics.unitOfMeasure: true
      case
        when DeviationDurationInSecondsABS < 60        then cast('S'   as abap.unit( 3 ))
        when DeviationDurationInSecondsABS < 3600      then cast('MIN' as abap.unit( 3 ))
        when DeviationDurationInSecondsABS < 86400     then cast('STD' as abap.unit( 3 ))
        when DeviationDurationInSecondsABS < 604800    then cast('TAG' as abap.unit( 3 ))
        when DeviationDurationInSecondsABS < 2592000   then cast('WCH' as abap.unit( 3 ))
        when DeviationDurationInSecondsABS < 31536000  then cast('MON' as abap.unit( 3 ))
        else cast('JHR' as abap.unit( 3 ))
      end as DeviationDurationUnit,

      @Semantics.unitOfMeasure: true
      cast('S' as abap.unit( 3 )) as DurationUnit,  //always in seconds

      // Offset
      StartDateOffsetReferenceCode,
      @Semantics.unitOfMeasure: true
      StartDateOffsetDurationUnit,
      @Semantics.calendarItem.duration: true
      StartDateOffsetDuration,
      EndDateOffsetReferenceCode,
      @Semantics.unitOfMeasure: true
      EndDateOffsetDurationUnit,
      @Semantics.calendarItem.duration: true
      EndDateOffsetDuration,

      // Quantities and UoM
      @Semantics.unitOfMeasure: true
      OperationUnit,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @DefaultAggregation: #MAX
      OperationReferenceQuantity,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @DefaultAggregation: #SUM
      OpPlannedTotalQuantity,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @DefaultAggregation: #SUM
      OpPlannedScrapQuantity,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @DefaultAggregation: #SUM
      OpPlannedYieldQuantity,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @DefaultAggregation: #SUM
      OpTotalConfirmedYieldQty,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @DefaultAggregation: #SUM
      OpTotalConfirmedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @DefaultAggregation: #SUM
      OperationConfirmedReworkQty,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @DefaultAggregation: #MAX
      cast( case stat.OperationIsConfirmed
        when 'X' then (OpTotalConfirmedYieldQty - OpPlannedYieldQuantity)
        else 0
      end as opyielddeviationqty) as OperationYieldDeviationQty,
      @Semantics.unitOfMeasure: true
      ProductionUnit,
      @Semantics.quantity.unitOfMeasure: 'ProductionUnit'
      @DefaultAggregation: #SUM
      OpTotConfdYieldQtyInOrdQtyUnit,

      // Confirmed Work Quantities and UoM
      @Semantics.unitOfMeasure: true
      OpWorkQuantityUnit1,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit1'
      @DefaultAggregation: #SUM
      OpConfirmedWorkQuantity1,
      NoFurtherOpWorkQuantity1IsExpd,
      @Semantics.unitOfMeasure: true
      OpWorkQuantityUnit2,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit2'
      @DefaultAggregation: #SUM
      OpConfirmedWorkQuantity2,
      NoFurtherOpWorkQuantity2IsExpd,
      @Semantics.unitOfMeasure: true
      OpWorkQuantityUnit3,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit3'
      @DefaultAggregation: #SUM
      OpConfirmedWorkQuantity3,
      NoFurtherOpWorkQuantity3IsExpd,
      @Semantics.unitOfMeasure: true
      OpWorkQuantityUnit4,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit4'
      @DefaultAggregation: #SUM
      OpConfirmedWorkQuantity4,
      NoFurtherOpWorkQuantity4IsExpd,
      @Semantics.unitOfMeasure: true
      OpWorkQuantityUnit5,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit5'
      @DefaultAggregation: #SUM
      OpConfirmedWorkQuantity5,
      NoFurtherOpWorkQuantity5IsExpd,
      @Semantics.unitOfMeasure: true
      OpWorkQuantityUnit6,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit6'
      @DefaultAggregation: #SUM
      OpConfirmedWorkQuantity6,
      NoFurtherOpWorkQuantity6IsExpd,

      // Work Quantities and UoM
      @Semantics.unitOfMeasure: true
      WorkCenterStandardWorkQtyUnit1,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit1'
      @DefaultAggregation: #SUM
      WorkCenterStandardWorkQty1,
      CostCtrActivityType1,
      @Semantics.unitOfMeasure: true
      WorkCenterStandardWorkQtyUnit2,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit2'
      @DefaultAggregation: #SUM
      WorkCenterStandardWorkQty2,
      CostCtrActivityType2,
      @Semantics.unitOfMeasure: true
      WorkCenterStandardWorkQtyUnit3,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit3'
      @DefaultAggregation: #SUM
      WorkCenterStandardWorkQty3,
      CostCtrActivityType3,
      @Semantics.unitOfMeasure: true
      WorkCenterStandardWorkQtyUnit4,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit4'
      @DefaultAggregation: #SUM
      WorkCenterStandardWorkQty4,
      CostCtrActivityType4,
      @Semantics.unitOfMeasure: true
      WorkCenterStandardWorkQtyUnit5,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit5'
      @DefaultAggregation: #SUM
      WorkCenterStandardWorkQty5,
      CostCtrActivityType5,
      @Semantics.unitOfMeasure: true
      WorkCenterStandardWorkQtyUnit6,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit6'
      @DefaultAggregation: #SUM
      WorkCenterStandardWorkQty6,
      CostCtrActivityType6,

      // Forecast Work Quantities
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit1'
      @DefaultAggregation: #SUM
      ForecastWorkQuantity1,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit2'
      @DefaultAggregation: #SUM
      ForecastWorkQuantity2,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit3'
      @DefaultAggregation: #SUM
      ForecastWorkQuantity3,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit4'
      @DefaultAggregation: #SUM
      ForecastWorkQuantity4,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit5'
      @DefaultAggregation: #SUM
      ForecastWorkQuantity5,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit6'
      @DefaultAggregation: #SUM
      ForecastWorkQuantity6,

      // Business Process
      @ObjectModel.foreignKey.association: '_BusinessProcess'
      BusinessProcess,
      @Semantics.unitOfMeasure: true
      BusinessProcessEntryUnit,
      @Semantics.quantity.unitOfMeasure: 'BusinessProcessEntryUnit'
      @DefaultAggregation: #SUM
      BusinessProcessConfirmedQty,
      NoFurtherBusinessProcQtyIsExpd,

      // OAN data
--    @ObjectModel.foreignKey.association: '_SetupOpActyNtwkInstance'
      SetupOpActyNtwkInstance,
--    @ObjectModel.foreignKey.association: '_ProduceOpActyNtwkInstance'
      ProduceOpActyNtwkInstance,
--    @ObjectModel.foreignKey.association: '_TeardownOpActyNtwkInstance'
      TeardownOpActyNtwkInstance,

      // Associations
      oper._OrdInternalBillOfOperations,
      _MfgOrder,
      _MfgOrderSequence,
      _MfgOrderCategory,
      _MfgOrderType,
      _OperationStandardTextCode,
      _ProductionPlant,
      _ProductionSupervisor,
      _ProductionUnit,
      _OperationUnit,
      _OperationControlProfile,
      _BillOfOperationsType,
      _WorkCenter,
      _WorkCenterType,
      _WorkCenterBySemanticKey,
      _MRPController,
      _ResponsiblePlannerGroup,
      _CapacityRequirement,
      _CapacityRequirementItem,
      _OperationConfirmation,
      _PurchasingOrganization,
      _PurchasingGroup,
      _PurchaseOrder,
      _PurchaseOrderItem,
      _PurchaseRequisition,
      _PurchaseRequisitionItem,
      _PurchasingInfoRecord,
      _Supplier,
      _OpExternalProcessingCurrency,
      _EmployeeWageGroup,
      _EmployeeSuitability,
      _Employee,
      _CompanyCode,
      _ProfitCenter,
      _ControllingArea,
      _ControllingObjectClass,
      _FunctionalArea,
      _BusinessArea,
      _BusinessProcess,
      _BusinessProcessEntryUnit,
      _OperationSetupGroupCategory,
      _OperationSetupGroup,
      _OperationSetupType,
      _LeadTimeReductionStrategy,
      _Language,
      _SetupOpActyNtwkInstance,
      _ProduceOpActyNtwkInstance,
      _TeardownOpActyNtwkInstance,
      _StartDate
}
where OperationIsToBeDeleted = ''; //Non-deleted operations only