Batch File Age Compare and Log

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: Date Comparison and File Log Function
:::
::: For use on Windows 10. To use on Older Systems, remove all instances of ANSI Color Codes IE: 

@GOTO :Main & REM Main Script Positioned After Functions.

:FolderOnly

    PUSHD "%~4"

    For %%A in (*.*) do (
        Set "extType=%%~xA"
        IF NOT "!extType!"=="" (
            CALL :FolderCheck "%%~dpA"
            CALL :ProcessDate "%%~tA"
REM Format File information into Columns using Set Substring Modification and white-space
            Set "File_N=%%~nxA"
            Set "File_N=!File_N!                                             "
            Set "File_N=!File_N:~,45!"
REM Set "Modified=!Modified:~,10!"
            Set "File_S=%%~zA"
            Set "File_S=!File_S!               "
            Set "File_S=!File_S:~,15!"
            CALL :ConvertJulian !FD_D! !FD_M! !FD_Y! FileDate
            CALL :DateDifference !FileDate! !CompDate! Difference

            IF !Difference!==0 (
                CALL :MatchFile
            )

            IF !Difference! LSS 0 (
                CALL :NewerFile
            )

            IF !Difference! GTR 0 (
                CALL :OlderFile
            )
        Set "InFolder=%%~dpA"
        )
    )

    POPD
    exit /b

:Recursive

    PUSHD "%~4"

    For /R %%A in (*.*) do (
        Set "extType=%%~xA"
        IF NOT "!extType!"=="" (
            CALL :FolderCheck "%%~dpA"
            CALL :ProcessDate "%%~tA"
REM Format File information into Columns using Set Substring Modification and white-space
            Set "File_N=%%~nxA"
            Set "File_N=!File_N!                                             "
            Set "File_N=!File_N:~,45!"
REM Set "Modified=!Modified:~,10!"
            Set "File_S=%%~zA"
            Set "File_S=!File_S!               "
            Set "File_S=!File_S:~,15!"
            CALL :ConvertJulian !FD_D! !FD_M! !FD_Y! FileDate
            CALL :DateDifference !FileDate! !CompDate! Difference

            IF !Difference!==0 (
                CALL :MatchFile "%%A"
            )

            IF !Difference! LSS 0 (
                CALL :NewerFile "%%A"
            )

            IF !Difference! GTR 0 (
                CALL :OlderFile "%%A"
            )
        Set "InFolder=%%~dpA"
        )
    )

    POPD
    exit /b

:FolderCheck <%%~dpI> REM displays or logs change in folder location for each Sub Directory being processed

