ae.mac

Sub Main

	/declare CLR0 string local Word of Pain
	/declare CLR1 string local Word of Shadow
	/declare CLR2 string local Word of Spirit
	/declare CLR3 string local Tremor
	/declare CLR4 string local Word of Souls
	/declare CLR5 string local Earthquake
	/declare CLR6 string local Word Divine
	/declare CLR7 string local Upheaval
	/declare CLR8 string local The Unspoken Word
	/declare CLR9 string local Catastrophe

	/declare NEC0 string local Word of Spirit
	/declare NEC1 string local Word of Souls

	/declare DRU1 string local Catastrophe
	/declare DRU2 string local Earthquake
	/declare DRU3 string local Upheaval
	/declare DRU4 string local Tremor
|	/declare DRU5 string local
|	/declare DRU6 string local
|	/declare DRU7 string local
|	/declare DRU8 string local
|	/declare DRU9 string local

	/declare WIZ0 string local Numbing Cold
	/declare WIZ1 string local Fingers of Fire
	/declare WIZ2 string local Project Lightning
	/declare WIZ3 string local Cast Force
	/declare WIZ4 string local Supernova
	/declare WIZ5 string local Jyll's Zephyr of Ice
	/declare WIZ6 string local Jyll's Wave of Heat
	/declare WIZ7 string local Winds of Gelid

	/declare MyClass string local ${Me.Class.ShortName}
	/declare AllowedClasses string local |CLR|DRU|WIZ|NEC|
	/declare MinNPC int local 3

	/declare a int local -1
	/declare b int local -1
	/declare MaxGems int local 8

	/if (${Me.AltAbility[Mnemonic Retention]}) /varset MaxGems 9

	/if (!${AllowedClasses.Find[${Me.Class.ShortName}]}) {
		/echo Error, you must be one of the following classes to run this macro: ${AllowedClasses}
		/bc Error, I'm not a ${AllowedClasses}
		/endmacro
	}

    :MemSpells
	/varset a 0
	/varset b 0
	/sit
	/for a 15 downto 0
		| check if the spell is defined ${MyClass}${a}
		/if (${Defined[${MyClass}${a}]}) {
			| check if i have the defined spell in my book. ${${MyClass}${a}}
			/if (${Me.Book[${${MyClass}${a}}]}) {
				/varcalc b ${b}+1
				| check if i alreadyhave it memorized where it should be
				/if (!${Me.Gem[${b}].Name.Find["${${MyClass}${a}}"]}) {
					| memorize the spell.
					/memorize "${${MyClass}${a}}|${b}"
					/delay 10s ${Cast.Status.Find[M]}
					/delay 10s !${Cast.Status.Find[M]}
				}
			}
		}
		/if (${b} >= ${MaxGems}) /goto :CastLoop
	/next a
	/stand
	:CastLoop
	/varset a 0
	/for a 1 to ${b}
		/if (${Cast.Ready[${a}]} && ${Me.CurrentMana} >= ${Spell["${Me.Gem[${a}]}"].Mana} && ${SpawnCount[radius 30 npc]} >= ${MinNPC}) {
			/casting "${Me.Gem[${a}]}"
			/delay 10s ${Cast.Status.Find[C]}
			/delay 10s !${Cast.Status.Find[C]}
			| delay for recast time
			/delay 1
			/varset a 0
		} else {
			/delay 10
		}
	/next a
	/goto :CastLoop

/return