label labrom:

    call animain from _call_animain

    if herbchecker["ромашка"]:
        show nik ace with vpunch
        nik "Я знаю! Я вижу! Здесь растут ромашки!"
        msh "Пупавки."
        show nik exc with vpunch
        nik "Что?!"
        show msh smi with dissolve
        msh "Здесь растут пупавки."
        msh "У ромашки было много разных имен, например - «пупавка»."
        show msh std
        show nik dou
        with dissolve
        nik "Пупавка? Это за что ж ее, бедную, так называли?"
        show msh smi with dissolve
        msh "Её так прозвали из-за желтого пупка, красующегося посередине цветка. "
        show nik std
        show yoz exc
        with dissolve
        yoz "Может хватит болтать, и пора собирать?"
        show msh ace with vpunch
        msh "Не торопись!"
        show msh ace with vpunch
        msh "Ты знаешь, что нам подойдет не любая ромашка?"
        show yoz dou with dissolve
        yoz "Ладно тебе, ромашка и в Африке ромашка."
        show msh smi with dissolve
        msh "Да нет, не все так просто! Нам нужна именно аптечная ромашка, только она обладает подходящими целебными свойствами."
        msh "Отличить её очень легко, у нее выпуклая сердцевина, а белые реснички лепестки короткие."
        show nik smi with dissolve
        nik "Мышь! Можно вопрос?"
        show msh std
        show yoz std
        with dissolve
        msh "Да?"
        show nik std with dissolve
        nik "А остальные? Что, например, вот это за зеленая штука?"
        msh "Это пахучая ромашка. Она тоже лечебная, но её сок нельзя принимать внутрь, нам она не подойдёт."
        msh "Не слишком похожа на аптечную, без белых лепестков и сердцевина зеленоватая."
        nik "Ага-ага. А это?"
        #TODO? Показать растения?
        msh "А это скальная ромашка. Вообще-то она растет на скалах, на островах, возле морских заливов."
        msh "Но тут, в вечном лесу, чего только не увидишь!"
        msh "Она больше похожа на аптечную, но крупнее и сердцевина значительно более выпуклая"
        show yoz smi with dissolve
        yoz "Красивая..."
        show msh smi with dissolve
        msh "О да, красивая. А ещё она бывает разных цветов: красная, желтая, нежно-розовая... Ну, и белая, конечно."
        show nik smi with dissolve
        nik "Ой, как здорово!"
        show msh std
        show yoz std
        show nik std
        with dissolve
        msh "А вот эта, ярко розовая, называется Ромашка Персидская. Или, ещё иногда её называют, кавказская."
        msh "Она помогает бороться со всякими насекомыми, вредителями и паразитами."
        show msh ace with vpunch
        msh "Но как лекарство её использовать не стоит! Все же она ядовита!"
        show yoz dou with dissolve
        yoz  "Оказывается, это не так просто..."
        show yoz std
        show msh std
        show nik std
        with dissolve
    else:
        show yoz std with dissolve
        yoz "И мы опять на поляне с ромашками."
    $ t=[i[0] for i in inventorys]
    if not "r" in t:
        if herbchecker["ромашка"]:
            $ herbchecker["ромашка"]=False
            yoz "[pl_name], поможешь мне? Укажи на нужную ромашку. Не хотелось бы сорвать что-то ядовитое."
            menu:
                "Да.":
                    show yoz smi with dissolve
                    yoz "Я в тебе не сомневался!"
                    show yoz std with dissolve
                    jump .game

                "Не сейчас.":
                    show yoz sad with dissolve
                    yoz "Понимаю..."
                    show yoz ace with vpunch
                    yoz "Но мы обязательно сюда вернёмся! И найдём нужную травку!"
                    jump goto
        else:
            yoz "В прошлый раз мы с тобой, [pl_name], не угадали. Может, в этот раз получится. Попробуем?"
            menu:
                "Да.":
                    show yoz smi with dissolve
                    yoz "Я в тебе не сомневался!"
                    show yoz std with dissolve
                    jump .game

                "Не сейчас.":
                    show yoz sad with dissolve
                    yoz "Понимаю..."
                    show yoz ace with vpunch
                    yoz "Но мы обязательно сюда вернёмся! И найдём нужную травку!"
                    jump goto
    else:
        yoz "Так, это полянка с ромашками. Они у нас уже есть."
        jump goto

    ##########################
    ### МИНИИГРА С ВЫБОРОМ ###
    ##########################
    label .game:
    yoz "Помоги мне выбрать правильную ромашку!"
    label labromrestart:
    call screen truestrike("r")
    if _return==True:
        show yoz ace with vpunch
        yoz "Ты справился! Круто!"
        show yoz std with dissolve
        $t=["r","Ромашка Аптечная","Ромашка аптечная (лекарственная) – очень известное и широко распространенное в наших широтах растение. Ромашка аптечная (лекарственная) – очень известное и широко распространенное в наших широтах растение. Длина листьев — 2-5 см, они располагаются на стебле по очереди. На узколинейном листе есть рассечения с острыми дольками. Корень тонкий, стержневой, практически не имеющий разветвлений. Цветочные корзинки маленькие, с белыми лепестками по краям и желтыми цветками. Дед Ёж говорит, что она помогает от раздражений, больного горла, проблем с пищеварением."]
        $inventorys.append(t)
        if len(numherbs)==0:
            $numherbs.append(t[0])
            jump initint
            jump goto
        else:
            $numherbs.append(t[0])
            voice pm
            "[t[1]] добавлено в инвентарь"
            jump goto

    elif _return=="Cancel":
        yoz "Уф. Что-то сложно! Отдохнем немного и..."
        menu:
            "Попробовать снова":
                show yoz ace with vpunch
                yoz "И попробуем снова!"
                show yoz std with dissolve
                jump labromrestart
            "Вернемся сюда позже.":
                yoz "Вернемся сюда потом."
                show yoz std with dissolve
                jump labromnogame
    else:
        msh "М... Нет. Это не та ромашка."
        show yoz dou with dissolve
        yoz "Да как так-то?!"
        show yoz std with dissolve
        yoz "Давай ещё раз."
        jump  labromrestart

    ##########################
    label labromnogame:

        msh "Что ж, мы сюда ещё обязательно вернемся"

    label .end:
    jump goto