pkgname=('lib32-x264')
_pkgbase=('x264')
pkgver=155.r0a84d986e702
pkgrel=1
arch=('x86_64')
url='https://www.videolan.org/developers/x264.html'
license=('GPL')
depends=('lib32-glibc' 'libx264')
makedepends=('git' 'l-smash' 'nasm')
pkgdesc='Library for encoding H264/AVC video streams (lib32)'
provides=('lib32-libx264' 'libx264.so')
conflicts=('lib32-libx264' 'lib32-libx264-10bit' 'libx264-all')
replaces=('lib32-libx264' 'lib32-libx264-10bit' 'lib32-libx264-all')
_commit='0a84d986e7020f8344f00752e3600b9769cc1e85'
source=("git+https://git.videolan.org/git/x264.git#commit=${_commit}")
sha256sums=('SKIP')

pkgver() {
    cd ${_pkgbase}

    local _ver=$(grep '#define X264_BUILD' x264.h | cut -d' ' -f3)
    local _rev=$(git rev-parse --short HEAD)

    echo ${_ver}.r${_rev}
}

prepare() {
    if [[ -d build ]]; then
        rm -rf build
    fi
    mkdir build
}

build() {
    cd build
    ../x264/configure \
    --prefix='/usr' \
    --enable-shared \
    --enable-pic \
    --enable-lto \
    --libdir=/usr/lib32 \
    --host=i686-linux-gnu
    make
}

package() {
    make -C build DESTDIR=${pkgdir} install-lib-shared
  rm -rf "${pkgdir}"/usr/include
}