Ribbon particle example

// Ribbon particle demo object, by Maestro Linden.  Spins around to demonstrate ribbon particles.
// 1) Rez 2 boxes, and link them together
// 2) Save this script in the root prim
// 3) Particles using the ribbon mask are emitted from the child prim, as the root prim spins around.
default
{
    state_entry()
    {
        // particle texture to use
        key texture = "f2018c32-9d50-41b7-d28a-ec558b97a00c";
        llSetLinkPrimitiveParamsFast(1, [PRIM_TEXTURE, ALL_SIDES, texture, <1,1,0>, ZERO_VECTOR, 0.0]);

        // spin the linkset
        llTargetOmega(<0,0,1>, 1, 1);
        // offset, rotate, and hide the child prim
        llSetLinkPrimitiveParams(2, [PRIM_ROT_LOCAL, <-0.55141, -0.02408, -0.03638, 0.83309>,
            PRIM_POS_LOCAL, <0.0, 1.0, 0.0>,
            PRIM_COLOR, ALL_SIDES, <0,0,0>, 0.0]);
        llLinkParticleSystem(2, [
            PSYS_SRC_PATTERN, PSYS_SRC_PATTERN_DROP,
            PSYS_PART_FLAGS, PSYS_PART_RIBBON_MASK|PSYS_PART_INTERP_COLOR_MASK,
            PSYS_PART_START_SCALE, <0.25, 2.0, 0.0>,
            PSYS_PART_START_ALPHA, 1.0,
            PSYS_PART_END_ALPHA, 0.0,
            PSYS_PART_MAX_AGE, 3.0,
            PSYS_SRC_TEXTURE, texture
        ]);
    }
}