Lab23

Program Lab23;

Uses
    SysUtils;

Const
    MIN_N = 2;
    MAX_N = 100;
    MIN_A = -10000;
    MAX_A = 10000;

Type
    TMatrix = Array Of Array Of Double;

Function InputAndCheckChoice: Integer;
Var
    IsCorrect: Boolean;
    Choice: Integer;
Begin
    Choice := 0;
    Repeat
        IsCorrect := True;
        WriteLn('Введите ваш выбор: ');
        Try
            ReadLn(Choice);
        Except
            IsCorrect := False;
            WriteLn('Некорректный ввод. Введите 1 или 2.');
        End;

        If IsCorrect And (Choice <> 1) And (Choice <> 2) Then
        Begin
            WriteLn('Введите 1 или 2.');
            IsCorrect := False;
        End;
    Until IsCorrect;
    InputAndCheckChoice := Choice;
End;

Function InputAndCheckN: Integer;
Var
    IsCorrect: Boolean;
    N: Integer;
Begin
    N := 0;
    Repeat
        IsCorrect := True;
        WriteLn('Введите порядок матрицы n: ');
        Try
            ReadLn(N);
        Except
            IsCorrect := False;
            WriteLn('Некорректный ввод. Введите целое число.');
        End;

        If IsCorrect And ((N < MIN_N) Or (N > MAX_N)) Then
        Begin
            WriteLn('Диапазон значений n от ', MIN_N, ' до ', MAX_N, '. ');
            IsCorrect := False;
        End;
    Until IsCorrect;
    InputAndCheckN := N;
End;

Function IsFileExists(Const FileName: String): Boolean;
Begin
    IsFileExists := FileExists(FileName);
    If Not FileExists(FileName) Then
        WriteLn('Файл не существует.');
End;

Function IsFileTxt(Const FileName: String): Boolean;
Var
    FileType: String;
Begin
    If (Length(FileName) > 4) Then
    Begin
        FileType := FileName.SubString(FileName.Length - 4);
        If (FileType = '.txt') Then
            IsFileTxt := True
        Else
        Begin
            WriteLn('Файл не является текстовым. ');
            IsFileTxt := False;
        End;
    End
    Else
    Begin
        WriteLn('Введите корректное имя файла. ');
        IsFileTxt := False;
    End;
End;

Function IsFileNotEmpty(Var MyFile: TextFile): Boolean;
Var
    IsNotEmpty: Boolean;
Begin
    Try
        Try
            Reset(MyFile);
            IsNotEmpty := Not Eof(MyFile);
            If (Not IsNotEmpty) Then
                WriteLn('Этот файл пустой. ');
        Except
            WriteLn('Непредвиденная ошибка.');
            IsNotEmpty := False;
        End;
    Finally
        CloseFile(MyFile);
    End;
    IsFileNotEmpty := IsNotEmpty;
End;

Function IsFileWritable(Var MyFile: TextFile): Boolean;
Begin
    IsFileWritable := True;
    Try
        Rewrite(MyFile);
        Close(MyFile);
    Except
        IsFileWritable := False;
        WriteLn('Этот файл невозможно открыть для записи.');
    End;
End;

Function IsFileReadable(Var MyFile: TextFile): Boolean;
Begin
    IsFileReadable := True;
    Try
        Reset(MyFile);
        Close(MyFile);
    Except
        IsFileReadable := False;
        WriteLn('Этот файл невозможно открыть для чтения.');
    End;
End;

Function RequestFileNameForReading(Var MyFile: TextFile): String;
Var
    FileName: String;
    IsCorrect: Boolean;
Begin
    Repeat
        WriteLn('Введите имя файла с путём:');
        ReadLn(FileName);
        AssignFile(MyFile, FileName);
        IsCorrect := IsFileExists(FileName) And IsFileTxt(FileName) And IsFileReadable(MyFile) And IsFileNotEmpty(MyFile);
    Until IsCorrect;
    RequestFileNameForReading := FileName;
End;

Function RequestFileNameForWriting(Var MyFile: TextFile): String;
Var
    FileName: String;
    IsCorrect: Boolean;
Begin
    Repeat
        WriteLn('Введите имя файла с путём: ');
        ReadLn(FileName);
        AssignFile(MyFile, FileName);
        IsCorrect := IsFileExists(FileName) And IsFileTxt(FileName) And IsFileWritable(MyFile);
    Until IsCorrect;
    RequestFileNameForWriting := FileName;
End;

