Shader 2D sprite + color mask + aura mask

Shader "Custom/Sprite Colored mask + Aura"
{
    Properties
    {
    [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
    [PerRendererData] _MainTexCut ("CutOff", 2D) = "white" {}
    _Color ("Tint", Color) = (1,1,1,1)
    [MaterialToggle] PixelSnap ("Pixel snap", Float) = 0

    _ColorMaskTex ("Color mask texture", 2D) = "white" {}
    _MainColor ("Main color (red)", Color) = (1,0,0,0)
    _AddColor ("Additional 1st color (green)", Color) = (0,1,0,0)
    _ExtColor ("Additional 2nd color (blue)", Color) = (0,0,1,0)

    _AuraMaskTex ("Aura mask texture", 2D) = "white" {}
    _Aura1Color ("Aura 1 color (red)", Color) = (1,0,0,0)
    _Aura1Cutoff ("Cutoff Aura 1", Range(0.0, 1.0)) = 1
    _Aura2Color ("Aura 2 color (green)", Color) = (0,1,0,0)
    _Aura2Cutoff ("Cutoff Aura 2", Range(0.0, 1.0)) = 1
    _Aura3Color ("Aura 3 color (blue)", Color) = (0,0,1,0)
    _Aura3Cutoff ("Cutoff Aura 3", Range(0.0, 1.0)) = 1
    }

    SubShader
    {
        Tags
        {
            "Queue"="Transparent+1"
            "IgnoreProjector"="True"
            "RenderType"="Transparent"
            "PreviewType"="Plane"
            "CanUseSpriteAtlas"="True"
        }

        Cull Off
        Lighting Off
        ZWrite Off
        Fog { Mode Off }
        Blend SrcAlpha OneMinusSrcAlpha

        Pass
        {

        CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile DUMMY PIXELSNAP_ON
            #include "UnityCG.cginc"

            struct appdata_t
            {
                float4 vertex   : POSITION;
                float4 color    : COLOR;
                float2 texcoord : TEXCOORD0;
            };

            struct v2f
            {
                float4 vertex   : SV_POSITION;
                fixed4 color    : COLOR;
                half2 texcoord  : TEXCOORD0;
            };

            fixed4 _Color;

            v2f vert(appdata_t IN)
            {
                v2f OUT;
                OUT.vertex = UnityObjectToClipPos(IN.vertex);
                OUT.texcoord = IN.texcoord;
                OUT.color = IN.color * _Color;
                #ifdef PIXELSNAP_ON
                OUT.vertex = UnityPixelSnap (OUT.vertex);
                #endif

                return OUT;
            }

            sampler2D _MainTex;

            sampler2D _ColorMaskTex;
            float4 _MainColor;
            float4 _AddColor;
            float4 _ExtColor;

            sampler2D _AuraMaskTex;
            float4 _Aura1Color;
            float _Aura1Cutoff;
            float4 _Aura2Color;
            float _Aura2Cutoff;
            float4 _Aura3Color;
            float _Aura3Cutoff;

            fixed4 frag(v2f IN) : COLOR
            {
                float4 MainTex = tex2D(_MainTex, IN.texcoord) * IN.color;
                float4 SkinTex = tex2D(_ColorMaskTex, IN.texcoord);
                float4 AuraTex = tex2D(_AuraMaskTex, IN.texcoord);

                float4 a1 = _Aura1Color * AuraTex.r * _Aura1Color.a;
                a1.a = clamp(AuraTex.r * _Aura1Color.a * AuraTex.a + _Aura1Cutoff - 1, 0, 1);

                float4 a2 = _Aura2Color * AuraTex.g * _Aura2Color.a;
                a2.a = clamp(AuraTex.g * _Aura2Color.a * AuraTex.a + _Aura2Cutoff - 1, 0, 1);

                float4 a3 = _Aura3Color * AuraTex.b * _Aura3Color.a;
                a3.a = clamp(AuraTex.b * _Aura3Color.a * AuraTex.a + _Aura3Cutoff - 1, 0, 1);

                float4 aura = a1 + a2 + a3;
                aura.a = a1.a + a2.a + a3.a;

                float4 res = float4(MainTex.rgb * (1 - SkinTex.r - SkinTex.g - SkinTex.b) +
                    lerp (MainTex.rgb, _MainColor.rgb, _MainColor.a * SkinTex.a) * SkinTex.r +
                    lerp (MainTex.rgb, _AddColor.rgb, _AddColor.a * SkinTex.a) * SkinTex.g +
                    lerp (MainTex.rgb, _ExtColor.rgb, _ExtColor.a * SkinTex.a) * SkinTex.b,
                    MainTex.a);

                    res.rgb = res.rgb * MainTex.a + aura.rgb * (1 - MainTex.a);
                    res.a = clamp(MainTex.a + aura.a, 0, 1);

                return res;
            }
        ENDCG
        }
    }
}