naver-whale-stable

# Maintainer:
# Contributor: Dimitris Kiziridis <ragouel at outlook dot com>
pkgname=naver-whale-stable
pkgver=2.9.115.7
pkgrel=1
pkgdesc="The web browser from NAVER"
arch=('x86_64')
url="https://whale.naver.com"
license=('custom')
depends=('alsa-lib' 'gtk3' 'libxss' 'libxtst' 'nss' 'ttf-liberation')
conflicts=('whale-browser')
replaces=('whale-browser')
source=("$pkgname-$pkgver.deb::https://installer-whale.pstatic.net/downloads/installers/${pkgname}_amd64.deb"
        'LICENSE')
sha256sums=('fe71da4ef17238ce1be58799b0d79f7fc2d565fd36335d0dbf5d06b267e7c410'
            '0ce852c7aa1d3d4401ba262108dad8fd04d84f9f1a9d2b4db0969242ccedc4e4')

package() {
    bsdtar xvf data.tar.xz -C "$pkgdir/"
    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"

    for _size in 16 24 32 48 64 128 256; do
        install -Dm644 "$pkgdir/opt/naver/whale/product_logo_${_size}.png" \
            "$pkgdir/usr/share/icons/hicolor/${_size}x${_size}/apps/naver-whale.png"
    done

    # Remove cron job for PPA updates
    rm -rf "$pkgdir/opt/naver/whale/cron"
    rm -rf "$pkgdir/etc"

    # Remove default app XML
    rm -rf "$pkgdir/usr/share/gnome-control-center"
}