peazip-qt-5.3.1-PKGBUILD

# Maintainer: Limao Luo <[email protected]>
# Contributor: TuxSpirit <[email protected]>
# Contributor: Narga <[email protected]>
pkgname=peazip-qt
pkgver=5.3.1
pkgrel=0
pkgdesc="QT archiver utility"
arch=(i686 x86_64)
url=http://peazip.sourceforge.net/peazip-linux.html
license=(Artistic2.0 LGPL2.1)
depends=(balz desktop-file-utils lib32-{curl,gmp,libx11,ncurses,qt4pas,gtk2} p7zip quad unace upx zpaq lpaq paq8o)
[[ $CARCH == "i686" ]] && depends=(${depends[@]/lib32-/})
provides=(${pkgname%-*})
conflicts=(${pkgname%-*}-gtk2)
install=${pkgname%-*}.install
source=($pkgname-$pkgver.tgz::http://downloads.sourceforge.net/project/${pkgname%-*}/$pkgver/${pkgname%-*}-$pkgver.LINUX.Qt.tgz
    ${pkgname%-*}.desktop)
noextract=($pkgname-$pkgver.tgz)
sha256sums=('d16470b412643c0f395bc6fa2408eaefea5620b9a5bc4d3458743b449dc74e49'
    'c3ca0fa3e89626447acc376e2392fdd4e452c2b8f0685324eb978ab63c217fce')
sha512sums=('f716061029e3bc995e750a58228c7b8af888bc5a7e92b026af61d8ac699b22850b9a69488695defe513df8b055ca5d0cc6438da928f5e0b0d0ade47917752c2e'
    '0fb2e432f3b403df55134ebd57aacd2fb1eea75ef96520a5e4d7827ec319ca16a45c6e147504af0472704872fc601273b38d8f45ebfb8f68328266d240a1f71f')

package() {
    _resdir="$pkgdir"/usr/lib/${pkgname%-*}/res/

    install -d $pkgname/
    cd $pkgname/
    bsdtar -xf ../$pkgname-$pkgver.tgz
    cd usr/local/share/PeaZip/res/

    install -Dm755 ../${pkgname%-*} "$pkgdir"/usr/lib/${pkgname%-*}/${pkgname%-*}

    for i in pea pealauncher rnd; do
        install -Dm755 $i "$_resdir"/$i
    done
    for i in arc/{arc,*.sfx}; do
        install -Dm755 $i "$_resdir"/$i
    done
    for i in altconf.txt lang/* themes/{{nographic,seven}-embedded/*,*.7z} arc/arc.{ini,groups}; do
        install -Dm644 $i "$_resdir"/$i
    done

    install -d "$_resdir"/7z/Codecs/
    for i in 7z{,a,r,.so,Con.sfx,.sfx} Codecs/Rar29.so; do
        ln -sf /usr/lib/p7zip/$i "$_resdir"/7z/$i
    done
    for i in quad/{balz,quad} unace/unace upx/upx lpaq/lpaq8 paq/paq8o zpaq/zpaq; do
        install -d "$_resdir"/$(dirname $i)/
        ln -sf /usr/bin/$(basename $i) "$_resdir"/$i
    done
    install -d "$pkgdir"/usr/bin/
    for i in /usr/lib/${pkgname%-*}/{${pkgname%-*},res/pea,res/pealauncher}; do
        ln -sf $i "$pkgdir"/usr/bin/$(basename $i)
    done

    install -Dm644 "$srcdir"/$pkgname/usr/local/share/icons/${pkgname%-*}.png "$pkgdir"/usr/share/pixmaps/${pkgname%-*}.png
    desktop-file-install "$srcdir"/${pkgname%-*}.desktop --dir "$pkgdir"/usr/share/applications/
}