Bdfd Giveaway command

Variable

gw2 =

gw = 0¤0¤0¤0¤?

Es war eine Qual diesen Code zu schreiben,
ich würde mich sehr freuen wenn wir bis zum Ende von 2023 die 100 Abonnenten erreichen würden.

Trigger : !gwstart

Script : Bdscript 2

$nomention
$suppressErrors
$onlyIf[$getUserVar[gw]==0¤0¤0¤0¤?;〣│<:abbrechen:1025819352848670770>・Sie veranstalten bereits ein Gewinnspiel]
$var[t;$message[1]]
$var[w;$replaceText[$message[2];w;]]
$var[p;$replaceText[$replaceText[$message;$var[t];];$var[w];]]
$if[$var[t]==]
$description[〣│<:abbrechen:1025819352848670770>・Geben Sie eine Giveaway-Dauer an]
$color[#ff0000]
$elseif[$isNumber[$replaceText[$replaceText[$replaceText[$var[t];s;];m;];h;]]==false]
$description[〣│<:abbrechen:1025819352848670770>・Dauer des Gewinnspieles ist ungültig, geben Sie eine Zahl an]
$elseif[$or[$checkContains[$var[t];s;m]==false;$checkContains[$var[t];h]==true]==true]
$description[〣│<:abbrechen:1025819352848670770>・Geben Sie ein gültiges Timer-Zeichen an
verfügbar: s (Sekunden), m (Minuten)]
$elseif[$and[$checkContains[$var[t];s]==true;$replaceText[$var[t];s;]>2400]==true]
$description[〣│<:abbrechen:1025819352848670770>・Aufgrund dessen das diese Funktion noch in der Entwicklung sind ist es nur möglich Gewinnspiele mit einer maximalen Länge 2400 Sekunden (40 Minuten)]
$color[#ff0000]
$elseif[$replaceText[$var[t];s;]==1]
$description[〣│<:abbrechen:1025819352848670770>・Die Giveaway-Dauer muss länger als 1 Sekunde sein]
$color[#ff0000]
$elseif[$and[$checkContains[$var[t];m]==true;$replaceText[$var[t];m;]>40]==true]
$description[〣│<:abbrechen:1025819352848670770>・Aufgrund dessen das diese Funktion noch in der Entwicklung sind ist es nur möglich Gewinnspiele mit einer maximalen Länge 2400 Sekunden (40 Minuten)]
$color[#ff0000]
$elseif[$var[w]==]
$description[〣│<:abbrechen:1025819352848670770>・Geben Sie die Anzahl der Gewinner an]
$elseif[$isNumber[$var[w]]==false]
$description[〣│<:abbrechen:1025819352848670770>・Geben Sie eine gültige Anzahl an Gewinnern an]
$color[#ff0000]
$elseif[$var[w]>15]
$description[〣│<:abbrechen:1025819352848670770>・Maximale 15 Gewinner sind möglich]
$color[#ff0000]
$elseif[$var[p]==]
$description[〣│<:abbrechen:1025819352848670770>・Geben sie bitte einen Preis an]
$color[#ff0000]
$elseif[$charCount[$var[p]]>256]
$description[〣│<:abbrechen:1025819352848670770>・Der maximale Preis beträgt `256` Zeichen]
$color[#ff0000]
$else
$var[id;$sendEmbedMessage[$channelID;;$replaceText[$var[p];|;¤];;**Giveaway-Dauer:** $replaceText[$replaceText[$var[t];s; Sekunden];m; Minuten]
**Anzahl der Gewinner:** $var[w]
**Einträge insgesamt:** 0
**Veranstaltet von:** <@$authorID>;$getServerVar[color];;;Klicke auf 🎉 Am Gewinnspiel teilnehmen, um am Gewinnspiel teilzunehmen;;;;;yes]]
$setUserVar[gw;$var[id]¤$authorID¤$var[t]¤$var[w]¤$var[p]]
$addButton[no;gjoin-$authorID;Teilnehmen;$randomText[primary;success];;🎉;$var[id]]
$addButton[no;gleave-$authorID;Verlassen;danger;;;$var[id]]
$var[t;〣│<:abbrechen:1025819352848670770>・hier waren nicht genügend Teilnehmer, um einen Gewinner für dieses Gewinnspiel zu ermitteln]
$endif
$async[1]
$textSplit[$getUserVar[gw];¤]
$var[uwu;$splitText[1]]
$var[wt1;$splitText[4]]
$replyIn[$splitText[3]]
$textSplit[$getUserVar[gw2]; ]
$var[wt2;$getTextSplitLength]
$if[$var[wt2]<=1]
$sendEmbedMessage[$channelID;;Springe zum Gewinnspiel;https://discord.com/channels/$guildID/$channelID/$var[uwu];**$var[t]**;$getServerVar[color]]
$textSplit[$getUserVar[gw];¤]
$editMessage[$channelID;$splitText[1];;Gewinnspiel vorbei;**Gewinner$replaceText[$replaceText[$checkCondition[$splitText[4]==1];true;];false;s]:** 〣│<:abbrechen:1025819352848670770>・Niemand;$getServerVar[color];]
$removeButtons[$splitText[1]]
$setUserVar[gw;0¤0¤0¤0¤?]
$setUserVar[gw2;]
$else
$if[$var[wt1]>$var[wt2]]
$var[u;$var[wt2]]
$else
$var[u;$var[wt1]]
$endif
$var[a;$cropText[$repeatMessage[3;$repeatMessage[5;a]];$var[u];]]
$textSplit[$getUserVar[gw2]; ]
$var[win;$trimSpace[$eval[$replaceText[$var[a];a;<@%{DOL}%optOff[%{DOL}%splitText[%{DOL}%random[1\;%{DOL}%sum[%{DOL}%var[u\]\;1\]\]\]\]>, ;-1]]]]
$var[win;$cropText[$var[win];$sub[$charCount[$var[win]];1];]]
$textSplit[$getUserVar[gw];¤]
$editMessage[$channelID;$splitText[1];;Gewinnspiel beendet;**Gewinner$replaceText[$replaceText[$checkCondition[$splitText[4]==1];true;];false;s]:**
$var[win];$getServerVar[color];Herzlichen Glückwunsch an den Gewinner$replaceText[$replaceText[$checkCondition[$splitText[4]==1];true;];false;s]!]
$sendEmbedMessage[$channelID;$var[win];Zum Gewinnspiel springen;https://discord.com/channels/$guildID/$channelID/$var[uwu];Glückwünsche **$var[win]**  Gewinnspiel für**$splitText[5]**;$getServerVar[color]]
$editButton[gjoin-$authorID;Teilnehmen;secondary;yes;🎉;$splitText[1]]
$editButton[gleave-$authorID;Verlassen;danger;yes;;$splitText[1]]
$endif
$setUserVar[gw;0¤0¤0¤0¤?]
$setUserVar[gw2;]
$endasync


Code 2

Trigger : $onInteraction

Script : Bdscript 2

$nomention
$if[$checkContains[$customID;gjoin]]
$suppressErrors
$textSplit[$customID;-]
$var[id;$splitText[2]]
$if[$checkContains[$getUserVar[gw2;$var[id]];$authorID]]
$ephemeral
$title[Du nimmst bereits am Gewinnspiel Teil, habe etwas Geduld bis es endet.]
$removeButtons
$color[$getServerVar[color]]
$else
$ephemeral
$removeButtons
$title[Du nimmst nun am Gewinnspiel teil, viel Glück]
$color[$getServerVar[color]]
$setUserVar[gw2;$trimSpace[$getUserVar[gw2;$var[id]] $authorID];$var[id]]
$textSplit[$getUserVar[gw2;$var[id]]; ]
$var[t;$getTextSplitLength]
$textSplit[$getUserVar[gw;$var[id]];¤]
$editMessage[$channelID;$splitText[1];;$replaceText[$splitText[5];|;¤];**Giveaway-Dauer:** $replaceText[$replaceText[$splitText[3];s; Sekunden];m; Minuten]
**Zahl der Gewinner:** $splitText[4]
**Teilnehmer insgesamt:** $numberSeparator[$var[t]]
**Veranstaltet von:** <@$var[id]>;$getServerVar[color];Klicke auf 🎉, um am Gewinnspiel teilzunehmen]
$endif
$endif
$if[$checkContains[$customID;gleave]]
$suppressErrors
$textSplit[$customID;-]
$var[id;$splitText[2]]
$if[$checkContains[$getUserVar[gw2;$var[id]];$authorID]==false]
$ephemeral
$title[Du nimmst nicht teil]
$removeButtons
$color[#ff0000]
$else
$ephemeral
$removeButtons
$textSplit[$getUserVar[gw2;$var[id]]; ]
$removeSplitTextElement[$getTextSplitIndex[$authorID]]
$title[Sie haben das Gewinnspiel verlassen]
$color[#38E873]
$setUserVar[gw2;$joinSplitText[ ];$var[id]]
$textSplit[$getUserVar[gw2;$var[id]]; ]
$var[t;$sub[$getTextSplitLength;1]]
$textSplit[$getUserVar[gw;$var[id]];¤]
$editMessage[$channelID;$splitText[1];;$splitText[5];**Gewinnspiel Dauer:** $replaceText[$replaceText[$splitText[3];s; Sekunden];m; Minuten]
**Anzahl der Gewinner:** $splitText[4]
**Anzahl der Teilnehmer:** $numberSeparator[$var[t]]
**Veranstaltet von:** <@$var[id]>;$random[1;16777216];Klicke auf 🎉, um am Gewinnspiel teilzunehmen]
$endif
$endif