pkgname=naev-git
pkgver=20110129
pkgrel=1
pkgdesc="2D space trading and combat game similar to Escape Velocity, development branch."
arch=('i686' 'x86_64')
url="http://naev.org"
license=('GPL')
depends=('sdl_image' 'sdl_mixer' 'libxml2' 'freetype2' 'libpng' 'openal' 'libvorbis' 'binutils' 'libgl')
makedepends=('git')
provides=('naev' 'naev-data')
conflicts=('naev' 'naev-data')

_gitroot="git://github.com/bobbens/naev.git"
_gitname="naev"
_gitbranch="balance"

build() {
    cd "$srcdir"
    msg "Connecting to $_gitroot..."

    if [[ -d "$_gitname" ]]; then
        cd "$_gitname"
        git pull origin
        msg "Completed update of local files."
    else
        git clone "$_gitroot" "$_gitname"
    fi

    cd "$srcdir/$_gitname"
    msg "Checking out $_gitbranch branch..."

    if [[ "$(git branch)" =~ "$_gitbranch" ]]; then
        git checkout "$_gitbranch"
    else
        git checkout -b "$_gitbranch" "origin/$_gitbranch"
    fi

    msg "GIT checkout done or server timeout."
    msg "Cloning to build directory..."

    rm -rf "$srcdir/$_gitname-build"
    git clone "$srcdir/$_gitname" "$srcdir/$_gitname-build"

    cd "$srcdir/$_gitname-build"
    msg "Starting make..."

    ./autogen.sh
    ./configure --prefix=/usr

    make
}

package() {
    cd "$srcdir/$_gitname-build"

    make DESTDIR="$pkgdir" install
}