Create_SteamBigWin

@echo off
SETLOCAL ENABLEEXTENSIONS
SETLOCAL ENABLEDELAYEDEXPANSION

set "defaultStyle=C:\Program Files (x86)\Steam\resource\styles\steam.styles"
set "bigStyleDirectory=C:\Program Files (x86)\Steam\skins\SteamBigWin\Resource\Styles"
set "bigStyleFile=%bigStyleDirectory%\steam.styles"

:: Create directory for new skin
md "%bigStyleDirectory%"

:: Copy Steam's default skin to our new skin directory
copy /Y "%bigStyleFile%" "%bigStyleFile%.bak"
copy /Y "%defaultStyle%" "%bigStyleFile%"

:: Let's start embiggening the skin (using powershell to do regex string replacement)

:: First, set up some variables that we'll plug in later

:: Scrollbar width 19->24
set "scrollbar24=19"

::SectionedListPanel CollapserWidth 16->20
set "sectionedList20=16"

:: font-size value replacements. There are a lot of these, so it's a little more involved
:: always replace largest numbers first so that we don't double replace
::   (example, 16->22->28 would be bad. We just want 22->28, then later 16->22)
set "font28=22 21"
set "font24=20 19 18 17"
set "font22=16 15"
set "font20=14 13 12"
set "font16=11"
set "font14=10"
set "font13=9 8"

:: bigFontSizes list's values should match the numbers in the "fontxx" variable names, again largest to smallest
set "bigFontSizes=28 24 22 20 16 14 13"

::Scrollbar widths to 24
for %%a in (%scrollbar24%) do (
   echo ScrollBar.Wide %%a to 24
   call powershell -Command "(gc '%bigStyleFile%') -replace '(ScrollBar\.Wide\s+)(\"?%%a\"?)', '${1}24' | Out-File -encoding ASCII '%bigStyleFile%'"
)

::SectionedListPanel CollapserWidth to 20
for %%a in (%sectionedList20%) do (
   echo SectionedListPanel.CollapserWidth %%a to 20
   call powershell -Command "(gc '%bigStyleFile%') -replace '(ScrollBar\.Wide\s+)(\"?%%a\"?)', '${1}20' | Out-File -encoding ASCII '%bigStyleFile%'"
)

::font sizes
for %%b in (%bigFontSizes%) do (
   for %%a in (!font%%b!) do (
      echo font-size %%a to %%b
      call powershell -Command "(gc '%bigStyleFile%') -replace '(font-size=)(\"?%%a\"?)', '${1}%%b' | Out-File -encoding ASCII '%bigStyleFile%'"
   )
)

echo Done
echo .
echo In Steam, choose Steam menu, Settings
echo On left side, choose Interface
echo On right side, choose SteamBigWin from the dropdown below "Select the skin..."


pause