import minetweaker.item.IItemStack;
import minetweaker.item.IIngredient;
import mods.betterbeginnings.AdvancedCrafting;
import mods.betterbeginnings.Oven;

var craftResources = [
<actuallyadditions:itemCrystal:0>, <actuallyadditions:itemCrystal:1>, <actuallyadditions:itemCrystal:2>,
<actuallyadditions:itemCrystal:3>, <actuallyadditions:itemCrystal:4>, <actuallyadditions:itemCrystal:5>,
<minecraft:emerald>, <minecraft:obsidian>, <actuallyadditions:itemMisc:5>, <minecraft:iron_ingot>,
<minecraft:gold_ingot>, <betterwithmods:material:49>, <botania:manaResource:0>,
<betterwithmods:material:50>
]as IItemStack[];

var helmetSet = [
<actuallyadditions:itemHelmCrystalRed>, <actuallyadditions:itemHelmCrystalBlue>, <actuallyadditions:itemHelmCrystalLightBlue>,
<actuallyadditions:itemHelmCrystalBlack>, <actuallyadditions:itemHelmCrystalGreen>, <actuallyadditions:itemHelmCrystalWhite>,
<actuallyadditions:itemHelmEmerald>, <actuallyadditions:itemHelmObsidian>, <actuallyadditions:itemHelmQuartz>, <minecraft:iron_helmet>,
<minecraft:golden_helmet>, <minecraft:diamond_helmet>, <botania:manasteelHelm>,
<minecraft:chainmail_helmet>
]as IItemStack[];

var chestSet = [
<actuallyadditions:itemChestCrystalRed>, <actuallyadditions:itemChestCrystalBlue>, <actuallyadditions:itemChestCrystalLightBlue>,
<actuallyadditions:itemChestCrystalBlack>, <actuallyadditions:itemChestCrystalGreen>, <actuallyadditions:itemChestCrystalWhite>,
<actuallyadditions:itemChestEmerald>, <actuallyadditions:itemChestObsidian>, <actuallyadditions:itemChestQuartz>, <minecraft:iron_chestplate>,
<minecraft:golden_chestplate>, <minecraft:diamond_chestplate>, <botania:manasteelChest>,
<minecraft:chainmail_chestplate>
]as IItemStack[];

var legsSet = [
<actuallyadditions:itemPantsCrystalRed>, <actuallyadditions:itemPantsCrystalBlue>, <actuallyadditions:itemPantsCrystalLightBlue>,
<actuallyadditions:itemPantsCrystalBlack>, <actuallyadditions:itemPantsCrystalGreen>, <actuallyadditions:itemPantsCrystalWhite>,
<actuallyadditions:itemPantsEmerald>, <actuallyadditions:itemPantsObsidian>, <actuallyadditions:itemPantsQuartz>, <minecraft:iron_leggings>,
<minecraft:golden_leggings>, <minecraft:diamond_leggings>, <botania:manasteelLegs>,
<minecraft:chainmail_helmet>
]as IItemStack[];

var bootsSet = [
<actuallyadditions:itemBootsCrystalRed>, <actuallyadditions:itemBootsCrystalBlue>, <actuallyadditions:itemBootsCrystalLightBlue>,
<actuallyadditions:itemBootsCrystalBlack>, <actuallyadditions:itemBootsCrystalGreen>, <actuallyadditions:itemBootsCrystalWhite>,
<actuallyadditions:itemBootsEmerald>, <actuallyadditions:itemBootsObsidian>, <actuallyadditions:itemBootsQuartz>, <minecraft:iron_boots>,
<minecraft:golden_boots>, <minecraft:diamond_boots>, <botania:manasteelBoots>,
<minecraft:chainmail_helmet>
]as IItemStack[];

for i, helm in helmetSet {

    var componet = craftResources[i];

    AdvancedCrafting.addRecipe(helm, [
        [componet, componet, componet],
        [componet, null, componet],
        [null, null, null]
        ]
        , [<betterwithmods:material:45> * 3, <betterwithmods:material:8> * 2]);
}

