@echo off
color 1F
chcp 437 >nul
%windir%\system32\reg.exe query "HKU\S-1-5-19" 1>nul 2>nul || (
echo.
echo ============================================================
echo ERROR: Administrator privileges not detected.
echo ============================================================
echo.
echo please, re-open this script and 'Run as administrator'
echo.
echo.
echo Press any key to exit...
pause >nul
goto :eof
)
setlocal enableextensions
for /f "tokens=6 delims=[]. " %%G in ('ver') do set winbuild=%%G
for /f "skip=2 tokens=2*" %%i in ('"reg query "HKLM\System\CurrentControlSet\Control\Session Manager\Environment" /v PROCESSOR_ARCHITECTURE" 2^>nul') do set arch=%%j
if /i %arch%==AMD64 set arch=bin
set "_SLMGR=%SystemRoot%\System32\slmgr.vbs"
for /f "tokens=2*" %%a IN ('"reg query HKLM\SOFTWARE\Microsoft\Office\ClickToRun /v InstallPath" 2^>nul') do (set "_OSPP=%%b\Office16\OSPP.VBS"&set "_LicPath=%%b\root\Licenses16")
sc query ClickToRunSvc >nul 2>&1
if %errorlevel% equ 1060 (
echo.
echo Could not detect Office ClickToRun service...
goto :end
)
if not exist "%_LicPath%\*.xrm-ms" (
echo.
echo Could not detect Office 2016 Licenses files...
goto :end
)
if %winbuild% LSS 9200 if not exist "%_OSPP%" (
echo.
echo Could not detect Licensing tool OSPP.VBS...
goto :end
)

:Check
set /a _VL=0
set /a _TB=0
set /a _Grace=0
if %winbuild% GEQ 9200 (
set spp=SoftwareLicensingProduct
set sps=SoftwareLicensingService
) else (
set spp=OfficeSoftwareProtectionProduct
set sps=OfficeSoftwareProtectionService
)
for /f "tokens=2 delims==" %%A in ('"wmic path %sps% get version /format:list" 2^>nul') do set ver=%%A
wmic path %spp% where (Description like '%%KMSCLIENT%%' AND LicenseFamily != 'Office16MondoR_KMS_Automation') get Name /format:list 2>nul | findstr /i /C:"Office 16" 1>nul && set /a _VL=1
wmic path %spp% where (Description like '%%TIMEBASED%%') get Name /format:list 2>nul | findstr /i /C:"Office 16" 1>nul && set /a _TB=1
wmic path %spp% where (Description like '%%Grace%%') get Name /format:list 2>nul | findstr /i /C:"Office 16" 1>nul && set /a _Grace=1
if %_TB% equ 0 if %_Grace% equ 0 if %_VL% equ 1 (
echo.
echo No Conversion or Cleanup Required...
goto :end
)
setLocal EnableDelayedExpansion
echo.
echo Cleaning Current Office 16 Licenses...
cd /d "%~dp0"
%arch%\cleanospp.exe >nul 2>&1

:Ret2VL
echo.
echo Installing Office 16 Volume Licenses...
cd /d "%_LicPath%"
for /f "delims=" %%i in ('dir /b /on client-issuance-*.xrm-ms') do (
  if %winbuild% GEQ 9200 (
    cscript //Nologo //B %_SLMGR% /ilc %%i
  ) else (
    cscript //Nologo //B "%_OSPP%" /inslic:%%i
  )
)

if %winbuild% GEQ 9200 (
cscript //Nologo //B %_SLMGR% /ilc pkeyconfig-office.xrm-ms
) else (
cscript //Nologo //B "%_OSPP%" /inslic:pkeyconfig-office.xrm-ms
)
set SkuIds=(mondo,proplus,projectpro,visiopro,standard,projectstd,visiostd)
set ProSkuIds=(access,excel,onenote,outlook,powerpoint,publisher,skypeforbusiness,word)
set ProSkuId2=(o365proplus,professional)
set StdSkuIds=(excel,onenote,outlook,powerpoint,publisher,word)
for /d %%a in %SkuIds% do (set /a _%%a=0)
for /d %%a in %ProSkuIds% do (set /a _%%a=0)
for /d %%a in %ProSkuId2% do (set /a _%%a=0)

for /f "tokens=2,*" %%a IN ('"reg query HKLM\SOFTWARE\Microsoft\Office\ClickToRun\Configuration /v ProductReleaseIds" 2^>nul') do (set "ProductIds=%%b")

