pkgname=gostcrypt
pkgver=1.3
pkgrel=1
pkgdesc="Free open-source cross-platform disk encryption software (fork truecrypt)"
url="https://www.gostcrypt.org"
arch=('x86_64' 'i686')
license=('GPLv3')
depends=('fuse' 'wxgtk2.8' 'p11-kit')
optdepends=()
makedepends=('nasm')
conflicts=()
replaces=()
backup=()
#install=''
source=("https://www.gostcrypt.org/download/${pkgver}/Linux/Sources/GostCrypt_${pkgver}_Linux.zip"
"${pkgname}.desktop")

sha256sums=('3fcd0c6df47540458302446f8cb5f92614b7012c6b68e82d028620fd27a9715f'
            '1f686d38b8478c25a84d786dea178deb5fcc16afe1f0dca13e5994fc21d6382d')

build() {
  cd "${srcdir}/GostCrypt_Linux_${pkgver}"

  # Build
  export WX_CONFIG=/usr/bin/wx-config-2.8
  make PKCS11_INC="/usr/include/pkcs11/" LFLAGS+="-ldl"

}
package() {
  cd "${srcdir}/GostCrypt_Linux_${pkgver}"

  # Install Binary
  install -D -m755 Main/${pkgname} "${pkgdir}/usr/bin/${pkgname}"

  # Install Desktop file and Icon
  install -D -m644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  install -D -m644 Resources/Icons/GostCrypt-48x48.xpm "${pkgdir}/usr/share/pixmaps/${pkgname}.xpm"

  # Install License
  install -D -m644 License.txt "${pkgdir}/usr/share/licenses/${pkgname}/License.txt"

}