past bloom shader

shader_type canvas_item;

uniform float hueadd;
uniform float valuemult;
uniform float blur;
uniform vec2 drift;
uniform vec2 world_pos;

uniform vec2 vignete = vec2(0.25);
uniform sampler2D vignete_sampler;

vec3 rgb2hsv(vec3 c) {
    vec4 K = vec4(0.0, -1.0 / 3.0, 2.0 / 3.0, -1.0);
    vec4 p = mix(vec4(c.bg, K.wz), vec4(c.gb, K.xy), step(c.b, c.g));
    vec4 q = mix(vec4(p.xyw, c.r), vec4(c.r, p.yzx), step(p.x, c.r));

    float d = q.x - min(q.w, q.y);
    float e = 1.0e-10;
    return vec3(abs(q.z + (q.w - q.y) / (6.0 * d + e)), d / (q.x + e), q.x);
}

vec3 hsv2rgb(vec3 c) {
    vec4 K = vec4(1.0, 2.0 / 3.0, 1.0 / 3.0, 3.0);
    vec3 p = abs(fract(c.xxx + K.xyz) * 6.0 - K.www);
    return c.z * mix(K.xxx, clamp(p - K.xxx, 0.0, 1.0), c.y);
}

uniform float outline_lod = 2.0;
uniform float outline_distance = 2.0;


vec4 permute(vec4 x){return mod(((x*34.0)+1.0)*x, 289.0);}
vec4 taylorInvSqrt(vec4 r) { return 1.79284291400159 - 0.85373472095314 * r; }

float vignete_mult(vec2 uv){
    float dist_x = min(min(uv.x, 1.0 - uv.x) / vignete.x, 1.0);
    float dist_y = min(min(uv.y, 1.0 - uv.y) / vignete.y, 1.0);

    return texture(vignete_sampler, vec2(min(dist_x, dist_y))).r;
}


float snoise(vec3 v){
    vec2 C = vec2(1.0/6.0, 1.0/3.0) ;
    vec3 cccx = vec3(C.x);
    vec3 cccy = vec3(C.y);
    vec4 D = vec4(0.0, 0.5, 1.0, 2.0);

// First corner
  vec3 i  = floor(v + dot(v, cccy) );
  vec3 x0 =   v - i + dot(i, cccx) ;

// Other corners
  vec3 g = step(x0.yzx, x0.xyz);
  vec3 l = 1.0 - g;
  vec3 i1 = min( g.xyz, l.zxy );
  vec3 i2 = max( g.xyz, l.zxy );

  //  x0 = x0 - 0. + 0.0 * C
  vec3 x1 = x0 - i1 + 1.0 * cccx;
  vec3 x2 = x0 - i2 + 2.0 * cccx;
  vec3 x3 = x0 - 1.0 + 3.0 * cccx;

// Permutations
  i = mod(i, 289.0 );
  vec4 p = permute( permute( permute(
             i.z + vec4(0.0, i1.z, i2.z, 1.0 ))
           + i.y + vec4(0.0, i1.y, i2.y, 1.0 ))
           + i.x + vec4(0.0, i1.x, i2.x, 1.0 ));

// Gradients
// ( N*N points uniformly over a square, mapped onto an octahedron.)
  float n_ = 1.0/7.0; // N=7
  vec3  ns = n_ * D.wyz - D.xzx;

  vec4 j = p - 49.0 * floor(p * ns.z *ns.z);  //  mod(p,N*N)

  vec4 x_ = floor(j * ns.z);
  vec4 y_ = floor(j - 7.0 * x_ );    // mod(j,N)

  vec4 x = x_ *ns.x + vec4(ns.y);
  vec4 y = y_ *ns.x + vec4(ns.y);
  vec4 h = 1.0 - abs(x) - abs(y);

  vec4 b0 = vec4( x.xy, y.xy );
  vec4 b1 = vec4( x.zw, y.zw );

  vec4 s0 = floor(b0)*2.0 + 1.0;
  vec4 s1 = floor(b1)*2.0 + 1.0;
  vec4 sh = -step(h, vec4(0.0));

  vec4 a0 = b0.xzyw + s0.xzyw*sh.xxyy ;
  vec4 a1 = b1.xzyw + s1.xzyw*sh.zzww ;

  vec3 p0 = vec3(a0.xy,h.x);
  vec3 p1 = vec3(a0.zw,h.y);
  vec3 p2 = vec3(a1.xy,h.z);
  vec3 p3 = vec3(a1.zw,h.w);

//Normalise gradients
  vec4 norm = taylorInvSqrt(vec4(dot(p0,p0), dot(p1,p1), dot(p2, p2), dot(p3,p3)));
  p0 *= norm.x;
  p1 *= norm.y;
  p2 *= norm.z;
  p3 *= norm.w;

// Mix final noise value
  vec4 m = max(0.6 - vec4(dot(x0,x0), dot(x1,x1), dot(x2,x2), dot(x3,x3)), vec4(0.0));
  m = m * m;
  return 42.0 * dot( m*m, vec4( dot(p0,x0), dot(p1,x1),
                                dot(p2,x2), dot(p3,x3) ) );
}

uniform float noisescale = 1.0;
uniform float noisespeed = 1.0;
uniform float noiseamp = 1.0;

uniform float period = 4.0;
const float PI = 3.14159;

void fragment(){
    vec2 worlduv = world_pos + UV;
    vec2 inuv = UV + vec2(1.0, 0.0) * noiseamp * snoise( vec3((worlduv.x + sin(noisespeed * TIME * PI * 2.0 / period)) * noisescale, (worlduv.y * (SCREEN_PIXEL_SIZE.x / SCREEN_PIXEL_SIZE.y) + cos(noisespeed * TIME * PI * 2.0 / period)) * noisescale, sin(noisespeed * TIME * PI * 1.0 / period) * noisescale));
    inuv += vec2(0.0, 1.0) * noiseamp * snoise( vec3((worlduv.x + sin(- noisespeed * TIME * PI * 2.0 / period)) * noisescale + 1000.0, (worlduv.y + cos(-noisespeed * TIME * PI * 2.0 / period)) * noisescale, sin(-noisespeed * TIME * PI * 1.0 / period) * noisescale));
    vec3 preprocess = texture(TEXTURE, UV).rgb;
    vec3 right = texture(TEXTURE, UV + TEXTURE_PIXEL_SIZE * vec2(outline_distance,0)).rgb;
    vec3 top = texture(TEXTURE, UV + TEXTURE_PIXEL_SIZE * vec2(0,outline_distance)).rgb;

    preprocess.r = min(abs(preprocess.r - right.r) + abs(preprocess.r - top.r), 1.0);
    preprocess.g = min(abs(preprocess.g - right.g) + abs(preprocess.g - top.g), 1.0);
    preprocess.b = min(abs(preprocess.b - right.b) + abs(preprocess.b - top.b), 1.0);

    vec3 hueshift = rgb2hsv(textureLod(SCREEN_TEXTURE, inuv + drift, blur).rgb);
    float one = 1.0;
    hueshift.x = modf(hueshift.x + hueadd, one);
    hueshift.z *= valuemult;
//  vec4 original = textureLod(TEXTURE, UV, 2.0) + (textureLod(TEXTURE, UV, 2.0) - textureLod(TEXTURE, UV, 0.0)) * 10.0;
//  vec4 original = textureLod(TEXTURE, UV, 2.0);
    COLOR.rgb = max(hsv2rgb(hueshift), preprocess*valuemult) * vignete_mult(UV);
//  COLOR = original;
}