REM Doubleqouting Of Directory Path Is Required

    IF Defined InFolder (
        IF NOT "!InFolder!"=="%~1" (
            ECHO(
            ECHO("%~1"
            ECHO(
            IF /I "!output!"=="Log" (
                ECHO.>>!LogLoc!fileage!LogDate!.log
                ECHO("%~1">>!LogLoc!fileage!LogDate!.log
                ECHO.>>!LogLoc!fileage!LogDate!.log
            )
        )
    )
    IF Not Defined Infolder (
        ECHO(
        ECHO("%~1"
        ECHO(
        IF /I "!output!"=="Log" (
            ECHO.>>!LogLoc!fileage!LogDate!.log
            ECHO("%~1">>!LogLoc!fileage!LogDate!.log
            ECHO.>>!LogLoc!fileage!LogDate!.log
        )
    )

    Exit /b

:OlderFile

    Set "Diff_Display=!Difference!               "
    Set "Diff_Display=!Diff_Display:~,15! Days Older.                              "
    Set Diff_Display=!Diff_Display:~,35!
    ECHO(!File_N! !Diff_Display! Modified: !Modified! Size: !File_S! Bytes

REM Insert Command/s below here if desired to act on files with an Older date. Filepath passed with Parameter 1

    IF "!output!"=="Log" (
        ECHO(!File_N! !Diff_Display! Modified: !Modified! Size: !File_S! Bytes>>!LogLoc!fileage!LogDate!.log
    )
    Exit /b

:NewerFile

    Set "Diff_Display=!Difference:~1,20!               "
    Set "Diff_Display=!Diff_Display:~,15! Days Newer.                              "
    Set Diff_Display=!Diff_Display:~,35!
    ECHO(!File_N! !Diff_Display! Modified: !Modified! Size: !File_S! Bytes

REM Insert Command/s below here if desired to act on Newer files. Filepath passed with Parameter 1

    IF "!output!"=="Log" (
    ECHO(!File_N! !Diff_Display! Modified: !Modified! Size: !File_S! Bytes>>!LogLoc!fileage!LogDate!.log
    )
    Exit /b

:MatchFile

    Set "Diff_Display=!Difference!               "
    Set "Diff_Display=!Diff_Display:~,15! Days. Date Match.                              "
    Set Diff_Display=!Diff_Display:~,35!
    ECHO(!File_N! !Diff_Display! Modified: !Modified! Size: !File_S! Bytes

REM Insert Command/s below here if desired to act on files that match the Date. Filepath passed with Parameter 1

    IF "!output!"=="Log" (
        ECHO(!File_N! !Diff_Display! Modified: !Modified! Size: !File_S! Bytes>>!LogLoc!fileage!LogDate!.log
    )
    Exit /b

:ProcessDate <%%~tI>

    Set "F_D=%~1"
    Set "F_D=!F_D:/=!"
    Set "F_D=!F_D:~0,8!"
    Set "FD_Y=!F_D:~4,4!"

    IF "%format%"=="DDMM" (
    REM DDMM Format:
        Set "FD_D=!F_D:~0,2!"
        Set "FD_M=!F_D:~2,2!"
        Set "Modified=!FD_D! !FD_M! !FD_Y!"

REM Remove leading Zeros to use for LSS LEQ EQU GTR GEQ comparisons
        Set /A FD_D = 100!FD_D! %% 100
        Set /A FD_M = 100!FD_M! %% 100
    ) else (
REM MMDD Format:
        Set "FD_M=!F_D:~0,2!"
        Set "FD_D=!F_D:~2,2!"
        Set "Modified=!FD_M! !FD_D! !FD_Y!"
REM Remove leading Zeros to use for LSS LEQ EQU GTR GEQ comparisons
        Set /A FD_M = 100!FD_M! %% 100
        Set /A FD_D = 100!FD_D! %% 100
    )

    Exit /b

:ConvertJulian REM Leading Zero's Must be removed. <DD> <MM> <YYYY> <ResultVar>

    Setlocal
    Set "Day=%1"
    Set "Month=%2"
    Set /a "MonthCv=( %Month% - 14 ) / 12"
    Set /a "YearCv=%3 + 4800"
    Set /a "Julian=1461 * ( %YearCv% + %MonthCv% ) / 4 + 367 * ( %Month% - 2 -12 * %MonthCv% ) / 12 - ( 3 * ( ( %YearCv% + %MonthCv% + 100 ) / 100 ) ) / 4 + %Day% - 32075"

    (
    Endlocal
    Set "%~4=%Julian%"
    exit /b
    )

:DateDifference <Comparison Date Julian Value> <File Date Julian Value> <ResultVar>

    SetLocal
    Set /a "tmp=%~2 - %~1"
    (
    Endlocal
    Set "%3=%tmp%"
    exit /b
    )

:Input <VarName> <StartRange> <EndRange> <Next Label>
    Set "C_Prompt=Enter a value between %2 and %3 for %1 }< "
    Set /P "%1=!C_Prompt!"
    For /L %%i in (%2,1,%3) DO (IF "%%i"=="!%1!" GOTO :%4)
    ECHO(Invalid value for %1
    Exit /B

:::
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: End File Age Comparison Function

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: *** Commence Main ***

:Main
@ECHO OFF & mode 1000 & Title File Age Checking Function

    Setlocal EnableDelayedExpansion
    cls & Color 02

    Set "LogLoc=%~dp0"
    Set "LogLoc=%LogLoc%logs\"
    IF NOT EXIST "%LogLoc%" md "%LogLoc%"

    Set "format=DDMM"
    Set "LogDate=%DATE%"
    Set "LogDate=%LogDate:~4,10%"
    Set "FormatID=false"
    Call :ProcessDate %LogDate%

    IF %FD_D% GTR 12 (
        ECHO( Date Format Detected as DDMMYYYY
        Set "FormatID=true"
    )

    IF "%FormatID%"=="false" (
        Set "format=MMDD"
        Call :ProcessDate %LogDate%
        IF %FD_D% GTR 12 (
            ECHO( Date Format Detected as MMDDYYYY
            Set "FormatID=true"
        )
    )

    IF "%FormatID%"=="false" (
        ECHO(  Select the Date Format of your device: [M] MMDDYYYY [D] DDMMYYYY
        CHOICE /N /C dm /M "" >nul
        IF %ERRORLEVEL%==2 (
            Set "format=MMDD"
        ) else (
            Set "format=DDMM"
        )
    )

    Set "LogDate=%Modified: =%

    ECHO(
    ECHO( Select Search Type: (R)ecursive (F)older Only
    CHOICE /N /C rf /M "" >nul
    IF ERRORLEVEL 2 (
        Set "Search=FolderOnly"
    ) else (
        Set "Search=Recursive"
    )

    ECHO( Select Output Type: (D)isplay Only (L)og and Display
    CHOICE /N /C ld /M "" >nul
    IF ERRORLEVEL 2 (
        Set "output=Display"
    ) else (
        Set "output=Log"
        IF Exist "!LogLoc!fileage!LogDate!.log" (
            ECHO( A Log Already Exists For Today.
            ECHO( Overwrite? Y/N
            CHOICE /N /C YN /M "" >nul
            IF ERRORLEVEL 2 (
                ECHO(Log Will Not be Stored.
                Set "output=Display"
            ) else (
                DEL /Q "!LogLoc!fileage!LogDate!.log" && ECHO( Log Removed.
            )
        )
    )

    ECHO(

    Set "C_Prompt=Drag and Drop or Enter Directory  }< "
    (Set /p "AgeDir=!C_Prompt!")

    IF Not Exist "!AgeDir!" (
        Cls
        ECHO( Invalid Directory Entered.
        Timeout 1 > nul
        Endlocal & GOTO :Main
    )

    ECHO(

REM Get safe user Input for Date Comparison

:Day_Select

    Call :Input DD 1 31 Month_Select
    GOTO :Day_Select

:Month_Select

    Call :Input MM 1 12 Year_Select
    GOTO :Month_Select

:Year_Select

REM Date substring modification `%Date:~10,4%` suitable for DDMMYYYY or MMDDYYYY Formats only
    Call :Input YYYY 1985 %Date:~10,4% Fetch_Data
    GOTO :Year_Select

:Fetch_Data
    Call :ConvertJulian %DD% %MM% %YYYY% CompDate
    Cls
    CALL :%search% %DD% %MM% %YYYY% "%AgeDir%"
    ECHO  & REM The preceeding Character is the BEL character, Not the ANSI ESC character used for Color Codes.
    ECHO(  Comparison Complete.  Next...
    pause >nul
    ENDLOCAL & GOTO :Main

::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::: *** End Main ***