#include "colors.inc"
#include "textures.inc"
#include "shapes.inc"
#include "woods.inc"
#include "glass.inc"
#include "finish.inc"
camera {
    perspective
    right x * 1.33
    location <5, 10, -10>
    look_at <0, 3, 0>
}
light_source {
    <5, 5, -20>
    color rgb <3, 3, 2>
    area_light <2, 0, 0>, <0, 2, 0>, 2, 2
    adaptive 1
    jitter
}
light_source {
    <5, 5, 20>
    color rgb <2, 3, 3>
    area_light <2, 0, 0>, <0, 2, 0>, 2, 2
    adaptive 1
    jitter
}
plane {
    y, 0
    texture { pigment { P_WoodGrain3A color_map { M_Wood12A }} scale <10, 1, 10> }
    texture { pigment { P_WoodGrain3B color_map { M_Wood12B }} scale <10, 1, 10> }
}

#declare glassOuter = sor {
    6,
    <0.8, 0>,
    <0.8, 0.1>,
    <0.9, 0.2>,
    <1, 0.5>,
    <0.7, 2>,
    <0.4, 3>
}

#declare glassInner = object {
    glassOuter
    translate y * 0.05
    scale <0.94, 1, 0.94>
}

merge {

    // Glass
    difference {
        object { glassOuter }
        object { glassInner }
    }

    // Handle
    difference {
        torus {
            1, 0.1
            rotate x * -90
            scale <0.5, 0.8, 1>
            translate <1, 1.1, 0>
        }
        object { glassOuter }
    }

    material {
        texture {pigment {color Clear} finish {F_Glass2}}
        interior {I_Glass2 fade_color Col_Blue_01}
    }
    scale <4, 4, 4>
}

// Jizz
intersection {

    object { glassInner }
    box { <-10, 0, -10>, <10, 1.5, 10> }

    texture {
        pigment { color rgbf <1.0, 1.0, 1.0, 0.3> }
        finish {diffuse 0.7 ambient 0.3}
        normal {bumps 0.2 scale .01}
    }
    translate y * 0.001
    scale <3.995, 4, 3.995>
}