glinemanager.mrc

/* Gline Manager
By Master
Version 1.0

This script allows you to manage the gline list, including editing, removing,
or even automatically pruning "old" glines which can be expired before their
actual expire date (from BOPM for example, or permanent glines).
This script does NOT have a gline add feature; that can be done with /gline ;)
*/
;Tradotto by Dragone2
;dialog
dialog gline.m {
  title "Gline Manager"
  size -1 -1 161 194
  option dbu
  box "Gline List", 1, 0 0 158 96
  list 2, 3 7 151 85, size
  box "Comandi", 3, 0 98 158 25
  box "Informazioni e Stats", 4, 0 126 158 54
  button "Modifica", 5, 3 106 37 12
  button "Rimuovi", 6, 43 106 37 12
  button "Auto-Rimuovi", 7, 83 106 37 12
  button "Pulisci", 8, 123 106 32 12
  text "Set by", 9, 2 135 18 8
  text "Durata", 13, 2 145 23 8
  text "", 14, 27 145 97 8
  text "Tempo Trascorso", 15, 2 157 25 8
  text "", 16, 27 157 128 8
  text "Motivo", 17, 2 168 21 8
  edit "", 18, 25 167 131 10, read autohs
  button "Chiudi", 19, 120 181 37 12, ok cancel
  text "Gline Manager v1.0 - Master", 20, 2 183 112 8, disable center
  text "Contatore", 21, 131 135 25 8, center
  text "", 22, 131 145 25 8, center
  edit "", 10, 23 134 102 10, read autohs
}
On *:DIALOG:gline.m:*:*:{
  if ($devent == init) {
    set %gline.init 1
    !raw -q stats g
    did -b $dname 5,6,8
  }
  elseif ($devent == sclick) {
    if ($did == 2) && ($did(2).seltext) {
      did -e $dname 6-8
      did -r $dname 10,14,16,18
      did -a $dname 10 $gstat($did(2).seltext,6)
      did -a $dname 14 $duration($calc($gstat($did(2).seltext,4) + $gstat($did(2).seltext,5)),2)
      did -a $dname 16 $iif($gstat($did(2).seltext,4) > 0,$duration($gstat($did(2).seltext,4),2),Permanent)
      did -a $dname 18 $gstat($did(2).seltext,7)
      live.upd
    }
    elseif ($did == 5) halt
    elseif ($did == 6) {
      !gline $+(-,$did(2).seltext)
      hdel gline.tmp $did(2).seltext
      did -d $dname 2 $did(2).line
      hdec gline.tmp count
    }
    elseif ($did == 7) dialog -m gline.p gline.p
    elseif ($did == 8) {
      set %gline.clear 1
      !raw -q stats g
      did -r $dname 2
      did -r 10,14,16,18
      gline.cleanup
    }
  }
  elseif ($devent == close) gline.cleanup
}
;auto-prune dialog
dialog gline.p {
  title "Gline Auto-Remover"
  size -1 -1 204 117
  option dbu
  box "Parametri", 1, 0 0 123 48
  text "Setted by", 2, 2 9 25 8
  edit "", 3, 30 8 90 10, autohs
  check "Non Scadere", 4, 2 34 46 10
  text "Host", 5, 2 22 25 8
  edit "", 6, 30 21 90 10, autohs
  text "Wildcards accettate. Clicka Controlla per vedere quanti bans corrispondenti verranno rimossi, quindi Rimuovi per rimuoverli TUTTI.", 7, 125 3 78 45
  box "Anteprima", 8, 0 50 123 53
  list 9, 2 57 118 44, size vsbar
  button "Controlla", 10, 126 54 37 12
  button "Rimuovi", 11, 165 54 37 12
  button "Chiudi", 12, 145 90 37 12, ok cancel
  text "Gline Auto-Remover Module v1.0 (Gline Manager) - By Master", 13, 2 106 201 8, disable center
  check "Escludi Non-Scadenti", 14, 50 34 70 10
  text "Contenenti", 15, 125 74 25 8
  text "", 16, 162 74 25 8, center
}

On *:DIALOG:gline.p:*:*:{
  if ($devent == init) did -b $dname 11
  elseif ($devent == sclick) {
    if ($did == 4) && ($did(14).state == 1) did -u $dname 14
    elseif ($did == 14) && ($did(4).state == 1) did -u $dname 4
    elseif ($did == 10) {
      did -e $dname 11
      did -r $dname 9
      set %gline.prune $iif($did(4).state == 1,noexpire,1) $did(14).state
      if ($did(6)) var %flag = m
      if ($did(3)) var %flag = %flag $+ s
      !raw -q stats g + $+ %flag $did(6) $did(3)
    }
    elseif ($did == 11) {
      var %a = 1
      while (%a <= $did(9).lines) {
        gline - $+ $did(9,%a)
        inc %a
      }
      if ($input(Gline rimossa. Per vedere cambiamenti riapri questa finestra!,ov)) {
        did -k gline.p
      }
    }
  }
  elseif ($devent == close) unset %gline.p*
}

;aliases
;$me G host countdown countup setter reason
alias -l gstat {
  if (!$isid) halt
  return $gettok($hget(gline.tmp,$1),$iif($2 > 6,7-,$2),32)
}
alias -l live.upd {
  .timergline.upd 1 1 live.upd
  if ($did(gline.m,16) > 0) did -o gline.m 16 1 $duration($calc($gstat($did(gline.m,2).seltext,4) - %gline.clock),2)
  did -o gline.m 22 1 $hget(gline.tmp,count)
}
alias -l gline.cleanup {
  hfree gline.tmp
  hfree gline.num
  .timergline.* off
  unset %gline.*
}


;events
raw 223:*:{
  if (%gline.init) {
    if (!%gline.c) set %gline.c 1
    if (!$timer(gline.clock)) .timergline.clock 0 1 inc %gline.clock
    ;  window @DEBUG
    ;  aline -p @DEBUG 1: $1 2: $2 3: $3 4: $4 5: $5 6: $6 7-: $7-
    hadd -m gline.tmp $3 $1-
    hadd -m gline.num %gline.c $3-
    did -a gline.m 2 $3
    inc %gline.c
    if (!$hget(gline.tmp,count)) hadd -m gline.tmp count 1
    else hinc gline.tmp count
    halt
  }
  elseif ($gettok(%gline.prune,1,32) == noexpire) && ($4 == 0) did -a gline.p 9 $3
  elseif ($gettok(%gline.prune,1,32) == 1) && ($gettok(%gline.prune,2,32) != 1) did -a gline.p 9 $3
  elseif ($gettok(%gline.prune,2,32) == 1) && ($4 != 0) did -a gline.p 9 $3
  if (%gline.prune) halt

  elseif (%gline.clear) {  gline - $+ $3 | halt }
}
raw 219:*:{
  if (%gline.init || %gline.clear || %gline.prune) {
    did -o gline.m 22 1 $hget(gline.tmp,count)
    did -o gline.p 16 1 $did(gline.p,9).lines
    unset %gline.clear
    unset %gline.prune
    unset %gline.init
    unset %gline.c
    halt
  }
}

;menu
menu status,channel {
  Gline Manager:dialog -m gline.m gline.m
}