for i, chest in chestSet {

    var componet = craftResources[i];

    AdvancedCrafting.addRecipe(chest, [
        [componet, null, componet],
        [componet, componet, componet],
        [componet, componet, componet]
        ]
        , [<betterwithmods:material:45> * 8, <betterwithmods:material:8> * 5]);
}

for i, legs in legsSet {

    var componet = craftResources[i];

    AdvancedCrafting.addRecipe(legs, [
        [componet, componet, componet],
        [componet, null, componet],
        [componet, null, componet]
        ]
        , [<betterwithmods:material:45> * 12, <betterwithmods:material:8> * 8]);
}

for i, boots in bootsSet {

    var componet = craftResources[i];

    AdvancedCrafting.addRecipe(boots, [
        [componet, null, componet],
        [componet, null, componet],
        [null, null, null]
        ]
        , [<betterwithmods:material:45> * 4, <betterwithmods:material:8> * 2]);
}


var allWater = [ <minecraft:water_bucket>,
<minecraft:potion>.withTag({Potion: "minecraft:water"}).transformReplace(<minecraft:glass_bottle>),
<ceramics:clay_bucket>.withTag({fluids: {FluidName: "water", Amount: 1000}}).transformReplace(<ceramics:clay_bucket>),
<botania:waterBowl>.withTag({Fluid: {FluidName: "water", Amount: 1000}}).transformReplace(<minecraft:bowl>),
<aether_legacy:skyroot_bucket:1>.transformReplace(<aether_legacy:skyroot_bucket>),
<minecraft:splash_potion>.withTag({Potion: "minecraft:water"}).transformReplace(<minecraft:glass_bottle>),
<extraalchemy:breakable_potion>.withTag({Potion: "minecraft:water"}).transformReplace(<extraalchemy:vial_break>),
<botania:rune:0>.reuse()
]as IIngredient[];

for i, water in allWater {
    recipes.addShapeless(<actuallyadditions:itemMisc:4>, [water, <betterwithmods:material:37>]);
    mods.betterwithmods.Cauldron.add(<actuallyadditions:itemFood:6>, [water, <minecraft:bowl>, <actuallyadditions:itemFood:7>, <actuallyadditions:itemFood:7>, <actuallyadditions:itemFood:7>]);
    mods.betterwithmods.Cauldron.add(<actuallyadditions:itemFood:6>, [water, <minecraft:bowl>, <ore:listAllchickenraw>, <minecraft:potato>, <minecraft:carrot>]);
    mods.betterwithmods.Cauldron.add(<actuallyadditions:itemFood:6>, [water, <minecraft:bowl>, <minecraft:pumpkin>]);
    mods.betterwithmods.Cauldron.add(<actuallyadditions:itemFood:6>, [water, <minecraft:bowl>, <ore:fish>, <ore:listBucketmilk>]);
    mods.betterwithmods.Cauldron.add(<actuallyadditions:itemFood:6>, [water, <minecraft:bowl>, <ore:mushroom>, <ore:mushroom>]);
    mods.betterwithmods.Cauldron.add(<actuallyadditions:itemFood:6>, [water, <minecraft:bowl>, <minecraft:potato>, <minecraft:carrot>, <minecraft:rabbit>]);
    mods.betterwithmods.Cauldron.add(<actuallyadditions:itemFood:6>, [water, <minecraft:bowl>, <minecraft:beetroot>, <minecraft:beetroot>]);
    mods.betterwithmods.Cauldron.add(<actuallyadditions:itemFood:6>, [water, <minecraft:bowl>, <animania:truffle>, <animania:truffle>]);
    mods.betterwithmods.Cauldron.add(<actuallyadditions:itemFood:6>, [water, <minecraft:bowl>, <minecraft:potato>, <minecraft:carrot>, <ore:mushroom>, <duckcraft:ItemRawDuck>]);
    mods.betterwithmods.Cauldron.add(<actuallyadditions:itemFood:6>, [water, <minecraft:bowl>, <minecraft:potato>, <minecraft:carrot>, <ore:mushroom>, <ore:foodMeat>]);

}