ED - TAD Lista - Enlazada simple v. 3

UNIT uListaEnlazadaSimple;
INTERFACE
    USES uElemento;
        {PARAMETROS GENERICOS: Funciones Asignar() y SonIguales() propias de cada tipo de elemento}
    TYPE
        TLista = ^TNodo;
        TNodo = RECORD
            info : TElemento;
            sig : TLista;
        END;

    {Constructoras generadoras}
        PROCEDURE CrearVacia(VAR l : TLista);
        PROCEDURE Construir(VAR l : TLista; e : TElemento);
    {Constructoras no generadoras}
        PROCEDURE Concatenar(VAR l : TLista; r : TLista);
        PROCEDURE BorrarElemento(VAR l : TLista; e : TElemento);
        PROCEDURE InsertarFinal(VAR l : TLista; e : TElemento);
    {Observadoras selectoras}
        PROCEDURE Primero(l : TLista; VAR e : TElemento);
        PROCEDURE Resto(l : TLista; VAR r : TLista);
    {Observadoras no selectoras}
        FUNCTION EsVacia(l : TLista):boolean;
        FUNCTION Longitud(l : TLista):integer;
        PROCEDURE Ultimo(l : TLista; VAR e : TElemento);
        FUNCTION Pertenece(l : TLista; e : TElemento):boolean;

IMPLEMENTATION
{Constructoras generadoras}
    PROCEDURE CrearVacia(VAR l : TLista);
        BEGIN
            l := NIL;
        END;
    PROCEDURE Construir(VAR l : TLista; e : TElemento);
        VAR
            aux : TLista;
        BEGIN
            new(aux);
            Asignar(aux^.info, e);
            aux^.sig := l;
            l := aux;
        END;

{Constructoras no generadoras}
    PROCEDURE Concatenar(VAR l : TLista; r : TLista);
        VAR
            aux : TLista;
        BEGIN
            IF(NOT EsVacia(r)) THEN BEGIN
                aux := l;
                WHILE (aux^.sig <> NIL) DO
                    aux := aux^.sig;
                aux^.sig := r;
            END;
        END;
    PROCEDURE BorrarElemento(VAR l : TLista; e : TElemento);
        VAR
            aux, aux2 : TLista;
            encontrado : boolean;
        BEGIN
            aux := l;
            aux2 := l;
            encontrado := FALSE;
            WHILE ((aux <> NIL) AND (NOT encontrado)) DO BEGIN
                IF (SonIguales(aux^.info, e)) THEN BEGIN
                    IF (SonIguales(l^.info, e)) THEN
                        l := aux^.sig
                    ELSE
                        aux2^.sig := aux^.sig;
                    dispose(aux);
                    encontrado := TRUE;
                END;
                aux2 := aux;
                aux := aux^.sig;
            END;
        END;
    PROCEDURE InsertarFinal(VAR l : TLista; e : TElemento);
        VAR
            aux, aux2 : TLista;
        BEGIN
            aux2 := l;
            IF (NOT EsVacia(l)) THEN BEGIN
                WHILE (aux2^.sig <> NIL) DO BEGIN
                    aux2 := aux2^.sig;
                END;
                new(aux);
                aux^.info := e;
                aux^.sig := NIL;
                aux2^.sig := aux;
            END ELSE
                Construir(l, e);
        END;

{Observadoras selectoras}
    PROCEDURE Primero(l : TLista; VAR e : TElemento);
        BEGIN
            IF (NOT EsVacia(l)) THEN
                Asignar(e, l^.info);
        END;
    PROCEDURE Resto(l : TLista; VAR r : TLista);
        BEGIN
            IF (NOT EsVacia(l)) THEN
                r := l^.sig;
        END;

{Observadoras no selectoras}
    FUNCTION EsVacia(l : TLista):boolean;
        BEGIN
            EsVacia := (l = NIL);
        END;
    FUNCTION Longitud(l : TLista):integer;
        VAR
            n : integer;
        BEGIN
            n := 0;
            WHILE (l <> NIL) DO BEGIN
                n := n + 1;
                l := l^.sig;
            END;
            Longitud := n;
        END;
    PROCEDURE Ultimo(l : TLista; VAR e : TElemento);
        BEGIN
            IF (NOT EsVacia(l)) THEN BEGIN
                WHILE (l^.sig <> NIL) DO BEGIN
                    l := l^.sig;
                END;
                Asignar(e, l^.info);
            END;
        END;
    FUNCTION Pertenece(l : TLista; e : TElemento):boolean;
        VAR
            encontrado : boolean;
        BEGIN
            encontrado := FALSE;
            WHILE ((l <> NIL) AND (NOT encontrado)) DO BEGIN
                IF (SonIguales(l^.info, e)) THEN
                    encontrado := TRUE
                ELSE
                    l := l^.sig;
            END;
            Pertenece := encontrado;
        END;
END.