Shader "Deformed/Basic"
{

	Properties
	{
		_Color ("Main Color", Color) = (.5,.5,.5,1)
		_MainTex ("Base (RGB)", 2D) = "white" {}
		_Distance ("Distance", Float) = 4.0
	}

	SubShader
	{

		Pass
		{
			CGPROGRAM

			#pragma exclude_renderers xbox360

			#pragma vertex			vert
			#pragma fragment		frag
			#pragma fragmentoption	ARB_precision_hint_fastest

			#include "UnityCG.cginc"

			float4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			float _Distance;

			struct appdata
			{
				float4 vertex		: POSITION;
				float2 texcoord		: TEXCOORD0;
				float3 normal		: NORMAL;
			};

			struct v2f
			{
				float4 pos			: POSITION;
				float2 texcoord		: TEXCOORD0;
				float3 normal;
			};

			v2f vert (appdata v)
			{
				float4 transformedVertex = mul(_Object2World, v.vertex);

				float3 transformedUnitVertex = normalize(float3(
					- transformedVertex.x,
					- transformedVertex.y,
					_Distance
				));

				float4 distortedVertex = float4(
					transformedUnitVertex.x * (transformedVertex.z - _Distance - 0.5f),
					transformedUnitVertex.y * (transformedVertex.z - _Distance - 0.5f),
					transformedUnitVertex.z * (transformedVertex.z - _Distance - 0.5f),
					1.0
				);

				float4 distortedModelspaceVertex = mul(_World2Object, distortedVertex);

				v2f vd;

				vd.pos = mul(UNITY_MATRIX_MVP, distortedModelspaceVertex);
    			vd.texcoord = TRANSFORM_TEX(v.texcoord, _MainTex);
    			vd.normal = v.normal;

				return vd;
			}

			float4 frag (v2f i) : COLOR
			{
				float d = clamp(dot(i.normal, float3(0.0, 0.0, -1.0)), 0.0, 1.0);
				float4 s = tex2D(_MainTex, i.texcoord);

				return _Color * (s * 0.5 + s * d * 0.5);
			}

			ENDCG
		}

	}

	FallBack "Diffuse"

}