EP2e Roll20 Macros: Hacking Intrusion

/*
 * User Notes
 * ----------
 * The stacked macros "prepend code" resolves as a newline in the Roll20 macro window. If needed again, replace the !newline with !
 * #hack-initiate is the only macro intended to be visible & selectable by players. It contains several nested macros to roll dice,
 *  prompt users for modifiers (prompting GM is outside of Roll20 default functionality), and prompt users for stare-and-compare roll
 *  resolution.
 * The intended usage paradigm follows GM-visible rolls and Player/Target tokens. Modification will be required for alternate usage.
 * Firewall target are intended to be used as token, where only the Total Infosec score matters. Mote/Server/Host = 30/50/70 skill.
 * Intruder Subversion and Defender actions are outside the scope of this pastebin.
 * Image Example: https://imgur.com/HbQr2Lg
 */

// name: hack-initiate
// brief: Attach to a character token as an ability macro. Serves as a wrapper for all further Intrusion macros.
&{template:default} {{name= **@{selected|character_name}** is initiating a hack!}} {{[Brute Force](!
#hack-initiate-brute-force) [Subtle](!
#hack-initiate-subtle)}}

// name: hack-initiate-brute-force
&{template:default} {{name= **@{selected|character_name}** initiated a brute force hack against **@{target|character_name}**}} {{Intruder Infosec Target= [[@{selected|total-infosec} - 30 - @{selected|malus} + ?{+30 if successful past hack + teamwork bonus}]]}} {{Roll= [[1d100]]}} {{Defender Infosec Target= [[@{target|total-infosec} - @{target|malus}]]}} {{Roll = [[1d100]]}} {{[Resolve Successful Hack](!
#hack-resolve-brute-force) [Resolve Failed Hack](!
#hack-resolve-failed) }}

// name: hack-initiate-subtle
&{template:default} {{name= **@{selected|character_name}** initiated a subtle hack against **@{target|character_name}**}} {{Task Action Timeframe= [[1 + ?{Time Modifier?|0}]] hours}} {{Intruder Infosec Target= [[@{selected|total-infosec} - @{selected|malus} + ?{+30 if successful past hack + teamwork bonus}]]}} {{Roll= [[1d100]]}} {{Defender Infosec Target= [[@{target|total-infosec} - @{target|malus}]]}} {{Roll = [[1d100]]}} {{[Resolve Successful Hack](!
#hack-resolve-subtle) [Resolve Failed Hack](!
#hack-resolve-failed) }}

// name: hack-resolve-brute-force
&{template:default} {{name= Intruder hacked the system!}} {{Privileges= User}} {{Visibility= Spotted}} {{Alert= Active}} {{Superior?= [Super](!
#hack-resolve-super) [Double Super](!
#hack-resolve-double-super) }} {{Crit?= [Crit](!
#hack-resolve-brute-force-crit)}}

// name: hack-resolve-brute-force-crit
&{template:default} {{name= Intruder diminished their Visibility and reduced Alert!}} {{Visibility= Covert}} {{Alert= Passive}}

// name: hack-resolve-double-super
&{template:default} {{name= Intruder upgraded their Privileges!}} {{Privileges= Admin}}

// name: hack-resolve-failed
&{template:default} {{name= Intruder failed to breach the system!}} {{Alert= Passive}}

// name: hack-resolve-subtle
&{template:default} {{name= Intruder hacked the system!}} {{Privileges= User}} {{Visibility= Covert}} {{Alert= None}} {{Superior?= [Super](!
#hack-resolve-super) [Double Super](!
#hack-resolve-double-super) }} {{Crit?= [Crit](!
#hack-resolve-subtle-crit)}}

// name: hack-resolve-subtle-crit
&{template:default} {{name= Intruder diminished their Visibility!}} {{Visibility= Hidden}}

// name: hack-resolve-super
&{template:default} {{name= Intruder raised their Privileges!}} {{Privileges= Security}}