for /d %%a in %SkuIds% do (
echo %ProductIds% | findstr /I /C:"%%aretail" 1>nul && set /a _%%a=1
)
for /d %%a in %ProSkuIds% do (
echo %ProductIds% | findstr /I /C:"%%aretail" 1>nul && set /a _%%a=1
)
for /d %%a in %ProSkuId2% do (
echo %ProductIds% | findstr /I /C:"%%aretail" 1>nul && set /a _%%a=1
)
if %_mondo% equ 1 (call :InsLic mondo &goto :GVLK)
for /d %%a in %SkuIds% do (
if !_%%a! equ 1 call :InsLic %%a
)
for /d %%a in %ProSkuId2% do (
if !_%%a! equ 1 if !_proplus! equ 0 call :InsLic proplus
)
for /d %%a in %StdSkuIds% do (
if !_%%a! equ 1 if !_proplus! equ 0 if !_standard! equ 0 if !_professional! equ 0 call :InsLic %%a
)
for /d %%a in (skypeforbusiness) do (
if !_%%a! equ 1 if !_proplus! equ 0 call :InsLic %%a
)
for /d %%a in (access) do (
if !_%%a! equ 1 if !_proplus! equ 0 !_professional! equ 0 call :InsLic %%a
)

:GVLK
echo.
echo Installing KMS Client Keys...
echo.
for /f "tokens=2 delims==" %%G in ('"wmic path %spp% where (Description like '%%Office 16, VOLUME_KMSCLIENT%%') get ID /format:list"') do (set ActID=%%G&call :InsKey)
goto :end

:InsLic
for /f "delims=" %%i in ('dir /b /on %1VL_*.xrm-ms') do (
  if %winbuild% GEQ 9200 (
    cscript //Nologo //B %_SLMGR% /ilc %%i
  ) else (
    cscript //Nologo //B "%_OSPP%" /inslic:%%i
  )
)
exit /b

:InsKey
for /f "tokens=2 delims==" %%A in ('"wmic path %spp% where ID='%ActID%' get Name /format:list"') do echo %%A
(echo edition = "%ActID%"
echo Set keys = CreateObject ^("Scripting.Dictionary"^)
echo keys.Add "9caabccb-61b1-4b4b-8bec-d10a3c3ac2ce", "HFTND-W9MK4-8B7MJ-B6C4G-XQBR2"
echo keys.Add "d450596f-894d-49e0-966a-fd39ed4c4c64", "XQNVK-8JYDB-WJ9W3-YJ8YR-WFG99"
echo keys.Add "dedfa23d-6ed1-45a6-85dc-63cae0546de6", "JNRGM-WHDWX-FJJG3-K47QV-DRTFM"
echo keys.Add "4f414197-0fc2-4c01-b68a-86cbb9ac254c", "YG9NW-3K39V-2T3HJ-93F3Q-G83KT"
echo keys.Add "da7ddabc-3fbe-4447-9e01-6ab7440b4cd4", "GNFHQ-F6YQM-KQDGJ-327XX-KQBVC"
echo keys.Add "6bf301c1-b94a-43e9-ba31-d494598c47fb", "PD3PC-RHNGV-FXJ29-8JK7D-RJRJK"
echo keys.Add "aa2a7821-1827-4c2c-8f1d-4513a34dda97", "7WHWN-4T7MP-G96JF-G33KR-W8GF4"
echo keys.Add "67c0fc0c-deba-401b-bf8b-9c8ad8395804", "GNH9Y-D2J4T-FJHGG-QRVH7-QPFDW"
echo keys.Add "c3e65d36-141f-4d2f-a303-a842ee756a29", "9C2PK-NWTVB-JMPW8-BFT28-7FTBF"
echo keys.Add "d8cace59-33d2-4ac7-9b1b-9b72339c51c8", "DR92N-9HTF2-97XKM-XW2WJ-XW3J6"
echo keys.Add "ec9d9265-9d1e-4ed0-838a-cdc20f2551a1", "R69KK-NTPKF-7M3Q4-QYBHW-6MT9B"
echo keys.Add "d70b1bba-b893-4544-96e2-b7a318091c33", "J7MQP-HNJ4Y-WJ7YM-PFYGF-BY6C6"
echo keys.Add "041a06cb-c5b8-4772-809f-416d03d16654", "F47MM-N3XJP-TQXJ9-BP99D-8K837"
echo keys.Add "83e04ee1-fa8d-436d-8994-d31a862cab77", "869NQ-FJ69K-466HW-QYCP2-DDBV6"
echo keys.Add "bb11badf-d8aa-470e-9311-20eaf80fe5cc", "WXY84-JN2Q9-RBCCQ-3Q3J3-3PFJ6"
echo if keys.Exists^(edition^) then
echo WScript.Echo keys.Item^(edition^)
echo End If)>"%temp%\key.vbs"
set key=Unknown
for /f %%A in ('cscript /nologo "%temp%\key.vbs"') do set key=%%A
del /f /q "%temp%\key.vbs" >nul 2>&1
if %key%==Unknown (echo.&echo Could not find matching KMS Client key&exit /b)
wmic path %sps% where version='%ver%' call InstallProductKey ProductKey="%key%" >nul 2>&1
exit /b

:end
echo.
echo.
echo Press any key to exit...
pause >nul
goto :eof