ShipmentBox.zs

import minetweaker.item.IItemStack;
val prices = {
	<minecraft:reeds> : 2,
    <minecraft:apple> : 10,
    <minecraft:fish> : 20,
	<minecraft:fish:1> : 20,
	<minecraft:fish:2> : 20,
	<minecraft:fish:3> : 20,
	<minecraft:cookie> : 30,
	<minecraft:bread> : 85,
	<minecraft:pumpkin_pie> : 150,
	<minecraft:diamond> : 25,
	<minecraft:emerald> : 75,
	<minecraft:golden_apple> : 50,
	<minecraft:golden_apple:1> : 450,
	<minecraft:golden_carrot> : 135,
	<biomesoplenty:berries> : 10,
	<biomesoplenty:pear> : 10,
	<biomesoplenty:peach> : 10,
	<biomesoplenty:persimmon> : 10,
	<biomesoplenty:turnip> : 10,
	<minecraft:nether_star> : 500,
	<hardcorewither:craftingItem> : 1000,
	<hardcorewither:starryApple>: 4100,

} as int[IItemStack];
val pre_format = "Can be sold for ";
val post_format = "g in the shipment box";

for entry in prices.entrySet {
	var item = entry.key as IItemStack;
	mods.harvestfestival.Shipping.addShipping(item, entry.value);

	item.addTooltip(
			format.green(
				pre_format +
				entry.value +
				post_format
			)
		);
}





mods.harvestfestival.Shipping.addShipping(<coins:coin>, 10);
mods.harvestfestival.Shipping.addShipping(<coins:coin:1>, 100);
mods.harvestfestival.Shipping.addShipping(<coins:coin:2>, 1000);
mods.harvestfestival.Shipping.addShipping(<coins:coin:3>, 10000);