b: [
    LoginScreen: [
        grid 2 2 padding 10 spacing 10 [
            label "User name:"
            username: text-input
            label "Password"
            password: text-input password
        ]
    ]
]

screen: [object [name: set-word! contents: into widget]]

widget: [
    object [
        opt [id: set-word!] [
            type: 'grid rows: number! cols: number!
                any ['padding padding: number! | 'spacing spacing: number!]
                contents: into [collect [some [keep widget]]]
            |
            type: 'label label: string!
            |
            type: 'text-input is-password: ['password (true) | (false)]
        ]
    ]
]

result: parse b screen

print mold result

object none [
    name: LoginScreen:
    contents: object none [
        type: 'grid
        rows: 2
        cols: 2
        padding: 10
        spacing: 10
        contents: [
            object none [
                type: 'label
                label: "User name:"
            ]
            object none [
                id: username:
                type: 'text-input
                is-password: false
            ]
            object none [
                type: 'label
                label: "Password"
            ]
            object none [
                id: password:
                type: 'text-input
                is-password: true
            ]
        ]
    ]
]