Procedure CreateMatrix(N: Integer; Var Matrix: TMatrix);
Var
    I, J: Integer;
    IsCorrect: Boolean;
Begin
    SetLength(Matrix, N, N);
    For I := 0 To High(Matrix) Do
        For J := 0 To High(Matrix) Do
        Begin
            Repeat
                IsCorrect := True;
                WriteLn('Введите элемент матрицы А', I + 1, J + 1, ': ');
                Try
                    ReadLn(Matrix[I][J]);
                Except
                    IsCorrect := False;
                    WriteLn('Некорректный ввод. Введите число.');
                End;

                If IsCorrect And ((Matrix[I][J] < MIN_A) Or (Matrix[I][J] > MAX_A)) Then
                Begin
                    WriteLn('Некорректный ввод данных.');
                    WriteLn('Диапазон значений A от ', MIN_A, ' до ', MAX_A, '. ');
                    IsCorrect := False;
                End;

            Until IsCorrect;
        End;
End;

Function ReadMatrix(Var MyFile: TextFile; Var Matrix: TMatrix; Const N: Integer): Boolean;
Var
    I, J: Integer;
    Elements: TArray<String>;
    Line: String;
    IsCorrect: Boolean;
Begin
    I := 0;
    SetLength(Matrix, N, N);
    Reset(MyFile);
    IsCorrect := True;
    Try
        Try
            While Not Eof(MyFile) Do
            Begin
                ReadLn(MyFile, Line);
                Elements := Line.Split([' ']);
                For J := 0 To High(Elements) Do
                Begin
                    Matrix[I][J] := StrToFloat(Elements[J]);
                End;
                Inc(I);
            End;
        Except
            WriteLn('Ошибка в чтении матрицы. Проверьте её корректность.');
            IsCorrect := False;
        End;
    Finally
        CloseFile(MyFile);
    End;
    ReadMatrix := IsCorrect;
End;

Function WriteToFile(Var MyFile: TextFile; Const Sum: Double): Boolean;
Var
    IsCorrect: Boolean;
Begin
    IsCorrect := True;
    Try
        Try
            Rewrite(MyFile);
            WriteLn(MyFile, Sum:8:6);
            WriteLn('Результат выведен в файле.');
        Except
            WriteLn('Непредвиденная ошибка.');
            IsCorrect := False;
        End;
    Finally
        CloseFile(MyFile);
    End;
    WriteToFile := IsCorrect;
End;

Function SumElements(Var Matrix: TMatrix; Const N: Integer): Double;
Var
    I, J: Integer;
    Sum: Double;
Begin
    Sum := 0;
    For I := 1 To High(Matrix) Do
    Begin
        For J := 0 To I - 1 Do
            If (Matrix[I][J] > 0) Then
                Sum := Sum + Matrix[I][J];
    End;
    SumElements := Sum;
End;

Var
    N: Integer;
    Sum: Double;
    IsCorrect: Boolean;
    ChoiceOne: Integer;
    ChoiceTwo: Integer;
    MyMatrix: TMatrix;
    MyFile: TextFile;
    MyFileName: String;

Begin
    WriteLn('Данная программа считает сумму положительных элементов матрицы порядка n, стоящих под главной диагональю.', #13#10,
        'Диапазон значений порядка матрицы n: ', MIN_N, '...', MAX_N, #13#10, 'Диапазон для значений элементов матрицы: ', MIN_A, '...',
        MAX_A, #13#10, 'Откуда Вы хотите вводить данные?', #13#10, '1 - консоль, 2 - файл.');
    ChoiceOne := InputAndCheckChoice;
    N := InputAndCheckN;
    If (ChoiceOne = 1) Then
    Begin
        CreateMatrix(N, MyMatrix);
    End
    Else
    Begin
        Repeat
            MyFileName := RequestFileNameForReading(MyFile);
            IsCorrect := ReadMatrix(MyFile, MyMatrix, N);
        Until IsCorrect;
    End;
    Sum := SumElements(MyMatrix, N);
    WriteLn('Куда Вы хотите выводить результат?', #13#10, '1 - консоль, 2 - файл.');
    ChoiceTwo := InputAndCheckChoice;
    If (ChoiceTwo = 1) Then
    Begin
        WriteLn('Сумма равна ', Sum:8:6);
    End
    Else
    Begin
        Repeat
            MyFileName := RequestFileNameForWriting(MyFile);
            IsCorrect := WriteToFile(MyFile, Sum);
        Until IsCorrect;
    End;

    ReadLn;

End.