Windows 10 RTM Enable Colored Window Chrome

@echo off

cls

:question
echo.
echo ARE YOU RUNNING THIS AS A ADMINISTRATOR?
echo.
SET /P ANSWER=(YES/NO):
if /i {"%ANSWER%"}=={"y"}   (goto :start)
if /i {"%ANSWER%"}=={"yes"} (goto :start)
if /i {"%ANSWER%"}=={"n"}   (goto :cancel)
if /i {"%ANSWER%"}=={"no"}  (goto :cancel)
goto :input_error

:input_error
cls
echo.
echo          *ERROR: Invalid Answer
echo _________________________________________
goto :question

:start
C:

cd \Windows\Resources\Themes\aero\en-US
echo F|xcopy /h /k /o /x aero.msstyles.mui aerocolor.msstyles.mui
cd \Windows\Resources\Themes\aero
echo F|xcopy /h /k /o /x aero.msstyles aerocolor.msstyles
cd \Windows\Resources\Themes
echo F|xcopy /h /k aero.theme aerocolor.theme

set SCRIPT1="%temp%\%RANDOM%.vbs"

echo Const ForReading = 1 >> %SCRIPT1%
echo Const ForWriting = 2 >> %SCRIPT1%
echo strFileName = Wscript.Arguments(0) >> %SCRIPT1%
echo strOldText = Wscript.Arguments(1) >> %SCRIPT1%
echo strNewText = Wscript.Arguments(2) >> %SCRIPT1%
echo Set objFSO = CreateObject("Scripting.FileSystemObject") >> %SCRIPT1%
echo Set objFile = objFSO.OpenTextFile(strFileName, ForReading) >> %SCRIPT1%
echo strText = objFile.ReadAll >> %SCRIPT1%
echo objFile.Close >> %SCRIPT1%
echo strNewText = Replace(strText, strOldText, strNewText) >> %SCRIPT1%
echo Set objFile = objFSO.OpenTextFile(strFileName, ForWriting) >> %SCRIPT1%
echo objFile.Write strNewText >> %SCRIPT1%
echo objFile.Close >> %SCRIPT1%

cscript /nologo %SCRIPT1% "aerocolor.theme" "DisplayName=" ";DisplayName="
cscript /nologo %SCRIPT1% "aerocolor.theme" "SetLogonBackground=0" "DisplayName=Windows Color"
cscript /nologo %SCRIPT1% "aerocolor.theme" "Aero.msstyles" "AeroColor.msstyles"
cscript /nologo %SCRIPT1% "aerocolor.theme" "0XC40078D7" "0XC4E6E6E6"

del %SCRIPT1%

icacls aerocolor.theme /grant "ALL APPLICATION PACKAGES:(RX)"
icacls aerocolor.theme /grant "BUILTIN\Users:(RX)"
icacls aerocolor.theme /grant "NT AUTHORITY\SYSTEM:(RX)"
icacls aerocolor.theme /grant "BUILTIN\Administrators:(RX)"
icacls aerocolor.theme /grant "NT SERVICE\TrustedInstaller:(F)"
icacls aerocolor.theme /setowner "NT SERVICE\TrustedInstaller"
icacls aerocolor.theme /inheritance:r

set SCRIPT2="%temp%\%RANDOM%.vbs"

echo Set oWS = WScript.CreateObject("WScript.Shell") >> %SCRIPT2%
echo sLinkFile = "%USERPROFILE%\Desktop\Color and Appearance.lnk" >> %SCRIPT2%
echo Set oLink = oWS.CreateShortcut(sLinkFile) >> %SCRIPT2%

echo oLink.TargetPath = "%SystemRoot%\System32\control.exe" >> %SCRIPT2%
echo oLink.Arguments = " Color" >> %SCRIPT2%
echo oLink.WorkingDirectory = "" >> %SCRIPT2%
echo oLink.Description = "Change the color of your taskbar, window borders, and Start menu." >> %SCRIPT2%
echo oLink.IconLocation = "%SystemRoot%\System32\themecpl.dll" >> %SCRIPT2%
echo oLink.Save >> %SCRIPT2%

cscript /nologo %SCRIPT2%
del %SCRIPT2%


set SCRIPT3="%temp%\%RANDOM%.vbs"

echo Set oWS = WScript.CreateObject("WScript.Shell") >> %SCRIPT3%
echo sLinkFile = "C:\ProgramData\Microsoft\Windows\Start Menu\Programs\Administrative Tools\Color and Appearance.lnk" >> %SCRIPT3%
echo Set oLink = oWS.CreateShortcut(sLinkFile) >> %SCRIPT3%

echo oLink.TargetPath = "%SystemRoot%\System32\control.exe" >> %SCRIPT3%
echo oLink.Arguments = " Color" >> %SCRIPT3%
echo oLink.WorkingDirectory = "" >> %SCRIPT3%
echo oLink.Description = "Change the color of your taskbar, window borders, and Start menu." >> %SCRIPT3%
echo oLink.IconLocation = "%SystemRoot%\System32\themecpl.dll" >> %SCRIPT3%
echo oLink.Save >> %SCRIPT3%

cscript /nologo %SCRIPT3%
del %SCRIPT3%

cd "\ProgramData\Microsoft\Windows\Start Menu\Programs\Administrative Tools"
start .

start \Windows\Resources\Themes\aerocolor.theme

\Windows\System32\control.exe Color

cd %USERPROFILE%

cls

echo.
echo.
echo DONE. Script has no error checking, please do not run more than once.
echo.
pause
cls
goto :finished

:cancel
cls

:finished
echo.

@echo on

:eof