import scripts.nc_script_addons.FuelInfoExample.FuelInfo.FuelInfo;
import scripts.nc_script_addons.FuelInfoExample.ExampleAddonSetup.fuelNameSuffix;
import scripts.nc_script_addons.FuelInfoExample.ExampleAddonSetup.fuelOreSuffix;
import scripts.nc_script_addons.FuelInfoExample.ExampleAddonSetup.fuelTimeMult;
import scripts.nc_script_addons.FuelInfoExample.ExampleAddonSetup.fuelHeatMult;
import scripts.nc_script_addons.FuelInfoExample.ExampleAddonSetup.fuelCritMult;
import scripts.nc_script_addons.FuelInfoExample.ExampleAddonSetup.fuelInfoList;

import crafttweaker.oredict.IOreDict;

import mods.nuclearcraft.SolidFission;

function addFuelRecipes(info as FuelInfo) {
	for i in 0 to 3 {
		var fuel = oreDict.get("ingot" ~ info.name ~ fuelOreSuffix[i]);
		fuel.add(itemUtils.getItem("contenttweaker:" ~ "fuel_" ~ info.name ~ fuelNameSuffix[i]));

		var depleted = oreDict.get("ingotDepleted" ~ info.name ~ fuelOreSuffix[i]);
		depleted.add(itemUtils.getItem("contenttweaker:" ~ "depleted_fuel_" ~ info.name ~ fuelNameSuffix[i]));

		SolidFission.addRecipe(fuel, depleted, (fuelTimeMult[i] * info.time) as int, (fuelHeatMult[i] * info.heat) as int, info.efficiency, (fuelCritMult[i] * info.crit) as int, info.decay, info.prime, info.rad);
	}
}

for info in fuelInfoList {
	addFuelRecipes(info);
}