nuclear-player-git

pkgname=nuclear-player-git
_app_id=org.js.nuclear.Nuclear
pkgver=0.6.17.r4.g4a807e1d
pkgrel=1
_nodeversion=12
pkgdesc="Streaming music player that finds free music for you"
arch=('x86_64')
url="https://nuclear.js.org"
license=('GPL3')
depends=('gtk3' 'nss')
makedepends=('git' 'nvm' 'setconf')
provides=("${pkgname%-git}")
conflicts=("${pkgname%-git}")
source=('git+https://github.com/nukeop/nuclear.git')
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/nuclear"
  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

_ensure_local_nvm() {
  # let's be sure we are starting clean
  which nvm >/dev/null 2>&1 && nvm deactivate && nvm unload
  export NVM_DIR="$srcdir/.nvm"

  # The init script returns 3 if version specified
  # in ./.nvrc is not (yet) installed in $NVM_DIR
  # but nvm itself still gets loaded ok
  source /usr/share/nvm/init-nvm.sh || [[ $? != 1 ]]
}

prepare() {
  cd "$srcdir/nuclear"
  setconf "flatpak/${_app_id}.desktop" Exec nuclear

  export npm_config_cache="$srcdir/npm_cache"
  _ensure_local_nvm
  nvm install "$_nodeversion"
}

build(){
  cd "$srcdir/nuclear"
  export npm_config_cache="$srcdir/npm_cache"
  _ensure_local_nvm
  npm install
  npm run build
}

package(){
  cd "$srcdir/nuclear"
  install -d "$pkgdir/opt/nuclear/"
  cp -r release/linux-unpacked/* "$pkgdir/opt/nuclear/"

  install -Dm644 "flatpak/${_app_id}.desktop" -t "$pkgdir/usr/share/applications/"
  install -Dm644 "flatpak/${_app_id}.metainfo.xml" -t "$pkgdir/usr/share/metainfo/"

  install -d "$pkgdir/usr/share/icons/hicolor/512x512/apps/"
  ln -s /opt/nuclear/resources/media/512x512.png \
    "$pkgdir/usr/share/icons/hicolor/512x512/apps/${_app_id}.png"

  install -d "$pkgdir/usr/bin"
  ln -s /opt/nuclear/nuclear "$pkgdir/usr/bin/"
}