#NoEnv
#Warn
#MaxHotkeysPerInterval 500000
SendMode Input
SetWorkingDir %A_ScriptDir%
SetStoreCapslockMode, off

#If !isMouseShown() and WinActive("Darkfall Online")

;Set the number of rays you have here
num_rays = 6
cur_ray = 1

;Binds are set here
k_1 = y ;Impale
k_2 = u ;unholy
k_3 = j ;frost
k_4 = k ;dragon
k_5 = n ;Insect Swarm
k_6 = \ ;Lightning Bolt

;Cooldowns are set here
cd_1 = 6500 ;Impale
cd_2 = 14000 ;unholy
cd_3 = 9500 ;frost
cd_4 = 14000 ;dragon
cd_5 = 13000 ;Insect Swarm
cd_6 = 9000 ;Lightning Bolt

;Ray priority is set here
p_1 = 1 ;Impale
p_2 = 2 ;Frost Bite
p_3 = 3 ;Dragon's Breath
p_4 = 4 ;Unholy Caress
p_5 = 5 ;Insect Swarm
p_6 = 6 ;Lightning Bolt

RayOnGCD := 0
RayQueued := 0

While A_Index <= num_rays
{
	a_%A_Index% = 1
}

return

~*q::
	shootray:
	if(RayOnGCD == 0)
	{
		cur_ray := RayCheck(cur_ray)
		KeySend(cur_ray)
		TimerCreate(cur_ray)
		Sleep, 40
		MouseClick, Left
		RayOnGCD := 1
		SetTimer, RayOffGCD, -1250
	}
	else
	{
		RayQueued := 1
	}
Return

TimerStart:
	Hotkey , ~LButton , TimerStart , Off
	TimerCreate(cur_ray)
Return

RayOffGCD:
	RayOnGCD := 0
	if(RayQueued == 1)
	{
		RayQueued := 0
		goto, shootray
	}
return

1:
2:
3:
4:
5:
6:
a_%A_ThisLabel% = 1
Return

RayCheck(cur_ray)
{
	global

	cur_ray := p_1

	While A_Index <= num_rays
	{
		ray_number := p_%A_Index%
		if (a_%ray_number% = 1)
		{
			cur_ray := ray_number
			Break
		}
	}
	Return cur_ray
}

KeySend(cur_ray)
{
	global

	SendInput , % k_%cur_ray%
	Return
}

TimerCreate(cur_ray)
{
	global

	a_%cur_ray% = 0
	SetTimer , %cur_ray% , % -cd_%cur_ray%
	Return
}

~w::
	Send, {F12 down}
Return

~w Up::
	Send, {F12 up}
Return

~e::
	Send, {PgUp}
	Send, {NumpadDiv}
	Send, {NumpadMult}
	Send, {Down}
	Send, {Right}
	Send, {End}
return

~x::
	Send, {F9}
	Send, {F10}
return

~Tab::
	Sleep, 600
	Send, o
return

isMouseShown()
{
	StructSize := A_PtrSize + 16
	VarSetCapacity(InfoStruct, StructSize)
	NumPut(StructSize, InfoStruct)
	DllCall("GetCursorInfo", UInt, &InfoStruct)
	Result := NumGet(InfoStruct, 8)

	if Result
		return 1
	else
		return 0
}