CursorHook_start:
    .db     83h
    cp      a, 24h
    jr      nz, +_
    inc     a
    ld      a, (curUnder)
    ret
_:  cp      a, 22h
    ret     nz
    ld      a, (cxCurApp)
    cp      a, cxPrgmEdit
    ret     nz
    ld      hl, (editCursor)
    ld      a, (hl)
    cp      a, tSum
    jr      z, DrawDetText
    cp      a, tDet
    ret     nz
DrawDetText:
    bit     0, (iy-41h)
    ret     nz
    ld      iyl, a
    ld      hl, (editTail)
    inc     hl
    ld      a, (hl)
    sub     a, t0
    ret     c
    cp      a, t9-t0+1
    ld      bc, (editBtm)
    ld      de, 0
    ld      e, a
    jr      c, GetDetValueLoop
WrongDetValue:
    or      a, 1
    ret
GetDetValueLoop:
    inc     hl
    or      a, a
    sbc     hl, bc
    jr      z, GetDetValueStop
    add     hl, bc
    ld      a, (hl)
    sub     a, t0
    jr      c, GetDetValueStop
    cp      a, t9-t0+1
    jr      nc, GetDetValueStop
    push    hl
            ex      de, hl
            add     hl, hl
            push    hl
            pop     de
            add     hl, hl
            add     hl, hl
            add     hl, de
            ld      de, 0
            ld      e, a
            add     hl, de
            ex      de, hl
    pop     hl
    jr     GetDetValueLoop
GetDetValueStop:
    ex      de, hl
    ld      a, iyl
    ld      iy, flags
    cp      a, tDet
    jr      z, +_
    ld      de, AMOUNT_OF_FILEIOC_FUNCTIONS
    ld      bc, CData4
    jr      ++_
_:  ld      de, AMOUNT_OF_GRAPHX_FUNCTIONS
    ld      bc, CData5
_:  or      a, a
    sbc     hl, de
    jr      nc, WrongDetValue
    add     hl, de
    ld      h, 3
    mlt     hl
    add     hl, bc
    push    hl
            scf
	    sbc hl, hl
	    ld (hl), 2
            ;call    _os_ClearStatusBarLow
    pop     hl
    ld      de, (rawKeyHookPtr)
    add     hl, de
    ld      hl, (hl)
    add     hl, de
    ld      de, 000E71Ch
    ld.sis  (drawFGColor & 0FFFFh), de
    ld.sis  de, (statusBarBGColor & 0FFFFh)
    ld.sis  (drawBGColor & 0FFFFh), de
    ld      a, 14
    ld      (penRow),a
    ld      de, 2
    ld.sis  (penCol & 0FFFFh), de
    call    _VPutS
    ld      de, 0FFFFh
    ld.sis  (drawBGColor & 0FFFFh), de
    set     0, (iy-41h)
    ret