;=========================================================
;=========================================================

; set the ID of your weapon here
set %weapon ZFESIVE
; set #TRUE or #FALSE for using poison
set %usepoison #TRUE
; set the time between poisoning weapons.
; 10 for every second, so 600 is 1 minute
set %poisontime 190

;=========================================================
;=========================================================

set %poison AVF
set %instrument MQF
set %food EDF_QQD_FWI_UWI_TWI_KPE_MQE_UQE_CWE_KPE_ZPE_AXI_YWI_WLI_ACG_QRD_NRD_FUD_WBG_JQE
set %Bandages ZLF
set %huntertime #time + 300
set #SYSMSGCOL 88
Event sysmessage Please target your sparring partner.
set #targcurs 1
repeat
until #targcurs = 0
set *Partner #ltargetid

;=========================================================
;=========================================================

loop:

if #time > %huntertime
{
   set %huntertime #time + 300
   gosub Hunger
}

if #scnt2 > %poisontime && #scnt > 10 && %usepoison
{
   GoSub Poison
   set #scnt 0
   set #scnt2 0
}

if #scnt > 10

if #ENEMYHITS < 4000
GoSub Healing


goto loop:
;=========================================================
;=========================================================
Sub Healing
   HealLoop:
      repeat
      {
        Finditem %Bandages C_ , #BACKPACKID
        if #findkind = -1
        {
           FINDITEM %Bandages G_2
           if #findkind = -1
           {
               msg STOP! I have run out of bandages!$
               msg STOP! I have run out of bandages!$
               Halt
           }
        }
        Set #LOBJECTID #FINDID
        Event Macro 17 0
        wait 20
      }
      until #targcurs = 1
      set %jstart #jIndex
      set #LTARGETID *Partner
      Event Macro 22 0
      repeat
      {
         set %jend #jIndex
         for %ji %jstart #jIndex
         {
            scanjournal %ji
            if You_could_not in #journal
               GoTo HealLoop
            if You_have_healed in #journal
               Return
            if Your_patient_is_at_full_health. in #journal
            {
              wait 40
              return
            }
            if You_successfully in #journal
               return
         }
      }
      until #ENEMYHITS = 4000
Return
;=========================================================
;=========================================================
sub hunger
  set #scnt2 0
  set %eat N/A
  set %jstart #jIndex
  msg .hunger$
  wait 20
  set %jend #jIndex
  for %ji %jstart %jend
  {
    scanjournal %ji
    if watch_your_weight in #journal
      return
    if three_square_meals in #journal
      return
    if Your_diet_is_consistent in #journal
      set %eat 1
    if Even_thought_you_are_not_starving,_some_food_would_be_welcome. in #journal
      set %eat 3
    if stomach_is_growling in #journal
      set %eat 6
    if Are_you_Anorexic in #journal
      set %eat 8
  }
  if %eat = N/A
    return
  for %i 1 %eat
  {
      finditem %food c_
      set #LOBJECTID #FINDID
      event macro 17
      wait 30
  }
return
;=========================================================
;=========================================================
sub Poison
Event Sysmessage Poisoning weapon
event macro 13 30
finditem %poison C_ , #BACKPACKID
if #findkind = -1
{
  finditem %poison G_0
  if #findkind = -1
  {
   event sysmessage You dont have any poisons left.
   set %usepoison #false
   return
  }
  Exevent Drag #FINDID 50
  Wait 5
  Exevent dropC #BACKPACKID
  Wait 10
  finditem WUF C_ , #BACKPACKID
  wait 5
  Exevent Drag #FINDID #FINDSTACK
  Wait 10
  Exevent dropg #CHARPOSX #CHARPOSY #CHARPOSZ
  Wait 10
  finditem %poison C_ , #BACKPACKID
}
set #LTARGETID #FINDID
target
event macro 22
set #LTARGETID %weapon
target
event macro 22
return